SPL,L,O,T,M 
      NAME ISA02(5)  !92413-16020A 760329 
!     SOURCE: 92413-18020 REV A 
!     RELOC:  92413-16020 REV A 
! 
! 
! 
! RETURN DIRECTLY TO MAIN 
! 
! 
      LET SWPRT BE LABEL,EXTERNAL 
ISA02:GOTO SWPRT
! 
! 
!     SOURCE:    92413-180XX
!     RELOC:     92413-160XX
! 
! 
! OUTRL 
! 
! OUTRL OUTPUTS THE BRANCH AND MNEMONIC TABLES IN RELOCATABLE 
! FORMAT. 
! 
! CALLING SEQUENCE IS: CALL OUTRL(NAM,ENT,EXT,DBL)
! 
! WHERE: NAM,ENT,EXT,DBL     ARE THE STRING ADDRESSES FOR 
!        EACH TABLE 
! 
! 
      LET OUTRL BE SUBROUTINE,GLOBAL
      LET INWS,WSAA BE PSEUDO,EXTERNAL,DIRECT 
      LET OUTLU,ENTW2,EXTW2,RBOID BE INTEGER,EXTERNAL 
      LET ENTIN,ENTEA,ENTOU,EXTIN,EXTEA,EXTOU,DBLIN,DBLEA,DBLOU,\ 
        OUTIT       BE SUBROUTINE,EXTERNAL,DIRECT 
      LET FREAD,FWRIT BE SUBROUTINE,EXTERNAL
      LET NEREC BE SUBROUTINE,DIRECT
      LET BUF BE INTEGER(4) 
      INITIALIZE BUFA TO @BUF 
      LET RBBUF BE INTEGER(20),EXTERNAL 
      LET ENDX BE INTEGER(5)
      INITIALIZE ENDX TO 4,2000K,120000K,0,0
      INITIALIZE END0 TO 0
      LET STPRG BE SUBROUTINE,EXTERNAL,DIRECT 
! 
! 
OUTRL:SUBROUTINE(NAM,ENT,EXT,DBL)GLOBAL 
! 
! 
      RBOID_OUTLU 
!OUTPUT NAME RECORD 
! 
      CALL NEREC(NAM) 
! 
!OUTPUT ENTRY RECORD
! 
      CALL ENTIN
      I_-3
      WHILE[I_I+4] DO[FOR J_0 TO 3 DO[BUF(J+1)_INWS(ENT,I+J)?\
        [GOTO OUT1]];.B._BUFA;CALL ENTEA] 
OUT1: .A._ENTW2 
      CALL ENTOU
! 
!OUTPUT EXTERN RECORD 
! 
      CALL EXTIN
      I_-2
      WHILE[I_I+3] DO[FOR J_0 TO 2 DO[BUF(J+1)_INWS(EXT,I+J)?\
        [GOTO OUT2]];.B._BUFA;CALL EXTEA] 
OUT2: .A._EXTW2 
      CALL EXTOU
! 
!OUTPUT DBL RECORD
! 
      .B._0                  !RELOCATION ADDRESS
      .A._1                  !RECORD TYPE PROGRAM RELOCATABLE 
      CALL DBLIN
      I_-1
      WHILE[I_I+2] DO[ J _INWS(DBL,I)?[GOTO OUT3];\ 
        BUF(1)_INWS(DBL,I+1);.A._J;.B._BUFA;CALL DBLEA] 
OUT3: CALL DBLOU
! 
!OUTPUT END RECORD
      WSAA(END0)_@ENDX
      CALL NEREC(END0)
      STPRG(END0) 
      RETURN
      END 
NEREC:SUBROUTINE(STR)DIRECT 
      I_0 
      WHILE[I_I+1] DO RBBUF(I)_INWS(STR,I)?[GOTO OUT0]
OUT0: RBBUF(7)_100001K
      CALL OUTIT
      RETURN
      END 
      END ISA02 
END$
          