ASMB,R,L,C
      HED (FMP) CRLK: LOCK AND UNLOCK DISC CARTRIDGE
*     NAME:   CRLK
*     SOURCE: 92071-18167 
*     RELOC:  92071-16167 
*     PGMR:   E.D.B.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1980.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
      NAM CRLK,7 98061-1X167 REV.2041 800806
* 
      ENT CRLK, CRULK 
* 
      EXT CLD.R, .P1, .P2, .R1
      EXT .ENTR 
      SUP 
      SKP 
* 
*     DESCRIPTION 
* 
*     THESE ROUTINES REQUEST A LOCK OR UNLOCK OF A DISC CARTRIDGE 
*     FROM THE FMP. 
* 
*     CRLK CALLING SEQUENCE:
* 
*     IERR = CRLK(CRN)
* 
*     WHERE:
* 
*     IERR    WILL BE THE ERROR RETURN CODE 
* 
*     CRN     IS THE +CRN/-LU OF THE CARTRIDGE TO BE LOCKED 
* 
*     POSSIBLE ERRORS:
* 
*     CRULK CALLING SEQUENCE: 
* 
*     IERR = CRULK(CRN) 
* 
*     WHERE:
* 
*     IERR    WILL BE THE ERROR RETURN CODE 
* 
*     CRN     IS THE +CRN/-LU OF THE CARTRIDGE TO BE UNLOCKED 
* 
*     POSSIBLE ERRORS:
* 
      SKP 
* 
*     ENTRY 
* 
CRLK  NOP 
      LDA .3
      LDB CRLK
      JMP SETUP 
* 
CRULK NOP 
      LDA .5
      LDB CRULK 
* 
SETUP STA REQST 
      STB DRLK
      CLA 
      STA CRN 
      JMP DRLK+1
* 
CRN   NOP           +CRN, -LU OF DISC TO LOCK 
* 
DRLK  NOP 
      JSB .ENTR 
      DEF CRN 
* 
      LDA CRN 
      SZA,RSS 
      JMP ER10      NOT ENOUGH PARAMETERS 
      SKP 
* 
*   SET UP FOR CALL TO D.RTR
* 
      LDA REQST     FETCH THE REQUEST CODE
      STA .P1       SET IT FOR CALL 
* 
      LDA CRN,I 
      STA .P2       SET DISK ID 
* 
      JSB CLD.R 
* 
      LDA .R1       PUT ERROR INTO A-REG
      JMP DRLK,I    RETURN
* 
ER10  LDA N10       NOT ENOUGH PARAMETERS 
      JMP DRLK,I    RETURN
* 
*     STORAGE AREA
* 
.3    DEC 3 
.5    DEC 5 
* 
N10   DEC -10 
* 
REQST NOP 
* 
A     EQU 0 
B     EQU 1 
* 
END   EQU * 
* 
      END 
                                                                      