Backus Naur Forms OMSI PILOT-73


			LEGEND
		  ::=    "is defined as...."
		  |      "or"
		  < >    encloses an element of OMSI PILOT-73



		  Language Rules

1. The length of a <string variable> must be from 1 to 8
   inclusive.
2. The length of a <statement label> must be from 2 to 9
   inclusive. The asterisk (*) at the beginning
   is counted.
3. A <string> may have zero length.
4. A double quote (") and a single quote (') may not
   both be in the same <talk object>.
5. In a <Continue statement> the object must be of the
   same type as the preceding <PILOT statement>. The
   <continue statement> must not be the first non-blank
   statement of a PILOT program.
6. A <Match statement> must contain a <conditional> 
   to be followed by a <Continue statement>.
7. The length of a <program line> must not exceed
   128.
8. A PILOT program is composed entirely of <program line>s.
   There may be a maximum of 300.
		Backus Naur Forms OMSI PILOT-73


<letter>		::=   A|B|C|D|E|F|G|H|I|J|K|L|M|N|O|P|
			      Q|R|S|T|U|V|W|X|Y|Z
<digit>			::=   1|2|3|4|5|6|7|8|9|0
<integer>		::=   <digit>|<integer><digit>
<number>		::=   <integer>|<integer>.<integer>|
			      <integer>.|.<integer>
<alhanumeric>		::=   <letter>|<digit>
<alphanumerics>		::=   <alphanumeric>|<alphanumerics>
			      <alphanumeric>
<numeric variable>	::=   <letter>
<string variable>	::=   $<alphanumerics>
<character>		::=   any ASCII character except null,
			      return,linefeed,rubout,altmode,
			      control C, and control Z
<literal character>	::=   any <character> except # and $
<string>		::=   <character>|<string><character>
<literal>		::=   <literal character>|<literal>
			      <literal character>
<statement label>	::=   *<literal>
<space>			::=   ASCII decimal code 32
<tab>			::=   ASCII decimal code 9
<blank>			::=   <space>|<tab>
<blanks>		::=   <blank>|<blanks><blank>
<relational operator>	::=   =|==|>|<|<>|>=|<=
<relation>		::=   <sum><relational operator><sum>
<expression>		::=   <sum>|<relation>
<sum>			::=   <term>|<sum>+<term>|<sum>-<term>
<term>			::=   <subterm>|<term>*<subterm>|
			      <term>/<subterm>
<subterm>		::=   <signed factor>|<factor>
<signed factor>		::=   +<factor>|-<factor>
<factor>		::=   <primary>|<factor>^<primary>
<primary>		::=   <numeric variable>|<number>|PI|
			      RND|<functional>|(<expression>)
<function>		::=   ABS|SGN|INT|FIX|COS|SIN|TAN|ATN|
			      SQR|EXP|LOG|LOG10|RND
<functional>		::=   <function>(<expression>)
<conditional>		::=   Y|N|(<relation>)|(<numeric variable>)
<statement line>	::=   <PILOT statement>carriage return
<PILOT statement>	::=   <Talk statement>|<Accept statement>|
			      <Jump statement>|<Use statement>|
			      <Compute statement>|<Remark statement>
			      <End statement>|<Match statement>|
			      <Continue statement>|<blanks>
<program line>		::=   <statement label><blanks><statement
			      line>|<statement line>
		Backus Naur Forms Continued


<Talk statement>	::=   T<conditional>:<talk object>|T:
			      <talk object>|Y:<talk object>|
			      N:<talk object>

<talk object part>	::=   #<numeric variable>|<literal>|
			      <string variable>
<talk object>		::=   <talk object part>|<talk object>
			      <talk object part>
<Accept statement>	::=   A<conditional>:<accept object>|
			      A:<accept object>
<accept object>		::=   #<numeric variable>|<string variable>|
			      <blanks>
<Jump statement>	::=   J<conditional>:<jump object>|J:
			      <jump object>
<jump object>		::=   <statememt label>
<Use statement>		::=   U<conditional>:<use object>|U:
			      <use object>
<use object>		::=   <statement label>
<Compute statement>	::=   C<conditional>:<compute object>|
			      C:<compute object>
<variable combination>	::=   <numeric variable>|<variable
			      combination>,<numeric variable>
<compute subobject>	::=   <variable combination>=<expression>
<compute object>	::=   <compute subobject>|<compute object>:
			      <compute subobject>
<Remark statement>	::=   R<conditional>:<string>|R:<string>
<End statement>		::=   E<conditional>:<string>|E:<string>
<Match statement>	::=   M<conditional>:<match object>|
			      M:<match object>
<match object>		::=   <string>|<match object>,<string>
<all object>		::=   <talk object>|<accept object>|
			      <jump object>|<use object>|<compute
			      object>|<string>|<match object>
<continue statement>	::=   :<all object>