10 !USED TO ADD A NEW MAIL RECEIVER TO THE VALID LIST; MAIL.LST
   !
50 EXTEND
60	PRINT
	\ PRINT "Use this utility to add an acct/MAIL name to the 'valid' list"
	\ PRINT
100 ON ERROR GOTO 20000
110 OPEN "MAIL:MAIL.LST" FOR INPUT AS FILE 1%, MODE 2%
	! OPEN IN UPDATE MODE
115 PRINT\ PRINT \ PRINT STRING$(72%,42%)
116 PRINT\ PRINT
120 INPUT "a) project #, programmer #";PROJ$,PROG$
125	IF LEN(PROJ$)>4% OR LEN(PROG$)>4% THEN 120
130 INPUT "b) name (<=15 char.s)";NNAME$
135	IF LEN(NNAME$)>15% THEN 130
140 PRINT "c) user descriptor (<=70 char.s)";
	\ INPUT LINE DESCR$
	!
145	IF LEN(DESCR$)>70% THEN 140
150 !
160 	PROJ$=CVT$$(PROJ$,-1%)
	\ PROJ$="0"+PROJ$ UNTIL LEN(PROJ$)=4%
170	PROG$=CVT$$(PROG$,-1%)
	\ PROG$="0"+PROG$ UNTIL LEN(PROG$)=4%
180	NNAME$=CVT$$(NNAME$,-1%)
	\ NNAME$=NNAME$+" " UNTIL LEN(NNAME$)=15%
190	DESCR$=CVT$$(DESCR$,1%+4%+16%)
	\ DESCR$=DESCR$+" " UNTIL LEN(DESCR$)=70%
200 !
210	DENTRY$=CVT$$(DATE$(0%),-1%)
	\ TENTRY$=CVT$$(TIME$(0%),-1%)
	\ TENTRY$=LEFT(TENTRY$,2%)+RIGHT(TENTRY$,4%)
220 !
225 PRINT\ PRINT "Successfully entered !!"\ PRINT
230 PRINT #1%,PROJ$+PROG$+NNAME$+DENTRY$+TENTRY$+DESCR$
250 CLOSE 1%
260 PRINT\PRINT\PRINT STRING$(72%,42%)\ PRINT
270 GOTO 100
300 !
1000 GOTO 32000
20000 IF ERR=11% THEN CLOSE 1%\ RESUME 32000
21000 ON ERROR GOTO 0\ STOP
32000 END