ASMB,R,Q,C
*     NAME:   ERL.. 
*     SOURCE: 92071-18148 
*     RELOC:  92071-1X148 
*     PGMR:   HLC 
* 
* 
*  **************************************************************** 
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1980.  ALL RIGHTS      * 
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,       * 
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT * 
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.        * 
*  **************************************************************** 
* 
* 
      NAM ERL..,0  92071-1X148  REV.2041  800613
      ENT $ERMG,$SYMG,$STMG 
      ENT $.ERL,$SMSG 
      ENT $SY#,$XS3   
*     ENT $$ERL     MUST NOT BE DEFINED 
* 
      EXT $XEQ,$A,$B,$PVCN
      EXT $SUSP,$RQRT,$ZZZZ,$TREM 
      EXT $STAT,$XQT,$IOFL
      EXT $LDRS,$LDAB,$TIM1 
A     EQU 0 
B     EQU 1 
* 
*     ABORT WITH ERROR MESSAGE
* 
$ERMG NOP 
      STA A.
      LDA $XQT
      SZA,RSS 
      JMP HALT      ABORTIVE ERROR -- NO USER PROGRAM EXECUTING 
      LDA $STAT,I 
      RAL 
      CLE,SSA       IF THE NO-ABORT BIT IS CLEAR
      CPB =A           OR B IS BLANK
      JMP ABORT           ABORT HIM 
* 
      LDA A.
      DST $A,I
      CCA 
      ADA $RQRT 
      STA $SUSP,I 
      JMP $ERMG,I 
* 
* 
ABORT RAR 
      IOR =B400 
      STA $STAT,I 
      STB B.
* 
      LDB $XQT
      JSB $TREM     REMOVE FROM TIME LIST 
* 
      DLD A.
      DST $TIM1,I   SAVE ERROR CODE TO PASS TO FATHER 
* 
      LDB $XQT
      CPB $LDRS 
      JMP LDAB      CURRENTLY BEING LOADED OR SWAPPED 
      LDA $STAT,I 
      AND =B77
      CPB =B2 
      RSS           I/O SUSPENDED, DO NOT ABORT YET 
      STB $ZZZZ     SET TO ABORT
FLUSH LDA $XQT
      JSB $IOFL     FLUSH PENDING I/O REQUESTS
      JMP $ERMG,I 
* 
* 
LDAB  JSB $LDAB     ABORT THE TRANSFER
      JMP FLUSH 
* 
* 
A.    NOP 
B.    NOP 
* 
* 
HALT  LDA A.
      HLT 3         HALT WITH ERROR CODE IN A AND B 
      JMP HALT      NO RECOVERY 
* 
$SYMG EQU *         PRINT SYSTEM MESSAGE
$SMSG EQU *         PRINT SYSTEM MESSAGE
      NOP 
      ISZ *-1 
      JMP *-2,I 
* 
* 
* 
$XS3  EQU * 
$SY#  EQU * 
      BSS 12
* 
* 
* 
$STMG JMP $XEQ
* 
$.ERL DEC -1        DUMMY MODULE
* 
      END 
  