ASMB,R,L,C
      NAM DCODE,7  92101-16015 REV.1614, 760330 
      ENT DCODE 
      EXT .DIO.,.IOR.,.DTA.,.ENTR 
* 
*********************************************** 
* 
*      CONVERT BINARY TO ASCII (FORMATTED)
* 
*      XXXX CALL DCODE(V,A$,B$) 
*        WHERE:  V =VALUE TO CONVERT
*                A$=RESULTING STRING
*                B$=FORMAT STRING 
* 
*      CONVERT ASCII TO BINARY (FORMATTED)
* 
*      XXXX CALL DCODE(A$,V,B$) 
*        WHERE:  A$=STRING TO CONVERT 
*                V= RESULTING VALUE 
*                B$=FORMAT STRING 
* 
*      SOURCE: 92101-18015
*      RELOC:  92101-16015
* 
*********************************************** 
      SUP 
* 
P1    DEF *           STRING OR VARIABLE
P2    DEF *           VARIABLE OR STRING
P3    DEF *           FORMAT STRING 
* 
DCODE NOP 
      JSB .ENTR       FETCH PARMS 
       DEF P1 
      LDA P1,I        DETERMINE CONV.DIRECTION
      CLB,INB 
      SZA,RSS         0?
      CLB              YES. 
      RAL,SLA         NEG.#?
      CLB              YES. 
      SSA             NORMALIZED? 
      CLB              YES. 
      STB TYPE
      LDA P1
      SZB,RSS         POST ADDR 
      LDA P2           OF STRING
      INA               BUFFER
      STA QF1 
      LDA P3,I        CHECK FORMAT STMT 
      SZA,RSS          0? 
      JMP QF0         YES, FREE FIELD 
      LDA P3          NO, POST ADDR 
      INA               OF FORMAT 
QF0   STA QF2            STATEMENT
      CLA 
      JSB .DIO.       INIT CONVERSION 
QF1    DEF *          =DATA BUFR
QF2    DEF *          =FORMAT STMT
       DEF QFX        =END OF LIST
      LDB TYPE
      SZB             DIRECTION?
      JMP QF3 
* 
      DLD P1,I        *DO BINARY TO ASCII 
      JSB .IOR. 
      JSB .DTA. 
      JMP QFX 
* 
QF3   JSB .IOR.       *DO ASCII TO BINARY 
      DST P2,I
QFX   JMP DCODE,I        & LEAVE
* 
* 
TYPE  BSS 1 
* 
SIZE  EQU * 
      END 
                                                                          