10 REM *** BUBBLE SORT PROGRAM ***
20 REM *** WRITTEN BY JIM PETERSEN FOR COMPUTER CLASS AT KIMBALL
            HIGH SCHOOL, RE-WRITTEN FOR MICROSOFT BASIC ON 3/4/79 ***
30 CLEAR 500
40 D=100
50 DIM A$(D),A(D)
60 PRINT CHR$(26):REM CLEAR SCREEN COMMAND
70 INPUT "DO YOU WANT TO DO A CHARACTER OR NUMBER SORT";A$
80 IF LEFT$(A$,1)="C" THEN F=1 ELSE F=0
90 PRINT "WHAT MARKER DO YOU WANT TO USE (NOT IN YOUR INPUTTED"
100 PRINT "INFORMATION) TO INDICATE THE END OF YOUR LIST";:
    IF F=1 THEN INPUT M$ ELSE INPUT M
110 PRINT "ENTER EACH ";:IF F=1 THEN PRINT "CHARACTER";
    ELSE PRINT "NUMBER";
120 PRINT " AFTER EACH QUESTION MARK AND TYPE RETURN."
130 PRINT "USE YOUR MARKER TO INDICATE THE END OF YOUR LIST."
140 N=0
150 N=N+1
160 ON ERROR GOTO 440
170 IF F=1 THEN PRINT "CHARACTER SET #";N;:INPUT A$(N) ELSE
 	       PRINT "NUMBER SET #";N;:INPUT A(N)
180 IF (F=1 AND A$(N)=M$) OR (F=0 AND A(N)=M) THEN 200
190 GOTO 150
200 N=N-1
210 PRINT "PLEASE WAIT WHILE YOUR LIST IS BEING SORTED:";
220 FOR I=1 TO N-1
230 FOR J=I+1 TO N
240 IF F=1 AND A$(J)<=A$(I) THEN SWAP A$(J),A$(I):GOTO 260
250 IF A(J)<=A(I) THEN SWAP A(J),A(I)
260 NEXT J
270 NEXT I
280 PRINT
290 Z=PEEK(61318!):IF Z<>0 THEN 320
300 INPUT "DO YOU WANT YOUR LIST ON HARD-COPY OR THE SCREEN";A$
310 IF LEFT$(A$,1)="H" THEN PRINT "TURN ON HARD-COPY AND PRESS";:
     PRINT " RETURN: ";:LINE INPUT A$:POKE 61318!,1:PRINT:
     REM TURN ON PRINTER
320 PRINT
330 PRINT "HERE IS YOUR LIST IN ";:IF F=1 THEN PRINT "ALPHABETICAL";
     ELSE PRINT "NUMERICAL";
340 PRINT " ORDER:":PRINT
350 FOR I=1 TO N
360 IF F=1 THEN PRINT A$(I), ELSE PRINT A(I),
370 NEXT I
380 IF Z<>0 THEN 390 ELSE POKE 61318!,0:REM POKE 61318! IF NOT
 				       ON PRINTER INITIALLY.
390 PRINT
400 INPUT "DO YOU WANT ANOTHER LIST OF THE SAME THING";A$:
     IF LEFT$(A$,1)="Y" THEN 290
410 INPUT "DO YOU WANT TO RUN THIS PROGRAM AGAIN";A$
420 IF LEFT$(A$,1)="Y" THEN RUN
430 GOTO 450
440 PRINT "THE DIMENSION STATEMENT IN THIS PROGRAM ONLY ALLOWS";D:
     PRINT "ENTRIES, SO I WILL SORT YOUR ENTRIES AS IS.":GOTO 200
450 RUN "DIR"
460 END
NT IN THIS PROGRAM ONLY ALLOWS";D:
     PRINT "EN