ASMB,R
* 
* 
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1980.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
* 
*           NAME:   EDIT1 
*           SOURCE: 92074-18005 
*           RELOC:  PART OF 92074-12001 
*           PGMR:   J.D.J.
* 
* 
      NAM EDIT1,5,51 92074-1X005 REV.2034 800818
      ENT EDIT1 
      ENT ED%RU 
      EXT .ENTR 
      EXT ERR 
      EXT SRTN,PGRUN
      EXT CSTRP 
      EXT ECCNT 
* 
A     EQU 0 
B     EQU 1 
* 
************************
* 
EDIT1 JMP SRTN      JUMP BACK TO MAIN 
* 
* 
******************************
*  RUN SUBROUTINE CALLER
PR    BSS 3         2 PARAMATERS
ED%RU NOP 
      JSB .ENTR     GET PARAMS
      DEF PR
      JSB CSTRP     STRIP COMMAS , BLANKS 
      JMP ERR 
      LDA ECCNT 
      INA 
      STA TEMP
      JSB PGRUN 
      DEF RUN.R 
      DEF PR,I
      DEF PR+1,I
      DEF TEMP
RUN.R EQU * 
      JMP ED%RU,I    RETURN 
* 
TEMP  BSS 1 
* 
      SKP 
      HED PTFME,7 2015 WHH Put FMGR err in SCB
      ENT PTFME 
      EXT .ENTR,PTERR,.DIV
* 
*     FMGR ERROR CODE PRINTER 
*     CALL IS 
*         CALL PTFME(<INTEGER-ERROR-CODE>)
* 
ERROR BSS 1 
PTFME BSS 1 
      JSB .ENTR 
      DEF ERROR 
      LDA ERROR,I   GET ABSOLUTE VALUE OF ERROR 
      LDB 0 
      SSA 
      CMA,INA 
      STA ABS 
      LDA MSG1      DETERMINE SPACE OR MINUS
      SSB 
      LDA MSG2
      STA BUF+2 
      LDA ABS       GET HIGH DIGIT OF ERROR CODE
      CLB 
      JSB .DIV
      DEF D100
      STB ABS 
      ADA BUF+2 
      STA BUF+2 
      LDA ABS 
      CLB 
      JSB .DIV
      DEF D10 
      ALF,ALF 
      ADA 1 
      ADA MSG3
      STA BUF+3 
      JSB PTERR     PUT INTO SCB
      DEF *+2 
      DEF BUF 
      JMP PTFME,I   RETURN
MSG1  ASC 1, 0
MSG2  ASC 1,-0
MSG3  ASC 1,00
D100  DEC 100 
D10   DEC 10
BUF   ASC 4,FMGRxxxx
ABS   BSS 1 
      END EDIT1 
                                                              