*GHOST INITIATOR
*PURPOSE- TO AUTOMATICALLY INITIATE LOAD MODULES WHICH ARE
*        IDENTIFIED BY RECORDS IN AN EDIT CREATED FILE,WHICH
*        HAS THE LM NAMES, AND THE LM'S ARE IN THE :SYS
*        ACCOUNT. THE POINTER FILE NAME MUST BE 'AUTOG'
*        IN THE ACCOUNT UNDER WHICH THIS PROGRAM IS RUNNING.
*        THE POINTER FILE 'AUTOG' MUST HAVE THE FOLLOWING
*        RECORD FORMATS:( $FILENAME COMMENT......)
*                 1.000 $FILENAMEX THIS GHOST BANGS MEMORY
*                 2.000 $FILENAMEY THIS GHOST USES NOWAIT IO
*                 3.000 $FILENAMEZ THIS GHOST TESTS SYMBIONT
*                 4.000  BECAUSE COL 1 IS NOT $, INITIATOR TERMINATES
*
*PREREQUISITES-THIS PROGRAM AND THE PROGRAMS POINTED TO BY
*        'AUTOG' MUST BE IN LOAD MODULE FORMAT, THE GHOST JOBS
*        WHICH WILL BE INITIATED MUST BE IN :SYS
*        THIS PROGRAM AND THE 'AUTOG' FILE CAN BE IN
*        ANY ACCOUNT THAT HAS SUFFICIENT PRIVLEDGE TO INITIATE
*        GHOSTS AND IN THIS MODE CAN BE RUN AS A BATCH OR
*        ONLINE JOB. THIS PROGRAM AND 'AUTOG' CAN
*        ALSO BE IN :SYS ACCOUNT WHICH WILL ALLOW THIS
*        PROGRAM TO BE GJOB'D FROM THE OPERATOR CONSOLE.
*OUTPUTS-THIS PROGRAM WILL OUTPUT TO M:LL THE FOLLOWING
*                 AUTO GHOST INITIATER HERE USING FILE 'AUTOG'
*                 (MEANS PROGRAM HAS STARTED)
*                 FOLLOWING FILE INITIATED
*                 (MEANS CC1,2 RESET AFTER INITIATE CAL)
*                 FOLLOWING FILE FAILED TO INITIATE
*                 (MEANS CC1 OR 2 SET AFTER GHOST INITIATE CAL)
*                 ALL DONE BYE
*                 (MEANS EOF OR NOT $ IN COL1 OF RECORD ENCOUNTERED)
         SYSTEM   BPM
         SYSTEM   SIG9P
F:GFILE  DSECT    1
F:GFILE  M:DCB    (FILE,'AUTOG'),(CONSEC),(SEQUEN),(IN);
                  ,(RECL,80),(TRIES,10)
         CSECT    0
START    M:PRINT  (MESS,MSINIT)
         M:TYPE   (MESS,MSINIT)
         CAL1,8   =X'0F000032'      SLEEP FOR 1 MINUTE
START1   EQU      $
         LI,1     240
         LI,2     0
         STB,2    STAGE,1
         BDR,1    $-1               CLEAR INPUT AREA
         LB,0     INBUF             GET FIRST BYTE
         CI,0     '$'               IS IT $?
         BNE      EXIT              NO
         LI,6     F:GFILE           GET DCB ADDR
         SCS,6    1
         LH,6     4,6               GET # BYTES TX'D
         SCS,6    -1
         STB,6    OUTMESS
         LI,2     1
MVLP     LB,3     INBUF,2           GET LMN FILE NAME FROM REC
         STB,3    STAGE,2
         STB,3    OUTMESS,2
         CI,3     ' '               IS IT A BLANK
         BE       GOTFN             BLANK FOUND FILE NAME
         AI,2     1                 NO
         BDR,6    MVLP              CONTINUE LOOKING
         B        EXIT              NEVER FOUND FILE NAME
GOTFN    STB,2    STAGE             PUT # BYTES OF FILE NAME IN FPT
         MTB,-1   STAGE             BUMP IT BACK ONE
MSLOOP   AI,2     1
         LB,3     INBUF,2
         STB,3    OUTMESS,2
         M:WAIT   1
         NOP
         CAL1,6   GHOSTIT           INITIATE GHOST JOB
         BCR,12   OK                IT MADE IT
         M:PRINT  (MESS,MSBAD)      NO
         M:PRINT  (MESS,OUTMESS)
         B        START1            GO BACK AND START AGAIN
OK       M:PRINT  (MESS,MSOK)
         M:PRINT  (MESS,OUTMESS)
         B        START1            GO BACK AND START AGAIN
EXIT     M:PRINT  (MESS,MSDONE)
         M:EXIT
MSINIT   TEXTC    'AUTOGHOST HERE, USING FILE AUTOG.'
MSBAD    TEXTC    '*******THIS FILE WILL NOT INITIATE***'
MSOK     TEXTC    '**FOLLOWING FILE INITIATED**'
MSDONE   TEXTC    '**********ALL DONE,BYE**********'
GHOSTIT  DATA     X'06000000'
STAGE    RES      20
INBUF    RES      20
OUTMESS  RES      20
         END      START
