10 REM THIS PROGRAM WAS TAKEN FROM PAGE 39 OF SCCS INTERFACE
20 REM MAGAZINE, VOL. 1, ISSUE 12, JULY 1977
30 REM IT WAS WRITTEN BY BOB RIPLEY
40 REM
50 CL$=CHR$(26):REM SCREEN CLEAR CHAR.
60 PRINT CL$
70 PRINT "PLANNING A FLIGHT CAN BE FUN"
80 PRINT "I WILL DO IT FOR YOU, IF YOU JUST ANSWER MY QUESTIONS."
90 PRINT "PRESS THE RETURN KEY AFTER EACH RESPONSE."
100 PRINT "WE WILL DO A LEG AT A TIME, PAUSING SO THAT YOU CAN"
110 PRINT"FILL IN THE FLIGHT PLAN FORM AS WE GO."
120 PRINT"IF YOU NOTICE THAT YOU MADE A MISTAKE AFTER THE RETURN"
130 PRINT "HOLD DOWN CNTL AND TYPE C, THEN TYPE RUN TO START OVER"
140 PRINT:PRINT:LINEINPUT"PRESS RETURN TO CONTINUE >";Z$
150 PRINT CL$
160 INPUT"HOW MANY GALLONS OF USABLE FUEL";F1
170 INPUT"WHAT IS THE FUEL RATE IN GPH";F
180 INPUT"WHAT IS THE TRUE AIR SPEED IN KNOTS";T
190 INPUT"THE WIND IS FROM WHAT (TRUE) DIRECTION (DEGREES)";D
200 INPUT"WHAT IS THE WIND SPEED IN KNOTS";S
210 INPUT"WHAT IS THE MAGNETIC VARIATION (EAST=+,WEST=-DEGREES)";V
220 INPUT"WHAT IS THE COURSE FOR THIS LEG (DEGREES)";C
230 INPUT"HOW LONG IS THIS LEG IN NM";M
240 R=57.2958
250 D=D-V
260 A=SIN(D-C)
270 IF S=0THEN B=0
280 IF S=0THENGOTO300
290 B=S/T
300 B1=ATN(B/SQR(-B*B+1))
310 H=C+(B1*R*A)
320 IF H<0THEN 370
330 PRINT
340 H=INT(H*10+.5)/10
350 PRINT "HEADING IS";H;"DEGREES"
360 GOTO 390
370 H=H+360
380 GOTO 330
390 G=T*COS((H-C)/R)-S*COS((D-C)/R)
400 G=INT(G*10+.5)/10
410 PRINT"GROUND SPEED IS";G;"KNOTS"
420 IF G>0 GOTO 440
430 PRINT"YOU CAN NOT GET THERE THIS WAY"
440 T1=60*M/G
450 T1=INT(T1*10+.5)/10
460 PRINT"THE TIME FOR THIS LEG IS";T1;"MINUTES"
470 T2=T2+T1
480 IFT2<60 THEN PRINT"TOTAL TIME IS";T2;"MINUTES"
490 IF T2<60 THEN 530
500 T3=INT(T2/60)
510 T4=T2-T3*60
520 PRINT"TOTAL TIME IS ";T3;"HOURS AND";T4;"MINUTES"
530 F2=F*(T1/60)
540 F2=INT(F2*10+.5)/10
550 PRINT"FUEL USED ON THIS LEG IS";F2;"GALLONS"
560 F1=F1-F2
570 F3=F3+F2
580 PRINT"TOTAL FUEL USED IS ";F3;"GALLONS; LEAVING";F1;"GALLONS"
590 IFF1<=0THEN640
600 PRINT 
610 INPUT "ANY SPEED, WIND, OR VAR CHANGES THIS LEG";C$
620 IF LEFT$(C$,1)="Y" THEN GOTO 170
630 GOTO 220
640 PRINT
650 PRINT"RUNNING OUT OF FUEL IN FLIGHT"
660 PRINT"CAN BE HAZARDOUS TO YOUR HEALTH"
670 FOR I=1 TO 500:NEXT I
680 RUN "DIR"
690 END
RUNNING OUT OF