SPL,L,O,T 
      NAME RTETG(3,90)
! 
! 
! 
! 
!   RTETG --------- CORE VERSION
! 
! 
!   RTETG IS AN INTERACTIVE TABLE CONFIGURATOR FOR RTE
! 
! SOURCE TAPE - 92413-18013 REV. A
! RELOC. TAPE - 92413-16013 REV. A
! 
! VERSION - JANUARY 1974 - T.A. SAPONAS 
! VERSION -   APRIL 1975 - T.A. LEUTHNER
! 
! 
!***************************************************************
! 
!   INITIALIZATION PHASE
! 
!***************************************************************
! 
      LET RBILU,CMDLU,CMCNT BE INTEGER,EXTERNAL 
      LET SPACE BE INTEGER(2) 
      INITIALIZE SPACE TO 1," " 
      LET BUFFR(60),OUTLU BE INTEGER,GLOBAL 
      LET C2313,C6940,CONST BE SUBROUTINE,EXTERNAL,DIRECT 
      LET WSAA BE PSEUDO,EXTERNAL,DIRECT
      LET STPRG BE SUBROUTINE,EXTERNAL,DIRECT 
      LET CMDIN BE SUBROUTINE,EXTERNAL
      LET NAM,EXTB,ENTM,ENTB,DBLM,DBLB BE INTEGER,GLOBAL
      LET HEADR BE INTEGER(18)
      INITIALIZE HEADR TO 33,"* 2313 AND 6940 TABLE GENERATOR *"
      LET PUNMS BE INTEGER(10)
      INITIALIZE PUNMS TO 17,"* TURN ON PUNCH *"
      LET TEARM BE INTEGER(16)
      INITIALIZE TEARM TO 29,"* TABLE GENERATION COMPLETE *"
      LET SYSIN,SYSPR,SYSPU,SYSOP BE INTEGER(4) 
      INITIALIZE SYSIN,SYSPR,SYSPU,SYSOP TO 5,"SYSIN ",5,"SYSPR ",\ 
        5,"SYSPU ",5,"SYSOP"
      LET FWRIT,FOPEN,FPAUS BE SUBROUTINE,EXTERNAL
      LET WRITE,LEADR,READ BE SUBROUTINE,DIRECT 
! 
! 
! 
! 
! 
RTETG:CALL FOPEN(RBILU,ERR,SYSIN,300K)
      CALL FOPEN(OUTLU,ERR,SYSPU,100K)
      CALL FOPEN(CMDLU,ERR,SYSOP,400K)
! 
      FRLST,NAM,EXTB,ENTM,ENTB,DBLM,DBLB_0
! 
! 
! 
      CALL WRITE(HEADR)     !HEADER MESSAGE 
! 
      CALL WRITE(PUNMS)    !TURN ON PUNCH MESSAGE 
! 
! 
! 
!     THIS MODULE INITIALIZES WORKSPACE IN MEMORY 
! 
      LET FRLST BE INTEGER,GLOBAL ! FREE WORKSPACE LIST POINTER 
      LET FIRST BE INTEGER,GLOBAL ! SMALLEST ADDRESS NOT USED 
      LET LAST  BE INTEGER,GLOBAL ! LARGEST  ADDRESS NOT USED 
      LET WKTOP BE INTEGER,GLOBAL ! LARGEST USABLE ADDRESS=7MOD8
      LET WKMIN BE INTEGER,GLOBAL ! SMALLEST ADDRESS EVER ALLOCATED 
! 
! 
      LAST,WKTOP,WKMIN_26677K 
      FIRST_LAST-5000K !WORK SPACE SET TO 5000K WORDS 
! 
! 
      CALL FWRIT(OUTLU,ERR,0,-1)  !WRITE LEADER 
      CALL LEADR  !WRITE LEADER 
! 
! 
      CALL C2313  !GENERATE 2313 TABLES 
      CALL C6940  !GENERATE 6949 TABLES 
      CALL CONST  !GENERATE CONFIG CONSTANTS
! 
! 
      CALL LEADR  !WRITE TRAILER
! 
      CALL WRITE(TEARM)     !TEAR OFF TAPE MESSAGE
      CALL FPAUS
      GO TO RTETG ! GO BACK TO BEGINNING
! 
! 
!WRITE A MESSAGE ROUTINE
! 
WRITE:SUBROUTINE(BUF)DIRECT,GLOBAL
      CALL FWRIT(CMDLU,ERR,SPACE) 
      CALL FWRIT(CMDLU,ERR,BUF) 
      RETURN
      END 
! 
!INPUT COMMAND
! 
READ: SUBROUTINE FEXIT,DIRECT,GLOBAL
      STPRG(NAM)
      CALL CMDIN(BUFFR(2),ERR)
      BUFFR(1)_(CMCNT+1)/2   !WORD COUNT
      IF BUFFR(2)="/E" THEN FRETURN 
      WSAA(NAM)_@BUFFR
      RETURN
      END READ
! 
! WRITE OUT LEADER
! 
LEADR:SUBROUTINE DIRECT 
      CALL FWRIT(OUTLU,ERR,0,-1)
      RETURN
      END 
      END RTETG 
END$
                                                                                                                                                                  