*                                                                       ELS20001
*                                                                       ELS20002
*                                                                       ELS20003
 TITLE 'CP-V/CP-R BOUNDARY MODULE ELLA. 708006-A01  6.10.75'            ELS20004
*                                                                       ELS20005
*                                                                       ELS20006
*                                                                       ELS20007
         PAGE                                                           ELS20008
*                                                                       ELS20009
*  THE BOUNDARY ROM COMPRISES THE MODEL,DEVICE,TYPE AND TIME BOUNDARY   ELS20010
*  SELECTION MECHANISM.                                                 ELS20011
*                                                                       ELS20012
         PAGE                                                           ELS20013
         SYSTEM   SIG7FDP                                               ELS20014
*                                                                       ELS20015
         CSECT                                                          ELS20016
*                                                                       ELS20017
*                                                                       ELS20018
         PAGE                                                           ELS20019
*                                                                       ELS20020
*  DEFINITIONS.-----                                                    ELS20021
*                                                                       ELS20022
         DEF      TYPE:0,DEV:0,MOD:0,TIME:0                             ELS20023
*                                                                       ELS20024
*                                                                       ELS20025
*                                                                       ELS20026
         PAGE                                                           ELS20027
*                                                                       ELS20028
*  REFERENCES.------                                                    ELS20029
*                                                                       ELS20030
         REF      TYPEF,:TYPE:,DEVF,:DEV:,MODF,:MOD:                    ELS20031
         REF      COMBUFF                                               ELS20032
         REF      E:PRINT,R:COM                                         ELS20033
         REF      DATE:0,YEAR:0,TIME:00                                 ELS20034
         REF      DATE:1,YEAR:1,TIME:1                                  ELS20035
         REF      DATE:2,YEAR:2,TIME:2                                  ELS20036
         REF      XFOX,XF9X                                             ELS20037
         REF      DECHEX:,EBCHEX1                                       ELS20038
         REF      COB,CAB,X4BD5                                         ELS20039
         REF      A:7                                                   ELS20040
         REF      F:F                                                   ELS20041
         REF      TIME:ZR,MD:JD,HMSN:MS                                 ELS20042
         REF      S:FLAG,GETDT                                          ELS20043
         REF      S:SYS                                                 ELS20044
         REF      MDIO                                                  ELS20045
         REF      RSE:                                                  ELS20046
         REF      MODTBL:                                               ELS20047
         PAGE                                                           ELS20048
*                                                                       ELS20049
*                                                                       ELS20050
*        BIFSYS *(KEY,*ADDR) . . .                                      ELS20051
*                                                                       ELS20052
*        KEY IS SYSTEM NAME (CPR,CPV,RBM)                               ELS20053
*        ADDR IS BRANCH ADDRESS                                         ELS20054
*        GROUP MAY BE REPEATED FOR MULTIPLE TEST/BRANCHES               ELS20055
*        AFA(I)   INDICATES B IF NOT SYSTEM                             ELS20056
*        AFA(I,2) INDICATES B INDIRECT                                  ELS20057
*                                                                       ELS20058
*                                                                       ELS20059
BIFSYS   CNAME                                                          ELS20060
         PROC                                                           ELS20061
         LOCAL    I,T1                                                  ELS20062
         GEN,8,4,20  X'71',1,S:SYS         CB,1 S:SYS                   ELS20063
I        DO       NUM(AF)                                               ELS20064
T1       SET      SCOR(AF(I,1),RBM,CPR)                                 ELS20065
         DO       T1>0                                                  ELS20066
         GEN,1,7,4,20  AFA(I,2),X'69'-AFA(I),T1,AF(I,2)                 ELS20067
         ELSE                                                           ELS20068
         GEN,1,7,4,20  AFA(I,2),X'68'+AFA(I),3,AF(I,2)                  ELS20069
         FIN                                                            ELS20070
         FIN                                                            ELS20071
         PEND                                                           ELS20072
*                                                                       ELS20073
*                                                                       ELS20074
         PAGE                                                           ELS20075
*                                                                       ELS20076
*                                                                       ELS20077
*                                                                       ELS20078
*  DATA  AREA                                                           ELS20079
*                                                                       ELS20080
B:FLAG   DATA     0          MOD,DEV OR TYPE FLAG   2,3,1 IN ORDER      ELS20081
B:VPM    DATA     0          MAXIMUM BYTE/ENTRY ALLOWED                 ELS20082
B:XYZ    DATA     0                                                     ELS20083
B:ZYX    DATA     0,0,0,0,0   TEMPORARY LOCATIONS.                      ELS20084
B:PV     DATA     0           PARAMETER FOR NO. OF ENTRIES              ELS20085
B:IVC    DATA     0           PARAMETER FOR NO. OF BYTES/ENTRY.         ELS20086
*                                                                       ELS20087
*                                                                       ELS20088
*                                                                       ELS20089
         PAGE                                                           ELS20090
B:START  EQU      %                                                     ELS20091
*                                                                       ELS20092
*    TYPE ENTRY                                                         ELS20093
*                                                                       ELS20094
TYPE:0   EQU      %                                                     ELS20095
         STW,1    B:FLAG     SET B:FLAG. 1= TYPE                        ELS20096
         LI,4     2          SET MAX ALLOWABLE BYTES/ENTRY.             ELS20097
         B        B:ENTRY    CONTINUE                                   ELS20098
*                                                                       ELS20099
*    MODEL ENTRY                                                        ELS20100
*                                                                       ELS20101
MOD:0    EQU      %                                                     ELS20102
         STW,2    B:FLAG     SET FLAG   2=MODEL                         ELS20103
         B        B:DEVMOD    CONTINUE                                  ELS20104
*                                                                       ELS20105
*    DEVICE ENTRY                                                       ELS20106
*                                                                       ELS20107
DEV:0    EQU      %                                                     ELS20108
         STW,3    B:FLAG      SET FLAG  3=DEVICE                        ELS20109
B:DEVMOD LI,4     4           SET MAX ALLOWABLE BYTE/ENTRY              ELS20110
*                                                                       ELS20111
*    CONTINUE                                                           ELS20112
*                                                                       ELS20113
B:ENTRY  EQU      %                                                     ELS20114
         STW,4    B:VPM       SAVE  REGISTER 4. (MAX.ALL.BYTE/ENTRY)    ELS20115
         LI,4     -8                                                    ELS20116
         STW,0    B:XYZ+8,4  CLEAR  LOCATIONS.                          ELS20117
         BIR,4    %-1                                                   ELS20118
         LW,4     CAB         TRANSFER TO WORKING LOCATION              ELS20119
         STW,4    COB                                                   ELS20120
*                                                                       ELS20121
*   BEGIN ANALYSIS OF VALUES.                                           ELS20122
*                                                                       ELS20123
B:B      EQU      %                                                     ELS20124
         BAL,15   F:F          FETCH A BYTE (INPUT CHARACTER)           ELS20125
         B        B:D          TERMINATION.                             ELS20126
         CB,14    X4BD5,1                                               ELS20127
         BE       B:C         BRANCH IF COMMA                           ELS20128
         MTW,1    B:IVC       INCREMENT BYTE/ENTRY                      ELS20129
         LW,4     B:IVC                                                 ELS20130
         CW,4     B:VPM       WITHIN LIMITS.....                        ELS20131
         BG       B:1ERR     BRANCH IF NOT (ERROR)                      ELS20132
*                                                                       ELS20133
*  BEGIN PROCESSING ACCORDING TO APPROPIATE FORMAT. (DECIMAL/HEXADEC)   ELS20134
*                                                                       ELS20135
         LW,4     B:FLAG     FETCH FLDG                                 ELS20136
         CI,4     2                                                     ELS20137
         BNE      B:1B       BRANCH IF NOT MODEL DEGIMITER              ELS20138
         CB,14    XFOX                                                  ELS20139
         BL       B:3ERR     DETERMINE IF IT IS DECIMAL OR NOT          ELS20140
         CB,14    XF9X       BRANCH IF NOT A DECIMAL                    ELS20141
         BLE      B:1B       *     *    *    *    *   *                 ELS20142
         B        B:3ERR     *     *    *    *    *   *                 ELS20143
B:1B     EQU      %                                                     ELS20144
         BAL,15   EBCHEX1    CONVERT TO HEX.                            ELS20145
         B        B:4ERR     BRANCH IF NOT A DECIMAL OR HEX NO.         ELS20146
         LW,4     B:PV       FETCH INDEX                                ELS20147
         LW,14     B:ZYX,4       FETCH VALUE PARA ETER                  ELS20148
         SLS,14   4                                                     ELS20149
         OR,14    15         OR' THE 4 BITS INTO PLACE.                 ELS20150
         STW,14   B:ZYX,4    STORE BACK.                                ELS20151
         B        B:B                                                   ELS20152
*                                                                       ELS20153
*   COMMA ENCOUNTERED                                                   ELS20154
*                                                                       ELS20155
B:C      EQU      %                                                     ELS20156
         MTW,1    B:PV       INCREMENT  ENTRIES COUNTER                 ELS20157
         LW,4     B:PV                                                  ELS20158
         CI,4     4          BRANCH ERROR IF TOO MANY ENTRIES.          ELS20159
         BG       B:2ERR     ERROR.... TOO MANY ENTRIES                 ELS20160
         STW,0    B:IVC                                                 ELS20161
         B        B:B        BRANCH BACK TO READ NEXT                   ELS20162
*                                                                       ELS20163
*  TERMINATION.  EITHER NL OR  CR OR ALL BYTES (80)                     ELS20164
*                                                                       ELS20165
B:D      EQU      %                                                     ELS20166
         LI,4     -6                                                    ELS20167
         LW,13    B:FLAG                                                ELS20168
B:4D     CI,13    1                                                     ELS20169
         BE       B:1D        CLEAR:TYPE:,OR :MOD: OR :DEV:             ELS20170
         CI,13    2                                                     ELS20171
         BE       B:2D         TOGETHER WITH    DEVF,MODF,OR TYPEF      ELS20172
         STW,0    DEVF+6,4                                              ELS20173
         B        B:3D                                                  ELS20174
B:1D     STW,0    TYPEF+6,4                                             ELS20175
         B        B:3D                                                  ELS20176
B:2D     STW,0    MODF+6,4                                              ELS20177
B:3D     BIR,4    B:4D                                                  ELS20178
         STW,0    B:PV                                                  ELS20179
         LI,4     -5           START TRANSFER OF VALUES                 ELS20180
B:44D    LW,14    B:ZYX+5,4                                             ELS20181
         BEZ      B:5D          EITHER  :DEV:, :MOD:, :TYPE:            ELS20182
         LW,5     B:PV                                                  ELS20183
         CI,13    1                                                     ELS20184
         BE       B:11D                                                 ELS20185
         CI,13    2                                                     ELS20186
         BE       B:22D                                                 ELS20187
         STW,14   :DEV:,5                                               ELS20188
         B        B:33D                                                 ELS20189
B:11D    STW,14   :TYPE:,5                                              ELS20190
         B        B:33D                                                 ELS20191
B:22D    RES      0                                                     ELS20192
         BIFSYS   (CPV,B:22E)       B IF CPV                            ELS20193
         BAL,15   DECHEX:                                               ELS20194
         B       B:3ERR                                                 ELS20195
         XW,14    15                                                    ELS20196
B:22E    STW,14    :MOD:,5     STORE MODEL NO                           ELS20197
B:33D    MTW,1    B:PV        INCREMENT PARAMETER COUNT                 ELS20198
B:5D     BIR,4    B:44D                                                 ELS20199
         LW,5     B:PV        DEPOSIT NO. OF VALUES IN                  ELS20200
         CI,13    1                                                     ELS20201
         BE       B:111D       TO  MODF,DEVF OR TYPEF                   ELS20202
         CI,13    2                                                     ELS20203
         BE       B:222D                                                ELS20204
         STW,5    DEVF                                                  ELS20205
         B        B:333D                                                ELS20206
B:111D   STW,5    TYPEF                                                 ELS20207
         B        B:333D                                                ELS20208
B:222D   STW,5    MODF                                                  ELS20209
B:333D   B        R:COM    BACK TO CONTROL                              ELS20210
*                                                                       ELS20211
*                                                                       ELS20212
*                                                                       ELS20213
*                                                                       ELS20214
*                                                                       ELS20215
*    ERROR  " TOO MANY PARAMETERS/ENTRY."                               ELS20216
*                                                                       ELS20217
B:1ERR   EQU      %                                                     ELS20218
         LI,14    28           SET BYTE COUNT.                          ELS20219
         LI,13    B1MSG        FETCH MSG ADDRESS.                       ELS20220
         B        B:OUT                                                 ELS20221
*                                                                       ELS20222
*    ERROR  " TOO MANY ENTRIES "                                        ELS20223
*                                                                       ELS20224
B:2ERR   EQU      %                                                     ELS20225
         LI,14    23           SET BYTE COUNT                           ELS20226
         LI,13    B2MSG        FETCH MSG                                ELS20227
         B        B:OUT                                                 ELS20228
*                                                                       ELS20229
*    ERROR  " CHARACTER ENTERED NOT DECIMAL "                           ELS20230
*                                                                       ELS20231
B:3ERR   EQU      %                                                     ELS20232
         LI,14    11           SET BYTE COUNT                           ELS20233
         LI,13    B3MSG        FETCH MSG                                ELS20234
         B        B:OUT                                                 ELS20235
*                                                                       ELS20236
*    ERROR  'CHARACTER ENTERED NOT  A HEXADECIMAL NO.'                  ELS20237
*                                                                       ELS20238
B:4ERR   EQU      %                                                     ELS20239
         LI,14    15           SET BYTE COUNT                           ELS20240
         LI,13    B4MSG        SET MSG                                  ELS20241
B:OUT    EQU      %                                                     ELS20242
         STW,13   B:ERMSG      STORE TO OUTPUT LOCATION                 ELS20243
         BAL,15   E:PRINT      ERROR PRINT                              ELS20244
B:ERMSG  DATA     0                                                     ELS20245
         B        R:COM        RETURN TO CONTROL                        ELS20246
*                                                                       ELS20247
*                                                                       ELS20248
*                                                                       ELS20249
*        TEXT MESSAGES.                                                 ELS20250
*                                                                       ELS20251
*                                                                       ELS20252
*                                                                       ELS20253
B1MSG    TEXT     'PARAMETER PER ENTRY EXCEEDED'                        ELS20254
B2MSG    TEXT     'NO. OF ENTRIES EXCEEDED'                             ELS20255
B3MSG    TEXT     'NOT DECIMAL'                                         ELS20256
B4MSG    TEXT     'NOT HEXADECIMAL'                                     ELS20257
*                                                                       ELS20258
*                                                                       ELS20259
*                                                                       ELS20260
*                                                                       ELS20261
*                                                                       ELS20262
         PAGE                                                           ELS20263
*                                                                       ELS20264
*                                                                       ELS20265
*                                                                       ELS20266
*                                                                       ELS20267
*                                                                       ELS20268
*        TIME ROUTINE.                                                  ELS20269
*                                                                       ELS20270
*                                                                       ELS20271
*                                                                       ELS20272
*                                                                       ELS20273
*        CONSTANTS.                                                     ELS20274
*                                                                       ELS20275
T:DSCC   TEXT     '-:/,'                                                ELS20276
*                                                                       ELS20277
*                                                                       ELS20278
*        DATA     AREA                                                  ELS20279
*                                                                       ELS20280
*                                                                       ELS20281
T:FF     DATA     0            FIELD FLAG. (SIGNALS 1 OR 2ND FILED)     ELS20282
T:IVC    DATA     0            INTERNAL VALUE COUNTER.                  ELS20283
T:DC     DATA     0            DASH COUNT.                              ELS20284
T:PST    DATA     0            PASS COUNT (SIGNIFICANT ONLY IF EXCEEDS 8ELS20285
T:SLSH   DATA     0            SLASH FLAG.                              ELS20286
T:TEMP   DATA     0            TEMPORARY LOCATION                       ELS20287
T:CF     DATA     0            COMMA FLAG.                              ELS20288
*                                                                       ELS20289
*        SAVE LOCATIONS FOR THE TIME INPUT.                             ELS20290
*                                                                       ELS20291
F1:HR    DATA     0                                                     ELS20292
F2:HR    DATA     0                                                     ELS20293
F1:MIN   DATA     0                                                     ELS20294
F2:MIN   DATA     0                                                     ELS20295
F1:MON   DATA     0                                                     ELS20296
F2:MON   DATA     0                                                     ELS20297
F1:DAY   DATA     0                                                     ELS20298
F2:DAY   DATA     0                                                     ELS20299
F1:YR    DATA     0                                                     ELS20300
F2:YR    DATA     0                                                     ELS20301
*                                                                       ELS20302
*        FLAGS TO DETERMINE WHETHER ANY INPUT HAS BEEN                  ELS20303
*        MADE TO THE TIME AND DATE PARAMETERS.                          ELS20304
*        0 IF NONE HAS BEEN MADE.                                       ELS20305
*        1 IF ANY ENTRY HAS BEEN MADE.                                  ELS20306
*        IN THIS CASES , ZERO IS A VALID ENTRY TO WARRANT A ONE.        ELS20307
*                                                                       ELS20308
FL:TIME  DATA     0,0                                                   ELS20309
FL:DATE  DATA     0,0                                                   ELS20310
*                                                                       ELS20311
*                                                                       ELS20312
*                                                                       ELS20313
         PAGE                                                           ELS20314
*                                                                       ELS20315
*                                                                       ELS20316
*                                                                       ELS20317
*                                                                       ELS20318
*        TIME BOUNDARY.                                                 ELS20319
*        THIS PART OF CODE WILL ACCEPT THE TIME AND DATE.               ELS20320
*        THE CONDITIONS FOR THE TIME COMMAND ARE AS SPECIFIED           ELS20321
*        IN THE SPECIFICATION 703118.                                   ELS20322
*        A BRANCH TO LABEL TIME:0 WILL ENTER THIS ROUTINE.              ELS20323
*                                                                       ELS20324
*                                                                       ELS20325
TIME:0   EQU      %                                                     ELS20326
         LW,5     CAB          TRANSFER THE CAB TO COB.                 ELS20327
         STW,5    COB                                                   ELS20328
         LI,5     -7           SET INDEX TO CLEAR AREAS.                ELS20329
         STW,0    T:FF+7,5     CLEAR AREA 1                             ELS20330
         BIR,5    %-1                                                   ELS20331
*                                                                       ELS20332
         LI,5     -14                                                   ELS20333
         STW,0    F1:HR+14,5   CLEAR AREA 2                             ELS20334
         BIR,5    %-1                                                   ELS20335
         STW,1    T:CF         SET COMMA FLAG.                          ELS20336
*                                                                       ELS20337
*                                                                       ELS20338
*                                                                       ELS20339
1:TM     EQU      %                                                     ELS20340
         BAL,15   F:F          FETCH CHARACTER FROM COMBUFF.            ELS20341
         B        7:TM         TERMINATION.                             ELS20342
         MTW,1    T:PST        INCREMENT PASS FLAG.                     ELS20343
         CB,14    T:DSCC,3     BRANCH IF COMMA                          ELS20344
         BE       2:TM                                                  ELS20345
         STW,0    T:CF         RESET COMMA FLAG.                        ELS20346
         CB,14    XFOX         BRANCH IF DECIMAL NO.                    ELS20347
         BL       11:TIM       BRANCH IF NOT.                           ELS20348
         CB,14    XF9X                                                  ELS20349
         BLE      3:TM                                                  ELS20350
11:TIM   EQU      %                                                     ELS20351
         CB,14    T:DSCC       BRANCH IF A DASH.                        ELS20352
         BE       4:TM                                                  ELS20353
*                                                                       ELS20354
*        T:IVC CHECKED HERE FOR THE BEFNEFIT OF COLON                   ELS20355
*        SLASH ROUTINES. T:IVC MUST BE 1 OR 2 BEFORE ENTERING           ELS20356
*        THE COLON OR SLASH ROUTINES.                                   ELS20357
*                                                                       ELS20358
         MTW,0    T:IVC        CHECK T:IVC                              ELS20359
         BEZ      12:TIM       BRANCH IF ERROR.                         ELS20360
         STW,0    T:IVC        IVC OK. RESET NOW.                       ELS20361
         CB,14    T:DSCC,1     BRANCH IF A COLON.                       ELS20362
         BE       5:TM                                                  ELS20363
         CB,14    T:DSCC,2     BRANCH IF A SLASH.                       ELS20364
         BE       6:TM                                                  ELS20365
12:TIM   EQU      %                                                     ELS20366
         B        A:7          BRANCH TO PRINT 'INVALID ENTRY'          ELS20367
*                                                                       ELS20368
*                                                                       ELS20369
*                                                                       ELS20370
         PAGE                                                           ELS20371
*                                                                       ELS20372
*        COMMA ENCOUNTERED.                                             ELS20373
*                                                                       ELS20374
*        DETERMINE IF ANY PREVIOUS ENTRIES MADE                         ELS20375
*        IF NOT 'ERROR'                                                 ELS20376
*                                                                       ELS20377
2:TM     EQU      %                                                     ELS20378
         MTW,0    T:CF         BRANCH IF PREVIOUS COMMA SET.            ELS20379
         BNEZ     12:TIM                                                ELS20380
         MTW,0    T:IVC        CHECK IVC.                               ELS20381
         BNEZ     12:TIM       BRANCH IF NOT ZERO                       ELS20382
         STW,1    T:CF         SET COMMA FLAG.                          ELS20383
         B        1:TM         READ NEXT CHARACTER.                     ELS20384
*                                                                       ELS20385
*                                                                       ELS20386
*                                                                       ELS20387
         PAGE                                                           ELS20388
*                                                                       ELS20389
*        INITIAL NUMBER ENTERED.                                        ELS20390
*        INCREMENT T:IVC                                                ELS20391
*        CONVERT AND STORE TO T:TEMP.                                   ELS20392
*                                                                       ELS20393
3:TM     EQU      %                                                     ELS20394
         LW,15    T:IVC        BRANCH IF NOT EQUAL TO LESS THAN 2       ELS20395
         CI,15    2                                                     ELS20396
         BGE      12:TIM       BRANCH .GTE. 2                           ELS20397
         MTW,1    T:IVC        INCREMENT IVC.                           ELS20398
         LI,15    0                                                     ELS20399
         SLD,14   -4           PROCEED TO CONVERT AND STORE             ELS20400
         LW,14    T:TEMP                                                ELS20401
         SLD,14   4                                                     ELS20402
         STW,14   T:TEMP                                                ELS20403
         B        1:TM         READ NEXT CHARACTER                      ELS20404
*                                                                       ELS20405
*                                                                       ELS20406
*                                                                       ELS20407
         PAGE                                                           ELS20408
*                                                                       ELS20409
*        DASH ENCOUNTERED.                                              ELS20410
*        INCREMENT DASH COUNTER.                                        ELS20411
*        IF T:DC  IS EQUAL TO 1 WHEN ENTERING (ERROR)                   ELS20412
*                                                                       ELS20413
4:TM     EQU      %                                                     ELS20414
         MTW,0    T:IVC        BRANCH IF IVC = GT. 1                    ELS20415
         BNEZ     12:TIM                                                ELS20416
         LW,14    T:DC         BRANCH IF T:DC .NEQ. ZERO                ELS20417
         BNEZ     12:TIM                                                ELS20418
         MTW,1    T:DC         INCREMENT T:DC                           ELS20419
         B        1:TM         READ NEXT CHARACTER.                     ELS20420
*                                                                       ELS20421
*                                                                       ELS20422
*                                                                       ELS20423
         PAGE                                                           ELS20424
*                                                                       ELS20425
*        COLON ENCOUNTERED.                                             ELS20426
*        T:IVC MUST BE 1 OR 2 (NOT ZERO)(IVC RESET BEFORE ENTERING)     ELS20427
*        T:DC MUST BE 0 OR 1                                            ELS20428
*                                                                       ELS20429
5:TM     EQU      %                                                     ELS20430
         LW,14    T:TEMP       FETCH TEMPORARY LOCATION                 ELS20431
         LW,4     T:DC         SET INDEX.                               ELS20432
         LW,15    FL:TIME,4    CHECK FOR ENTRY PREVIOUSLY MADE.         ELS20433
         BNEZ     12:TIM       IF YES, **ERROR**                        ELS20434
         STW,1    FL:TIME,4    SET THE FLAG.                            ELS20435
         BAL,15   DECHEX:      CONVERT TO HEX.                          ELS20436
         B        12:TIM       **ERROR**                                ELS20437
         CI,15    23           COMPARE TO MAX HOURS PERMITTED.          ELS20438
         BG       12:TIM       BRANCH IF GREATER **ERROR**              ELS20439
         STW,15   F1:HR,4      STORE TO LOCATION.                       ELS20440
51:TIM   EQU      %                                                     ELS20441
         BAL,15   F:F          FETCH NEXT CHARACTER.                    ELS20442
         B        53:TIM       TERMINATION.                             ELS20443
         CB,14    XFOX         BRANCH IF DECIMAL NO.                    ELS20444
         BL       52:TIM                                                ELS20445
         CB,14    XF9X         BRANCH IF NOT.                           ELS20446
         BLE      54:TIM                                                ELS20447
52:TIM   EQU      %                                                     ELS20448
         CB,14    T:DSCC,3     BRANCH IF COMMA                          ELS20449
         BE       53:TIM                                                ELS20450
         CB,14    T:DSCC       BRANCH IF A DASH.                        ELS20451
         BE       53:TIM                                                ELS20452
         B        12:TIM       **ERROR**                                ELS20453
*                                                                       ELS20454
*                                                                       ELS20455
*                                                                       ELS20456
*                                                                       ELS20457
*        DASH OR COMMA ENCOUNTERED.                                     ELS20458
*        PROCEED TO EXIT.                                               ELS20459
*                                                                       ELS20460
53:TIM   EQU      %                                                     ELS20461
         MTW,0    T:IVC        CHECK IVC.                               ELS20462
         BEZ      12:TIM       **ERROR**                                ELS20463
         STW,0    T:TEMP       RESET TEMPORARY                          ELS20464
         STW,0    T:IVC        RESET IVC                                ELS20465
         MTW,-1   COB          DECREMENT BY ONE COB.                    ELS20466
         LW,4     T:DC         FETCH IEX.                               ELS20467
         LW,14    F1:MIN,4     FETCH MINUTES.                           ELS20468
         BAL,15   DECHEX:      CONVERT                                  ELS20469
         B        12:TIM       **ERROR**                                ELS20470
         CI,15    59           COMPARE TO MAX MINUTES PERMITTED.        ELS20471
         BG       12:TIM       BRANCH IF GREATER**ERROR**               ELS20472
         STW,15   F1:MIN,4     STORE TO LOCATION.                       ELS20473
         B        1:TM         READ NEXT CHARACTER.                     ELS20474
*                                                                       ELS20475
*                                                                       ELS20476
*                                                                       ELS20477
*                                                                       ELS20478
*        NUMBER ENCOUNTERD.                                             ELS20479
*        FETCH AND SAVE THE MINUTES.                                    ELS20480
*                                                                       ELS20481
54:TIM   EQU      %                                                     ELS20482
         LW,15    T:IVC        BRANCH IF IVC .GTW. 2                    ELS20483
         CI,15    2                                                     ELS20484
         BGE      12:TIM       **ERROR**                                ELS20485
         MTW,1    T:IVC        I NCREMENT IVC.                          ELS20486
         LW,4     T:DC         FETCH INDEX.                             ELS20487
         LI,15    0                                                     ELS20488
         SLD,14   -4           PROCEED TO CONVERT AND STORE.            ELS20489
         LW,14    F1:MIN,4                                              ELS20490
         SLD,14   4                                                     ELS20491
         STW,14   F1:MIN,4                                              ELS20492
         B        51:TIM                                                ELS20493
         PAGE                                                           ELS20494
*                                                                       ELS20495
*        SLASH ENCOUNTERED.                                             ELS20496
*        T:IVC MUST BE 1 OR 2                                           ELS20497
*        T:DC     MUST BE 0 OR 1                                        ELS20498
*                                                                       ELS20499
6:TM     EQU      %                                                     ELS20500
         LW,14    T:TEMP       FETCH TEMPORARY.                         ELS20501
         LW,4     T:DC         FETCH INDEX.                             ELS20502
         LW,15    FL:DATE,4    CHECK TO SEE IF ENTRIES HAS BEEN MADE    ELS20503
         BNEZ     12:TIM       IF YES **ERROR**                         ELS20504
         STW,1    FL:DATE,4    SET THE FLAG.                            ELS20505
         BAL,15   DECHEX:      CONVERT TO HEX.                          ELS20506
         B        12:TIM       **ERROR**                                ELS20507
         CI,15    12           COMPARE TO MAX MONTHS PERMITTED.         ELS20508
         BG       12:TIM       BRANCH IF GREATER **ERROR**              ELS20509
         STW,15   F1:MON,4     STORE TO LOCATION.                       ELS20510
         STW,0    T:SLSH       CLEAR OUT SLASH FLAG.                    ELS20511
61:TIM   EQU      %                                                     ELS20512
         BAL,15   F:F          FETCH CHARACTER.                         ELS20513
         B        63:TIM       TERMINATION.                             ELS20514
         CB,14    XFOX         BRANCH IF IT IS A DECIMAL.               ELS20515
         BL       62:TIM                                                ELS20516
         CB,14    XF9X                                                  ELS20517
         BLE      64:TIM       BRANCH IF A DECIMAL.                     ELS20518
62:TIM   EQU      %                                                     ELS20519
         CB,14    T:DSCC,3     BRANCH IF A COMMA                        ELS20520
         BE       63:TIM                                                ELS20521
         CB,14    T:DSCC,2     BRANCH IF SLASH                          ELS20522
         BE       65:TIM                                                ELS20523
         CB,14    T:DSCC       BRANCH IF A DASH.                        ELS20524
         BE       63:TIM                                                ELS20525
         B        12:TIM       **ERROR**                                ELS20526
*                                                                       ELS20527
*                                                                       ELS20528
*                                                                       ELS20529
         PAGE                                                           ELS20530
*                                                                       ELS20531
*        SLASH FOUND.                                                   ELS20532
*        T:IVC    MUST BE 1 OR 2 NOT 0 OR 3                             ELS20533
*        T:SLSH MUST BE 0                                               ELS20534
*                                                                       ELS20535
65:TIM   EQU      %                                                     ELS20536
         MTW,0    T:IVC        CHECK FOR ZERO                           ELS20537
         BEZ      12:TIM       **ERROR**                                ELS20538
         MTW,0    T:SLSH       CHECK FOR ZERO                           ELS20539
         BNEZ     12:TIM       **ERROR**                                ELS20540
         MTW,1    T:SLSH       INCREMENT SLSH FLAG.                     ELS20541
         STW,0    T:IVC        CLEAR IVC COUNTER.                       ELS20542
         B        61:TIM       READ NEXT CHARACTER.                     ELS20543
*                                                                       ELS20544
*                                                                       ELS20545
*                                                                       ELS20546
         PAGE                                                           ELS20547
*                                                                       ELS20548
*        NUMBER FOUND.                                                  ELS20549
*                                                                       ELS20550
64:TIM   EQU      %                                                     ELS20551
         LW,15    T:IVC        FETCH IVC                                ELS20552
         CI,15    2            BRANCH IF .GT. OR .EQ. 2                 ELS20553
         BGE      12:TIM       **ERROR**                                ELS20554
         MTW,1    T:IVC        INCREMENT INTERNAL VALUE COUNTER.        ELS20555
         LW,4     T:DC         FETCH DASH COUNTER.                      ELS20556
         LI,15    0            CLEAR 15                                 ELS20557
         SLD,14   -4           PROCEED TO CONVERT AND STORE             ELS20558
         LW,14    T:SLSH                                                ELS20559
         BEZ      641:TIM                                               ELS20560
         LW,14    F1:YR,4                                               ELS20561
         B        642:TIM                                               ELS20562
641:TIM  EQU      %                                                     ELS20563
         LW,14    F1:DAY,4                                              ELS20564
642:TIM  EQU      %                                                     ELS20565
         SLD,14   4                                                     ELS20566
         LW,15    T:SLSH                                                ELS20567
         BEZ      643:TIM                                               ELS20568
         STW,14   F1:YR,4                                               ELS20569
         B        644:TIM                                               ELS20570
643:TIM  EQU      %                                                     ELS20571
         STW,14   F1:DAY,4                                              ELS20572
644:TIM  EQU      %                                                     ELS20573
         B        61:TIM       GO FETCH NEXT CHARACTER.                 ELS20574
*                                                                       ELS20575
*                                                                       ELS20576
*                                                                       ELS20577
         PAGE                                                           ELS20578
*                                                                       ELS20579
*        COMMA OR DASH FOUND.                                           ELS20580
*                                                                       ELS20581
*        IVC MUST NOT BE ZERO                                           ELS20582
*        SLASH COUNTER MUST BE 1                                        ELS20583
*        EXIT WILL BE THRU THIS ROUTINE.                                ELS20584
*                                                                       ELS20585
63:TIM   EQU      %                                                     ELS20586
         MTW,0    T:IVC        CHECK FOR IVC = 0                        ELS20587
         BEZ      12:TIM       **ERROR** BRANCH IF ZERO                 ELS20588
         LW,4     T:SLSH       FETCH SLASH COUNTER.                     ELS20589
         CI,4     1                                                     ELS20590
         BNE      12:TIM       **ERROR** SLASH COUNTER .NE. 1           ELS20591
         MTW,-1   COB          DECREMENT COB INDEX.                     ELS20592
         STW,0    T:IVC        CLEAR IVC.                               ELS20593
         STW,0    T:TEMP       CLEAR TEMPORARY.                         ELS20594
         LW,4     T:DC         FETCH INDEX.                             ELS20595
         LW,14    F1:DAY,4     FETCH THE DAY ENTERED.                   ELS20596
         BAL,15   DECHEX:      CONVERT TO HEX                           ELS20597
         B        12:TIM       **ERROR**                                ELS20598
         CI,15    31           COMPARE TO MAX DAYS PERMITTED.           ELS20599
         BG       12:TIM       BRANCH IF GREATER **ERROR**              ELS20600
         STW,15   F1:DAY,4     STORE TO LOCATION.                       ELS20601
         LW,14    F1:YR,4      FETCH THE YEAR ENTERED.                  ELS20602
         BAL,15   DECHEX:      CONVERT TO HEX.                          ELS20603
         B        12:TIM       **ERROR**                                ELS20604
         CI,15    99           COMPARE TO MAX YEARS PERMITTED.          ELS20605
         BG       12:TIM       BRANCH IF GREATER **EROR*                ELS20606
         STW,15   F1:YR,4      STORE TO LOCATION                        ELS20607
         B        1:TM         BACK TO CENTRAL ROUTINE.                 ELS20608
*                                                                       ELS20609
*                                                                       ELS20610
*                                                                       ELS20611
         PAGE                                                           ELS20612
*                                                                       ELS20613
*        TERMINATE THE BYTE INPUT SEARCH.                               ELS20614
*                                                                       ELS20615
7:TM     EQU      %                                                     ELS20616
         LW,14    T:PST        FETCH PASS FLAG.                         ELS20617
         BEZ      12:TIM       **ERROR**                                ELS20618
*                                                                       ELS20619
*        VALID INPUT........                                            ELS20620
*        NOW, CHECK FOR DISCREPANCIES.                                  ELS20621
*                                                                       ELS20622
         LW,14    T:CF         CHECK THE COMMA FLAG                     ELS20623
         BNEZ     12:TIM       **ERROR** COMMA FLAG MUST BE 0           ELS20624
         LW,14    T:IVC        CHECK IVC.                               ELS20625
         BNEZ     12:TIM       **ERROR** IVC MUST BE ZERO               ELS20626
*                                                                       ELS20627
*        PROCEED HERE TO VALIDATE ENTRIES AND CHECK                     ELS20628
*        FOR THE TIME BOUNDARIES .                                      ELS20629
*        THE LIMITS OF THE BOUNDARIES MUST NOT BE EXCEEDED.             ELS20630
*                                                                       ELS20631
*                                                                       ELS20632
*        CONTINUE PROCESS.                                              ELS20633
*                                                                       ELS20634
*                                                                       ELS20635
T:PROC   EQU      %                                                     ELS20636
         LI,4     -2           INITIALIZE INDEX.                        ELS20637
T2:PR    EQU      %                                                     ELS20638
         LW,14    FL:DATE+2,4  CHECK DATE FLAG.                         ELS20639
         BEZ      T1:PR        BRANCH IF NO ENTRY DONE.                 ELS20640
         LW,13    F1:MON+2,4   ENTRY DONE. BEGIN CONVERSION             ELS20641
         LW,14    F1:DAY+2,4    FROM M/D TO JULIAN DAYS.                ELS20642
         BAL,15   MD:JD                                                 ELS20643
         STW,15   F1:DAY+2,4   SAVE THE RESULTS.                        ELS20644
T1:PR    EQU      %                                                     ELS20645
         BIR,4    T2:PR        LOOP UNTIL DONE. WITH INDEX.             ELS20646
*                                                                       ELS20647
*                                                                       ELS20648
*                                                                       ELS20649
         LI,4     -2           INITIALIZE INDEX                         ELS20650
T22:PR   EQU      %                                                     ELS20651
         LW,14    FL:TIME+2,4  CHECK TIME FLAG.                         ELS20652
         BEZ      T11:PR       BRANCH IF NO ENTRY DONE.                 ELS20653
         LW,13    F1:HR+2,4    ENTRY DONE. BEGIN CONVERSION             ELS20654
         LW,14    F1:MIN+2,4    FROM HR/MIN TO MILLISEC.                ELS20655
         BAL,15   HMSN:MS                                               ELS20656
         B        12:TIM       **ERROR** NON-CONVERTIBLE.               ELS20657
         STW,15   F1:MIN+2,4   SAVE THE RESULTS.                        ELS20658
T11:PR   EQU      %                                                     ELS20659
         BIR,4    T22:PR       LOOP UNTIL DONE WITH INDEX.              ELS20660
*                                                                       ELS20661
*                                                                       ELS20662
*                                                                       ELS20663
*        FETCH THE DEFAULT OR APPROPIATE VALUES                         ELS20664
*                                                                       ELS20665
*                                                                       ELS20666
         LI,4     -2           SET INDEX.                               ELS20667
T3:PR    EQU      %                                                     ELS20668
         LW,14    FL:DATE+2,4  CHECK DATE FLAG.                         ELS20669
         BEZ      T4:PR        BRANCH IF NO ENTRY DONE.                 ELS20670
         LW,14    FL:TIME+2,4  FETCH TIME FLAG.                         ELS20671
         BNEZ     T6:PR        BRANCH IF ENTRY IS DONE!!                ELS20672
         LW,14    TIME:00,4    FETCH FROM TIME:ZR+2,4                   ELS20673
         STW,14   F1:MIN+2,4   SAVE RESULTS.                            ELS20674
         B        T6:PR        BRANCH  TO END.                          ELS20675
T4:PR    EQU      %                                                     ELS20676
         LW,14    FL:TIME+2,4  FETCH TIME FLAG.(NO DATE ENTERED)        ELS20677
         BEZ      T5:PR        BRANCH IF NO TIME ENTERD.                ELS20678
         BAL,15   GETDT        GET MOST CURRENT DAT-YEAR.               ELS20679
         LW,14    DATE:0            GET CURRENT DATE                    ELS20680
         STW,14   F1:DAY+2,4   SAVE..                                   ELS20681
         LW,14    YEAR:0            GET CURRENT YEAR.                   ELS20682
         STW,14   F1:YR+2,4    SAVE..                                   ELS20683
         B        T6:PR        BRANCH TOEND                             ELS20684
T5:PR    EQU      %                                                     ELS20685
         LW,14    DATE:1,4     FETCH FROM YEAR:1+2,4                    ELS20686
         STW,14   F1:YR+2,4    SAVE..                                   ELS20687
         LW,14    TIME:1,4     FETCH FROM DATE:1+2,4                    ELS20688
         STW,14   F1:DAY+2,4   SAVE..                                   ELS20689
         LW,14    YEAR:0,4     FETCH FROM TIME:1+2,4                    ELS20690
         STW,14   F1:MIN+2,4   SAVE//                                   ELS20691
T6:PR    EQU      %                                                     ELS20692
         BIR,4    T3:PR        LOOP UNTIL DONE.                         ELS20693
*                                                                       ELS20694
*                                                                       ELS20695
*                                                                       ELS20696
*        BEGIN TO CHECK THE BOUNDS.                                     ELS20697
*                                                                       ELS20698
*                                                                       ELS20699
         LW,14    F1:YR        FETCH YEAR.                              ELS20700
         CW,14    F2:YR                                                 ELS20701
         BE       T7:PR        Y1 EQ. Y2 BRANCH:                        ELS20702
         BL       T9:PR        Y1 .LT. Y2 BRANCH:                       ELS20703
         LI,15    TY1GTY2      **ERROR** Y1 GT Y2                       ELS20704
         B        T:ERPR                                                ELS20705
T7:PR    EQU      %                                                     ELS20706
         LW,14    F1:DAY       FETCH DAY.                               ELS20707
         CW,14    F2:DAY                                                ELS20708
         BE       T8:PR        D1 EQ D2 BRANCH:                         ELS20709
         BL       T9:PR        D1 LT D2 BRANCH:                         ELS20710
         LI,15    TD1GTD2      **ERROR** D1 GT D2                       ELS20711
         B        T:ERPR                                                ELS20712
T8:PR    EQU      %                                                     ELS20713
         LW,14    F1:MIN       FETCH TIME.                              ELS20714
         CW,14    F2:MIN                                                ELS20715
         BG       T10:PR       **ERROR** T1 GT T2                       ELS20716
T9:PR    EQU      %                                                     ELS20717
         LW,14    F1:YR        (GOOD CONDITIONS):                       ELS20718
         STW,14   YEAR:1       (1) Y1 LT Y2 , DATE-TIME PASSED.         ELS20719
         LW,14    F2:YR        (2) Y1 EQ Y2,,                           ELS20720
         STW,14   YEAR:2           THEN D1 LT D2, TIME PASSED.          ELS20721
         LW,14    F1:MIN       (3) D1 EQ D2 THEN                        ELS20722
         STW,14   TIME:1          T1 LT T2                              ELS20723
         LW,14    F2:MIN                                                ELS20724
         STW,14   TIME:2                                                ELS20725
         LW,14    F1:DAY                                                ELS20726
         STW,14   DATE:1                                                ELS20727
         LW,14    F2:DAY                                                ELS20728
         STW,14   DATE:2                                                ELS20729
         BAL,15   RSE:         RESET                                    ELS20730
*                                                                       ELS20731
         B        R:COM        BRANCH TO EXEC.                          ELS20732
*        ERROR**                                                        ELS20733
*                                                                       ELS20734
T10:PR   EQU      %                                                     ELS20735
         LI,15    TT1GTT2      FETCH TIME ERROR FORMAT.                 ELS20736
T:ERPR   EQU      %                                                     ELS20737
         LI,14    21           FETCH BYTE COUNT                         ELS20738
         STW,15   T:ER1        STORE THE TEXT ADDRESS.                  ELS20739
         BAL,15   E:PRINT                                               ELS20740
T:ER1    DATA     0                                                     ELS20741
         B        A:7          BRANCH TO INVALID ENTRY.....             ELS20742
*                                                                       ELS20743
*                                                                       ELS20744
*                                                                       ELS20745
TY1GTY2  TEXT     'YEAR2 LESS THAN YEAR1'                               ELS20746
TD1GTD2  TEXT     'DATE2 LESS THAN DATE1'                               ELS20747
TT1GTT2  TEXT     'TIME2 LESS THAN TIME1'                               ELS20748
*                                                                       ELS20749
*                                                                       ELS20750
*                                                                       ELS20751
         PAGE                                                           ELS20752
         SPACE    25                                                    ELS20753
         END      B:START                                               ELS20754

