ASMB
      NAM JULIA,7 . 92903-16001 REV.1805  761222
* 
*     SOURCE 92903-18032
* 
      SPC 2 
**************************************************************
* (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1978.  ALL RIGHTS    *
* RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED, RE- *
* PRODUCED, OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITH-  *
* OUT THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.  *
**************************************************************
      SPC 2 
      ENT JULIA 
      EXT .ENTR 
A     EQU 0 
B     EQU 1 
* 
* 
* 
*           FORTRAN CALLABLE FUNCTION:
* 
*              I=JULIA(ID,MO,IY)
* 
*              ON RETURN I = JULIAN DAY,OR
*                          = -1 IF ERROR! 
* 
* 
ID    NOP 
MO    NOP 
IY    NOP 
JULIA NOP 
      JSB .ENTR 
      DEF ID
      LDA IY,I
      ADA MIN 
      SSA 
      JMP ERROR 
      LDA IY,I
      ADA MAX 
      SSA,RSS 
      JMP ERROR 
      LDA IY,I
      CPA D1900 
      INA 
      CPA D2000 
      INA 
      AND D3
      LDB D28 
      SZA,RSS 
      INB 
      STB FEBR
      LDA ID,I
      CMA,INA 
      SSA,RSS 
      JMP ERROR 
      LDA MO,I
      CMA,INA 
      STA POINT 
      SSA,RSS 
      JMP ERROR 
      ADA D12 
      SSA 
      JMP ERROR 
      LDA AMT 
      ADA MO,I
      LDB ID,I
      CMB,INB 
      ADB A,I 
      SSB 
      JMP ERROR 
      LDA ID,I
      LDB AMT 
LOOP  ADA B,I 
      INB 
      ISZ POINT 
      JMP LOOP
      JMP JULIA,I 
ERROR CCA 
      JMP JULIA,I 
POINT NOP 
AMT   DEF *+1 
      DEC 0,31
FEBR  DEC 0,31,30,31,30,31
      DEC 31,30,31,30,31
D3    DEC 3 
D12   DEC 12
D28   DEC 28
MIN   DEC -1801 
MAX   DEC -2100 
D1900 DEC 1900
D2000 DEC 2000
      END 
      