ASMB,R,L
* 
* 
* 
**************************************************************
* (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1978.  ALL RIGHTS    *
* RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED, RE- *
* PRODUCED, OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITH-  *
* OUT THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.  *
**************************************************************
* 
* 
* 
*      NAME:  PLOTR 
*      SOURCE:  92840 - 18005 
*      RELOC:  92840 - 16001
* 
* 
* 
************************************************************* 
* 
      NAM PLOTR,7  92840-16001  REV. 1819  780515 
* 
      EXT SETUP,PLTER,INDCK 
      EXT .OPTN 
      ENT PLOTR,GPON,.PLTR
* 
*     THIS IS THE INTERFACE MODULE FOR THE AGL COMMANDS PLOTR 
*     GPON
* 
* 
      SPC 3 
* 
*     CALLING SEQUENCE CALL PLOTR(ID,ACTION[,[,LUN,GCB],IOBUF,IOBL])
* 
*     LUN AND GCB REQUIRED FOR ACTION = 1 AND 4 
PLOTR NOP 
      ISZ .PLTR     SET FLAG FOR .OPTN
      LDA .40 
      STA ERCOD 
      LDA PLOTR 
      JSB .OPTN 
      DEF *+8 
      DEF PARM
      DEF M8        # OF LOCATIONS IN PARM BUFFER 
      DEF .1
      DEF .4        FOUR REQUIRED PARAMETERS
      DEF .2        OPTIONAL PARAMETERS (IOBUF,IOBL)
      DEF DZER0 
      DEF RETRN     USED TO SAVE RETURN ADDRESS 
      JMP CKPRM 
      LDB ACTON,I 
      CPB .1
      JMP ON
      CPB .4
      JMP ON
      JMP CKPRM 
ON    LDA IOBUF     CHECK TO SEE IF IOBUF AND IOBL
      CPA DZER0     SEE IF DEFAULT ADDRESS WAS SUBSTITUTED
      JMP CHNG      YES THEN IT MUST BE CHANGED 
      JMP IBLCK     CHECK ON IOBL LENGTH
CHNG  ADB M4        CHECK ON NUMBER OF PARAMTERS FOR PLOTR 1 OR 4 
      SZB 
      JMP CHNG1     ACTION = 1
      LDA DF1       CHANGE ACTION = 4 TO 1
      STA ACTON 
      JMP ERR8
CHNG1 LDA GCB       I O BUFFER WILL LIVE IN GCB 
      JSB INDCK     INDIRECT CHECK
      STA B         GCB(FWA) -> B 
      ADA GCIO      I O ADDRESS IN GCB
      ADB .5        6TH WORD OF GCB 
      STA B,I 
      LDA GCIL      IIO  LENGTH 
      INB 
      STA B,I 
      JMP ENTRY+1 
CKPRM STA CNTR
      LDB ACTON     ACTION PARAM PRESENT
      SZB,RSS 
      JMP ERROR 
      LDA B,I 
      SZA           ACTION = 0
*     JMP CHK3
*     CPA .3        ACTION = 3? (SUSPEND) 
*     JMP CHK3
*     CPA .2
*     JMP CHK3
      JMP ERR4
CHK3  LDA CNTR      MAKE SURE WE HAVE ENOUGH PARAMETERS 
      CPA M1
      JMP CHKGC 
      CPA .0
      JMP CHKGC 
      JMP ERROR 
CHKGC LDA GCB,I 
      CPA M99       MAKE SURE GCB IS LEGAL
      JMP ENTRY+1 
      JMP ER199 
IBLCK LDB GCB       PUT AWAY I/O ADDRESS IN GCB(6)
      JSB INDCK 
      ADB .5
      STA B,I 
      INB           NOW LENGTH
      LDA IOBL,I    MAKE SURE IOBL >=10 
      STA B,I 
      ADA M20 
      SSA,RSS 
      JMP ENTRY+1   POSITIVE OK 
      LDA DF1 
      STA ACTON 
      JMP ERR8
* 
* 
ERROR LDA PARM+1
      STA IGCB
      JSB PLTER 
      DEF RTNER 
      DEF ERCOD     PARAMETER ERROR 
IGCB  NOP 
RTNER CLA 
      STA .PLTR 
      LDA ERCOD 
      CPA .8
      JMP CHNG1 
      JMP RETRN,I 
* 
ERR4  LDA .4
      STA ERCOD 
      JMP ERROR 
* 
ERR8  LDA PARM,I
      CMA,INA 
      STA PARM,I
      JMP CHNG1 
* 
ER199 LDA .199
      STA ERCOD 
      JMP ERROR 
* 
      SKP 
* 
*     POWER ON CALL 
* 
GPON  NOP 
      LDA .67 
      STA ERCOD 
      LDA GPON
      JSB .OPTN 
      DEF GPRTN 
PADR  DEF PARM
      DEF M8
      DEF .2
      DEF .1        LEVEL 
      DEF .1        DEFAULT = 2 
      DEF DF2 
      DEF RETRN 
GPRTN JMP ERROR 
      JMP ENTRY+1 
      SPC 3 
* 
      SPC 3 
* 
* 
      SPC 3 
* 
*     CALL TO SETUP FUNCTIONAL MODULE 
* 
ENTRY JMP ERROR 
      CLA 
      STA .PLTR 
      JSB SETUP 
      DEF END 
PARM  NOP 
GCB   NOP 
ID    NOP 
ACTON NOP 
LUN   NOP 
IOBUF NOP 
IOBL  NOP 
END   JMP RETRN,I 
* 
      SPC 3 
* 
* 
* 
      SPC 3 
* 
* 
* 
B     EQU 1 
.4    OCT 4 
GCIO  DEC 105 
GCIL  DEC 25
.14   OCT 14
.5    DEC 5 
.0    OCT 0 
.1    OCT 1 
.2    OCT 2 
.3    OCT 3 
DZER0 DEF .0
      DEF .0
DF2   DEF .2
FRMFD DEF .14 
A     EQU 0 
M8    DEC -7
M20   DEC -20 
.67   DEC 67
.PLTR NOP 
.8    DEC 8 
.199  DEC 199 
DF1   DEF .1
.40   DEC 40
M1    OCT -1
M99   DEC -99 
M4    OCT -4
CNTR  NOP 
RETRN NOP 
ERCOD NOP 
* 
      END 
                                                                                                                                                                  