ASMB,R,Q,C
      NAM SRV.L   92076-16004  REV 2040  800423 
* 
      ENT SRV.L 
* 
      EXT SRQ.T,TRPNT,RMPAR,$LUTA,PNAME,IMESS,EXEC,IPUT 
      EXT IXGET 
* 
********************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1980.  ALL RIGHTS       *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,        *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT  *
*  * THE PROIR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.         *
********************************************************************
* 
*     RELOC:  92076-16004 
*     SOURCE: 92076-18004 
*     PGMR:   T.A.L.
* 
* 
A     EQU 0 
B     EQU 1 
* 
SRV.L JSB RMPAR 
       DEF *+2
       DEF CPAR1
      JSB IXGET     GET DVT TABLE ENTRY ADDRESS 
       DEF *+2
       DEF LUTA 
      STA B         SAVE IT 
      LDA CPAR1     LOAD FIRST PARAMETER
      AND B77       MASK LU 
      STA LU        SAVE IT 
      CMA,INA,SZA,RSS CONVERT TO NEG. LU, ZERO? 
      JMP LOSE      YES, LOSE 
      ADA B         ADD TO LAST CONFIGURED LU 
      SSA           VALID LU? 
      JMP LOSE      NO, EXIT WITH ERROR MESSAGE 
      LDA M16       TABLE COUNTER 
      STA COUNT 
      LDB SRQ.T     GET SRQ.T ADDRESS 
      CLA,INA       SET TRAP
      STA TRAP       TO ONE 
SRV.1 LDA B,I       GET LU FROM ARV.L TABLE 
      CPA LU        TABLE LU = INTERRUPTING LU? 
      JMP SRV.2      YES, SAVE OPTIONAL VALUE & STATUS
      ADB .3         NO, INDEX TO NEXT LU ADDR. 
      ISZ TRAP      INCREMENT TRAP #. 
      ISZ COUNT     ARV.L TABLE EXAUSTED? 
      JMP SRV.1      NO, GET NEXT LU IN TABLE 
      JMP LOSE       YES, LOSE
SRV.2 INB           INDEX TO OPTIONAL VALUE ADDR
      STB ARVAD      IN ARV.L TABLE 
      JSB IPUT      PUT OPTIONAL VALUE 
       DEF *+3       IN ARV.L TABLE 
       DEF ARVAD
       DEF CPAR1+1
      ISZ ARVAD     INDEX TO INTERRUPT STATUS ADDR
      JSB IPUT      PUT INTERRUPT STATUS
       DEF *+3       IN ARV.L TABLE 
       DEF ARVAD
       DEF CPAR1+2
      LDA TRAP      GET TRAP #
      JSB TRPNT 
      JMP LOSE      ERROR 
      JMP BYE       NORMAL RETURN 
* 
.3    DEC 3 
M16   DEC -16 
B77   OCT 77
TRAP  BSS 1 
COUNT BSS 1 
LU    BSS 1 
ARVAD BSS 1 
CPAR1 BSS 5 
LUTA  DEF $LUTA 
* 
LOSE  JSB PNAME 
       DEF *+2
       DEF MSGA+6   GET PROGRAM NAME
      JSB IMESS 
       DEF *+4
       DEF .2       WRITE 
       DEF MSGA     "ILL RQ-HPIB" 
       DEF .13      MESSAGE 
* 
BYE   JSB EXEC
       DEF *+2      AND QUIT
       DEF .6 
* 
.2    DEC 2 
.6    DEC 6 
.13   DEC 13
      SUP 
MSGA  ASC 13,ILL RQ-HPIB XXXXXXABORTED
* 
      END SRV.L 
                                                                                          