ASMB,Q,C
*     NAME:   EQTRQ 
*     SOURCE: 92071-18257 
*     RELOC:  92071-1X257 
*     PGMR:   HLC,DJN 
* 
* 
*  **************************************************************** 
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1980.  ALL RIGHTS      * 
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,       * 
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT * 
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.        * 
*  **************************************************************** 
* 
* 
      NAM EQTRQ,7  92071-1X257  REV.2041  800806
      ENT EQTRQ 
      EXT $ID#,$LIBR,$RQRT,$SJP,.XLD,.XST 
      EXT $STAT,$ERAB,.XLA,.XSA,$SUSP,$PVCN 
* 
A     EQU 0 
B     EQU 1 
* 
* 
*     PURPOSE: TO LOCK ALL THE LU'S ON A GIVEN INTERFACE
*              TO THE CALLING PROGRAM.  USED FOR DIAGNOSTICS
*              OR OTHER PROGRAMS THAT MODIFY THE STATE OF 
*              A MULTI-DEVICE CONTROLLER SUCH THAT IT SHOULD
*              NOT BE USED BY OTHER PROGRAMS. 
* 
*     DUMMY ROUTINE FOR SYSTEMS THAT DO NOT SUPPORT TRUE
*     INTERFACE LOCKING CAPABILITY. 
* 
EQTRQ NOP 
      JSB .XLD      THE CALLER SHOULD BE THE ONLY PROGRAM 
      DEF $ID#
      CPA =D1 
      JMP OK
* 
*     TOO MANY ID SEGMENTS, COULD BE TROUBLE! 
* 
      JSB $LIBR     TURN OFF MEMORY PROTECT 
      NOP 
      CCA 
      ADA EQTRQ 
      STA CALAD     ADDRESS OF JSB EQTRQ
      JSB .XLD      SAVE CALLING ADDRESS AT $SUSP 
      DEF $SUSP     FOR ERAB
      STA 1 
      LDA CALAD 
      JSB .XST
      DEF 1,I 
* 
      DLD EQTRQ,I 
      INA 
      JSB .XST      SAVE POINT OF RETURN FOR 'NO ABORT' 
      DEF $RQRT 
* 
      LDB B,I       GET THE OPTION
      JSB .XLA      GET ADDRESS OF STAT WORD
      DEF $STAT 
      STA AT$ST     SAVE ADDRESS
      JSB .XLA
      DEF A,I       GET STAT WORD 
      AND =B137777  CLEAR THE 'NO ABORT' BIT
      RBL 
      SSB 
      IOR =B40000   SET THE 'NO ABORT' BIT
      JSB .XSA      REPLACE STAT WORD 
      DEF AT$ST,I 
      CLA           CLEAR PRIVILEDGE NEST LEVEL 
      JSB .XST
      DEF $PVCN 
* 
      LDA =AEQ
      LDB =D2 
      JSB $SJP      ABORT CALLER
      DEF $ERAB 
* 
* 
* 
OK    DLD EQTRQ,I 
      LDB B,I       GET THE OPTION
      RBL 
      SSB 
      INA           BUMP TO GOOD RETURN 
      STA EQTRQ 
* 
      CLA 
      CLB 
      JMP EQTRQ,I 
* 
AT$ST NOP           STORES ADDRESS OF STAT WORD LOCALLY 
CALAD NOP           ADDRESS OF JSB EQTRQ
      END 
      