*
*  help.cmd
*
*  Glenn Story - 6/10/83
*
*  This command provides interactive help information about dBASE
*
use help index help
set talk off
set intensity off
store '?' to choice
do while 1=1
  do help1
  do case
    case choice='1'
      erase
      store "        " to xcommand
      @ 5,5 say "Enter command name" get xcommand
      read
      store !(xcommand) to xcommand
      do while xcommand # " "
        find &xcommand
        if #=0
          @ 10,5 say "Command not found"
          @ 20,5 say "Press any key to continue" get choice
          read
        else
          do help5
        endif
        store link to xcommand
      enddo
    case choice='2'
      erase
    @ 2, 32 say "dBASE II Commands"
    store 4 to y
    find ?
    do while .not. eof
      store 2 to x
      do while (x<72) .and. (.not. eof)
        if $(command,1,1)<>'%'
          @ y,x say command
          store x+10 to x
        endif
        skip
        enddo
      store y+1 to y
      enddo
     @ 23,10 say "Press any key to continue" get choice
     read
    case choice='3'
      do help2
    case choice='4'
      do help3
      do help4
    case choice='0'
      erase
      set intensity on
      set talk on
      use
      return
  endcase
enddo