ASMB,L
* 
* 
* 
* 
* 
* 
**************************************************************
* (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1978.  ALL RIGHTS    *
* RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED, RE- *
* PRODUCED, OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITH-  *
* OUT THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.  *
**************************************************************
* 
* 
* 
*      NAME: GFONT
*      SOURCE: 92840 - 18139
*      RELOC:  92840 - 16021
* 
* 
* 
************************************************************* 
      NAM GFONT,7 92840-16021 REV.2013 790904 
********************************************************************* 
* GFONT IS THE ASMB INTERFACE FOR THE SOFTWARE TEXT 
* GENERATION SUBROUTINE GFONT.
* 
*********************************************************************** 
      ENT GFONT 
      EXT PLTER,.OPTN,GFON1 
      EXT GASC1,GCHK
      EXT GFON3 
*     EXT GJUST     NOT CURRENTLY IMPLEMENTED.
********************************************************************* 
* ENTRY POINT FOR GFONT.
* CALL GFONT(IGCB,NAME,ISECU,ICR,IDCB)
* CALL GFONT(IGCB,0,0,0,IDCB) 
**********************************************************************
IAC   NOP 
IGCB  NOP 
NAME  NOP 
ISECU NOP 
ICR   NOP 
IDCB  NOP 
GFONT NOP 
      LDA GFONT 
      JSB .OPTN     .OPTN TRANSFERS PARAMETER ADDRESSES TO BUFFER IAC 
      DEF RTN0
      DEF IAC       START OF PARAMETER STORAGE AREA 
      DEF M6        NEGATIVE NUMBER OF PARAMETERS 
      DEF IDUMY     DONT NEED AN ACTION CODE
      DEF D5        NUMBER OF PARAMETERS .OPTN WILL TRANSFER
      DEF D0        NUMBER OF OPTIONAL PARAMETERS 
      DEF IDUMY     DUMMY ADDRESS OF OPTIONAL PARAMETERS
      DEF RETRN     .OPTN STUFFS RETURN ADDRESS INTO HERE 
RTN0  JMP GERR1     .OPTN'S ERROR RETURN POINT
********************************************************************
* .OPTN'S NORMAL RETURN POINT.
**************************************************************
* GRAPHICS LINK AND CHECK FOR SUSPENDED GCB.
* 
      JSB GCHK
      DEF RTNA
      DEF IGCB,I
      DEF ISUSP 
RTNA  LDA ISUSP 
      SZA 
      JMP RETRN,I 
****************************************************************
* CALL GASC1 TO TEST IF NAME IS A TEXT STRING FROM BASIC. 
* IF SO, BUMP THE PARAMETER ADDRESS BY 1. 
* 
      JSB GASC1 
      DEF RTN01 
      DEF NAME,I
      DEF IBASC 
* 
RTN01 LDA IBASC 
      SSA 
      ISZ NAME      BUMP THE ADDRESS IF THE STRING CAME FROM BASIC
***************************************************************** 
* CALL GFON1 TO PROCESS THE CALL. 
* 
      JSB GFON1     CALL GFON1 TO PROCESS 
      DEF RTN1      THE GFONT CALL. 
      DEF IAC,I 
      DEF IGCB,I
      DEF NAME,I
      DEF ISECU,I 
      DEF ICR,I 
      DEF IDCB,I
RTN1  NOP 
      JMP RETRN,I 
*************************************************************** 
* NOT ENOUGH PARAMETERS 
* 
GERR1 NOP           NOT ENOUGH PARAMETERS.
      JSB PLTER 
      DEF RTN11 
      DEF D95       TRANSLATES TO GPS 99 GFONT
      DEF IGCB
* 
RTN11 LDA NAME,I    IF NAME = 0, TURN 
      SZA           OFF SOFTWARE TEXT.
      JMP RETRN,I   ELSE RETURN IMMEDIATELY 
      JSB GFON3 
      DEF RTN21 
      DEF IGCB
      DEF IZERO 
RTN21 JMP RETRN,I 
* 
D95   DEC 95
IZERO DEC 0 
ISUSP DEC 0 
IBASC DEC 0 
M6    DEC -6
IDUMY NOP 
D5    DEC 5 
D0    DEC 0 
RETRN NOP           RETURN ADDRESS FOR JMP RETRN,I
      END GFONT 
                                                          