1!	Program HELPLG.BAS	Version 1	June, 1976
	This is the utility program for creating and editing large
	(32 steps, 256 lines) HELPn.TXT files (HELP1.TXT thru HELP3.TXT)

2!			Department of Psychology
			   Lawrence University
			Appleton, Wisconsin, 54911
			(414) 739-3681,  Ext. 464

3!	Copyright (C) 1975, 1976 by Francis Campos.  General 
	permission to copy or modify, but not for profit, all or part of
	this document or the software described herein is hereby
4!	granted, provided that this copyright notice is given, and
	reference is made to the fact that reproduction privileges were
	granted by permission of Francis Campos, Lawrence University.

5!	Although  every  effort has been made to insure the accuracy and
	usefulness of this document and the software  described  herein,
	neither  the  author(s),  Lawrence  University,  nor its funding
6!	sources make any warranty, expressed or implied, with respect to
	the  performance or features of same on equipment which Lawrence
	neither owns nor controls.

7!	This program is one of the twenty-one BASIC-PLUS programs and
	eighteen virtual core files that comprise the CASANOVA
	package for Computer ASsisted instruction in ANalysis Of
8!	VAriance.  The package is coded for use on a PDP 11/40, 45 or 70
	computer operating under RSTS/E, V6A-02.  Those who wish to adapt
	the package to other systems and/or programming languages are
9!	urged to consult the BASIC-PLUS Language Manual, published by the
	Digital Equipment Corporation, Maynard, Massachusetts, 01754,
	as well as the Instructor's Manual for CASANOVA, provided by Lawrence.


20 PRINT"HELP FILE WRITER - CASANOVA - LARGE VERSION
30 INPUT"HELP FILE NUMBER";A1$
40 A1$="HELP"+A1$+".TXT"
50 OPEN A1$ AS FILE 1
60 DIM #1, H$(1,128)=64
70 INPUT"NEW OR OLD";A2$
80 IF A2$="NEW"THEN 90 ELSE 260 
90 INPUT"HOW MANY PROBLEM STEPS";N
100 &:&"ENTER THE TEXT WITHOUT COMMAS OR SEMICOLONS."
110 & A1$
120 FOR I=1 TO N
130 PRINT
140 &"S";I;" L1"
150 FOR I2=0 TO 3
160 INPUT A2$
170 H$(0,(I*4)-4+I2)=A2$
180 NEXT I2
190 &"S";I;" L2"
200 FOR I2=0 TO 3
210 INPUT A2$
220 H$(1,(I*4)-4+I2)=A2$
230 NEXT I2
240 NEXT I
250 H$(0,N*4)="HALT123456789"
260 FOR I=1 TO 128
270 IF H$(0,I)="HALT123456789" THEN 290 
280 NEXT I
290 N=I/4
300 PRINT"THERE ARE ";N;" PROBLEM STEPS.
310 INPUT"LIST THE TEXT";Q9$
320 IF Q9$="N"THEN 410 
330 & A1$
340 FOR I=1 TO N
350 FOR I2=0 TO 1
360 PRINT"S ";I;"  L";I2+1
370 FOR I3=0 TO 3
380 PRINT H$(I2,I*4-4+I3)
390 NEXT I3:NEXT I2:NEXTI
410 &:&
420 &"TO EDIT A LINE, SPECIFY STEP #, LEVEL #, & LINE #.
430 &"SEPARATE THE NUMBERS WITH COMMAS. 0,0,0 ENDS EDITTING.
440 INPUT"###";M1,M2,M3
450 IF M1=0 THEN 560 
460 IF M1>N OR M2>2 OR M2<1 OR M3>4 OR M3<1 THEN 470 ELSE 480 
470 PRINT"NOT A LEGAL SPECIFICATION.....TRY AGAIN:":GOTO 440 
480 M2=M2-1
490 PRINT H$(M2,M1*4-5+M3)
500 INPUT"CHANGE";Q2$
510 IF Q2$="N" THEN 440 
520 &"GO AHEAD"
530 INPUT Q3$
540 H$(M2,M1*4-5+M3)=Q3$
550 GO TO 440 
560 INPUT"LIST THE TEXT";Q2$
570 IF Q2$="N" THEN 790
580 P=1: L=1
590 PRINT FOR L=1 TO 5
600 PRINT FOR K=1 TO 9
610 &"CASANOVA HELP FILE",A1$,DATE$(0),"   PAGE";P
620 &:&:&
630 FOR I=1 TO N
640 FOR J=0 TO 1
650 PRINT"S ";I;" L "J+1
660 FOR K=0 TO 3
670 PRINT H$(J,I*4-4+K)
680 L=L+1
690 NEXT K
700 IF L>= 40 THEN 740
710 NEXT J:NEXT I
720 PRINT FOR K=L TO 64
730 GOTO 790
740 PRINT FOR K=1 TO 14
750 P=P+1
755 L=1
760 &"CASANOVA HELP FILE",A1$,DATE$(0),"   PAGE";P
770 &:&:&
780 GOTO 710
790 CLOSE 1
800 &"FILE ";A1$;" IS CLOSED."
810 END