1   'LABELS3.BAS  MBASIC 5.2 CP/M  05/82  TEM
2   'PRINT LABELS ONE, TWO, OR THREE UP.
6    GOTO 50
7    SAVE "LABELS3.BAS",A:STOP
40	SPACES$ = "                              "
50	     N$ = "                              "
55	     O$ = "                              "
60	     S$ = "                              "
65	     C$ = "                              "
70	     Z$ = "                              "
90	DEFINT A-Z: WIDTH 80
100	PRINT:PRINT
110	PRINT	TAB(20);"L A B E L S"
130	PRINT
150	PRINT "   Prints labels of up to five lines each."
160	PRINT "Each field may contain a total of 25 characters max."
170	PRINT "The lines are: Name, Organization, Street address,"
175	PRINT "City and State, and Zip code.
180	PRINT "You may omit any line(s).  Do NOT use commas."
200	PRINT "Prints one, two, or three across in 80 columns."
300	PRINT:PRINT   "         PRINT 1, 2, OR 3-UP      (1-3 or 0 to exit)";
400	INPUT U
500	IF U = 0 THEN SYSTEM
600	IF U < 1  OR  U > 3  THEN GOTO 300
700	PRINT:PRINT   "         HOW MANY LABELS         (1-300   0 to exit)";
800	INPUT L
900	IF L=0 THEN SYSTEM
1000	IF L < 1 OR L > 300 THEN 700
1100	IF L/3 <> INT (L/3) THEN L = L + 1: GOTO 1100
1150	GOSUB 25900			'IS PRINTER READY?
1200	PRINT
1300	INPUT	"        NAME (NO COMMA)";N$
1400	INPUT	"           ORGANIZATION";O$
1500	INPUT	"                 STREET";S$
1600	INPUT	"CITY & STATE (NO COMMA)";C$
1700	INPUT	"                ZIPCODE";Z$
1800	PRINT
1900	IF U = 1  THEN	GOTO  6000
2000	' TWO-UP OR THREE-UP ROUTINE
2100	PRINT	"*************************";" ";
2200	PRINT	"*************************"
2300	PRINT	N$;TAB(27);N$
2400	PRINT	 O$;TAB(27); O$
2500	PRINT	 S$;TAB(27); S$
2600	PRINT	LEFT$ (C$+SPACES$,25); TAB(27);
2700	PRINT	LEFT$ (C$+SPACES$,25)
2800	PRINT	Z$; TAB(27);Z$
2900	PRINT	"*************************"; " ";
3000	PRINT	"*************************":PRINT
3100	PRINT	"          LOOK OK ?    Y=YES   N=NO   E=EXIT PROGRAM ";
3200	OKAY$=INPUT$(1)
3300	IF	OKAY$ = "E" OR OKAY$ = "e" THEN GOTO 100
3400	IF	OKAY$ = "N" OR OKAY$ = "n" THEN GOTO 1200
3500	FOR I = 1 TO L/U	'HOW MANY LINES TO PRINT?
3600	LPRINT:LPRINT
3700	IF U = 3 THEN GOTO 4600 'GO DO 3-UP PRINTING, NOT 2-UP
3800	LPRINT	  N$;TAB(27);N$
3900	LPRINT	  O$;TAB(27); O$
4000	LPRINT	  S$;TAB(27); S$
4100	LPRINT	  LEFT$ (C$+SPACES$,25);
4200	LPRINT	  TAB(27);LEFT$ (C$+SPACES$,25)
4300	LPRINT	  Z$; TAB(27);Z$
4400	GOTO 5300		'DONE 2-UP
4500	' THREE-UP PRINT ROUTINE
4600	LPRINT	  N$;TAB(27); N$;TAB(53);N$
4700	LPRINT	  O$;TAB(27); O$;TAB(53);O$
4800	LPRINT	  S$;TAB(27); S$;TAB(53);S$
4900	LPRINT	  LEFT$ (C$+SPACES$,25);
5000	LPRINT	  TAB(27);LEFT$ (C$+SPACES$,25);
5100	LPRINT	  TAB(53);LEFT$ (C$+SPACES$,25)
5200	LPRINT	  Z$; TAB(27);Z$;TAB(53);Z$
5300	LPRINT:LPRINT
5400	IF I > 1 THEN GOTO 5700
5500	PRINT	 "...FORM ALIGNMENT PAUSE: OK ?   (Y-N)";:G$=INPUT$(1)
5600	IF G$ = "N" OR G$ = "n"  THEN GOTO 3600
5700	NEXT I
5800	GOTO 100
5900	'--------------------------------------------------
6000	' 1-UP ROUTINE
6100	PRINT	"******************************"
6200	PRINT	N$:PRINT O$:PRINT S$:
6300	PRINT	LEFT$ (C$+SPACES$,25)
6400	PRINT	Z$
6500	PRINT	"******************************":PRINT
6600	PRINT	"LOOK OK ?    Y=YES   N=NO   E=EXIT PROGRAM ";:OKAY$=INPUT$(1)
6700	IF	OKAY$ = "N" OR OKAY$ = "n" THEN GOTO 100
6800	IF	OKAY$ = "E" OR OKAY$ = "e" THEN SYSTEM
6900	 PRINT
7000	FOR I = 1 TO L
7100	LPRINT:LPRINT
7200	LPRINT N$:LPRINT O$:LPRINT S$
7300	LPRINT LEFT$ (C$+SPACES$,25):LPRINT Z$
7400	LPRINT:LPRINT
7500	IF I > 1 THEN GOTO 7800
7600	PRINT "  IS FORM ALIGNMENT OK ?    (Y-N) ";G$=INPUT$(1)
7700	IF G$ = "N" OR G$ = "n" THEN GOTO 7100
7800	NEXT I
7900	GOTO 100
8000	END
25900	'TEST FOR PRINTER READY RTN
25910	IF (INP(230) AND (48))<>0 THEN GOTO 25990
25920	PRINT:PRINT CHR$(7)		'ONE RINGY DINGY
25930	PRINT "         Printer is NOT turned-on, or NOT ready."
25940	INPUT "         Press the RETURN key when printer is ready.";Z$
25950	GOTO 25910
25990	RETURN
ned-on, or NOT ready."
25940	INPUT "         Press the RETURN key w