ASMB,R
      NAM HLP02,7  92080-1X357 REV.2026  800408         
* 
*     SOURCE 92080-18357
* 
      SPC 2 
**************************************************************
* (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1978.  ALL RIGHTS    *
* RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED, RE- *
* PRODUCED, OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITH-  *
* OUT THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.  *
**************************************************************
      SPC 2 
      SUP 
* 
**********************************************************************
*                                                                    *
*                   THIS SUBROUTINE IS USED TO PRINT A HELP MESSAGE  *
*  ON LINES 23 AND 24 OF THE TGP SCREENS                             *
*                   THE CURSOR IS POSITIONEDAT THE FIELD WHERE THE   *
*  HELP SOFT KEY WAS PRESSED.                                        *
*                   THIS SUBROUTINE IS CALLED WITH TWO PARAMETERS :  *
*                                                                    *
*           - PAR#1 =  HELP  MESSAGE # TO OUTPUT                     *
*           - PAR#2 =  HELP  FIELD # ON THE SCREEN                   *
*                                                                    *
**********************************************************************
* 
* 
      ENT HLP02     ENTRY POINT 
      EXT EXEC
      EXT .ENTR 
      EXT &REMP 
      EXT &MVW
      COM ILU       TERM. LU
* 
*  GET CALLING PARAMETERS 
* 
NMESS NOP           FIRST PARM. ADDRESS 
NOF   NOP           SECD. PARM. ADDRESS 
HLP02 NOP           ENTRY POINT 
      JSB .ENTR     SUBR. TO GET
      DEF NMESS     PARM. ADDRESS 
* 
* 
*  MOVE HELP  MESSAGE IN OUTPUT BUFFER
* 
      LDA NMESS,I   GET ERROR MESSAGE # 
      SZA,RSS       IS 0 ?
*     JMP HLPC      YES NO MESSAGE
      LDA =B7       YES, GIVE GENERAL HELP MESSAGE
      ADA AMES0     COMPUTE MESSAGE 
      LDB A,I       ADDRESS 
      STB P1        STORE IT
      CMB,INB       MINUS STARTING ADDRESS
      STB IST        OF MESSAGE IN IST
      INA            COMPUTE NEXT MESSAGE 
      LDA A,I       STARTING ADDRESS
      ADA IST       COMPUTE MESSAGE LENGTH
      STA P2        STORE IT
      LDA P1        BUFFER SOURCE ADDRESS 
      LDB BUFAD     BUFFER DEST ADDRESS 
      JSB &MVW      MOVE WORDS
P2    NOP           BUFFER LENGTH 
* 
      LDB BUFAD     COMPUTE CURRENT 
      ADB P2        ADDRESS IN OUTPUT BUFFER
* 
      LDA BUF1      INCLUDE FORMAT ON 
      STA B,I       IN OUTPUT BUFFER
      INB           INCREMENT ADDRESS IN OUT. BUFFER
* 
      LDA D.10      COMPUTE OUTPUT BUFFER LENGTH
      ADA P2
      STA ILN       STORE IT
      JMP HLPB
* 
HLPC  LDA D.10
      STA ILN 
      LDB BUFAD 
      LDA BUF1
      STA B,I 
      INB 
* 
* NOW INCLUDE TABS IN BUFFER
* 
HLPB  LDA NOF,I     GET HELP  FIELD # 
      CPA D.1       IS 1 ?
      JMP HLPA      YES NO TABS 
      ADA .D1       DECREMENT 
      STA P5        STORE # OF FIELD
      ADA ILN       INCREMENT OUTPUT BUFFER 
      STA ILN       LENGTH
      LDA P5        GET FIELD # 
      CMA,INA       MAKE IT NEG 
      STA P4
      LDA B 
      STB P2        SORE B
      LDB TAB 
      JSB &REMP     MOVE TABS IN BUFFER 
P4    NOP 
* 
      LDB P2        RESTORE B 
      LDA P5        INCREMENT ADDRESS IN
      ADB A 
* 
HLPA  LDA BUFA2 
      JSB &MVW      INCLUDE KEY ENABLE
      DEC 3         IN BUFFER 
* 
      JSB EXEC      WRITE MESSAGE 
      DEF *+5 
      DEF D.2 
      DEF ILU 
      DEF BUF 
      DEF ILN 
* 
      JMP HLP02,I 
* 
* 
*  BUFFER DATA
* 
BUF   BYT 33,130,33,46,141,62,62,162,60,103  FORMAT OFF:POS.CURSOR
      BYT 33,112    CLEAR DISPLAY 
BUFER BSS 140       MESSAGE BUFFER
* 
* STORAGE , CONSTANTS ..
* 
BUFAD DEF BUFER     BUFF. ADDRESS 
BUFA2 DEF BUF2
A     EQU 0         A REGISTER
B     EQU 1         B REGISTER
IST   NOP 
P1    NOP           SOURCE ADDRESS BUFFER ADDRESS 
P5    NOP 
ILN   NOP             BUFFER LENGTH 
TAB   BYT 33,111
BUF1  BYT 33,127    FORMAT ON 
BUF2  BYT 0,0,0,33,142,137                   ERASE h ,KEY. ENABLE 
.D1   DEC -1
D.10  DEC 10
D.1   DEC 1 
D.2   DEC 2 
* 
*  MESSAGE ADDRESS
* 
AMES0 DEF AMES1-1 
AMES1 DEF MES1
      DEF MES2
      DEF MES3
      DEF MES4
      DEF MES5
      DEF MES6
      DEF MES7
      DEF MES8
* 
*  MESSAGE STORAGE
* 
MES1  BYT 33,46,144,112 
      ASC 22, Enter the SFK number corresponding to the n 
      ASC 18,umbering scheme on the Data Capture
      BYT 33,46,144,112 
      ASC  5, terminal. 
      BYT 33,46,141,53,67,60,103,0
* 
MES2  BYT 33,46,144,112 
      ASC 22, Enter a value if the key is used to generat 
      ASC 18,e a character string. Note that a
      BYT 33,46,144,112 
      ASC 22, key cannot be both a value and a function k 
      ASC  2,ey.
      BYT 33,46,141,53,67,66,103,0
* 
MES3  BYT 33,46,144,112 
      ASC 22, If no KEY VALUE was specified, enter the fu 
      ASC 18,nction abbreviation corresponding to 
      BYT 33,46,144,112 
      ASC 22, the function assigned to this key. All but
      ASC 13,PREFIX act as terminators. 
      BYT 33,46,141,53,65,64,103,0
* 
MES4  BYT 33,46,144,112 
      ASC 22, Enter an X if this key is to complete the i 
      ASC 18,nput operation (act as terminator) 
      BYT 33,46,144,112 
      ASC 22, when pressed. All functions except PREFIX a 
      ASC  8,re terminators.
      BYT 33,46,141,53,66,64,103,0
* 
MES5  BYT 33,46,144,112 
      ASC 22, Enter an optional label if desired. It is u 
      ASC 18,sed to provide a label printout for
      BYT 33,46,144,112 
      ASC 22, the key assigned at the completion of TGP.
      BYT 33,46,141,53,63,66,103,0
* 
MES6  BYT 33,46,144,112 
      ASC 22, A maximum of 20 questions (U and M question 
      ASC 18,s combined) may be defined per 
      BYT 33,46,144,112 
      ASC 22, transaction. Each question label is limited 
      ASC  9, to 12 characters. 
      BYT 33,46,141,53,66,62,103,0
* 
MES7  BYT 33,46,144,112 
      ASC 22, Please reference the DATACAP/1000 Reference 
      ASC 18, Manual for further information. 
      BYT 33,46,144,112 
      ASC  1, 
      BYT 33,46,141,53,67,70,103,0
* 
MES8  ASC  1,-1 
* 
* 
      END HLP02 
                                                                                                                                                                                                                                      