ASMB,R,L,C
      HED (FMGR) PR.IT: PRINT LIST OF PROGRAM NAMES 
*     NAME:   PR.IT 
*     SOURCE: 92071-18069 
*     RELOC:  92071-16069 
*     PGMR:   M.L.K.
*     MOD:    E.D.B.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1980.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
      NAM PR.IT,7 92071-1X069 REV.2041 800630 
* 
      ENT PR.IT 
* 
      EXT P.NAM, FM.ER
      EXT .ENTR 
      SUP 
      SKP 
* 
* 
*     DESCRIPTION 
* 
*     THIS ROUTINE PRINTS A LIST OF PROGRAM NAMES FROM
*     AN LIST OF ID SEGMENT NUMBERS.  IT IS USED
*     IN CONJUNCTION WITH SY.TR TO LIST ACTIVE SYSTEM PROGRAMS. 
      SKP 
* 
*     ENTRY 
* 
ARRAY NOP 
ASIZE NOP 
* 
PR.IT NOP 
      JSB .ENTR     SET UP PARAMETERS 
      DEF ARRAY 
* 
      LDA ASIZE,I   GET ARRAY SIZE
      CMA,INA        SET NEGATIVE 
      SSA,RSS       IF IT WAS NEGATIVE OR 0,
      CCA            THEN ASSUME ONE
      STA ASIZE     NOW SAVE IT 
* 
LOOP  LDA ARRAY,I   GET THE NEXT ENTRY ADDRESS
      SZA,RSS       IF ZERO,
      JMP PR.IT,I    THEN EXIT
* 
      SSA           IF NEGATIVE,
      JMP SWAP       THEN PRINT 'SWAP FILE' 
* 
      JSB P.NAM     CONVERT ID SEGMENT NUMBER 
      DEF *+3        INTO PROGRAM NAME
      DEF BUF 
      DEF ARRAY,I 
* 
      JSB FM.ER     WRITE OUT THE NAME
      DEF *+4 
      DEF .1
      DEF BUF 
      DEF .3
      JMP NEXT      GO DO NEXT ENTRY
* 
SWAP  JSB FM.ER     WRITE OUT 'SWAP FILE' 
      DEF *+4 
      DEF .1
      DEF SWPBF 
      DEF .6
* 
NEXT  ISZ ARRAY     INCREMENT TO NEXT ELEMENT 
      ISZ ASIZE     IF NOT END OF ARRAY,
      JMP LOOP       THEN WRITE NEXT
      JMP PR.IT,I    ELSE EXIT
      SKP 
* 
*     STORAGE AREA
* 
.1    DEC 1 
.3    DEC 3 
.6    DEC 6 
* 
SWPBF ASC 6,SWAP AREA 
* 
BUF   BSS 3         NAME BUFFER 
* 
A     EQU 0 
B     EQU 1 
* 
END   EQU * 
* 
      END 
                                                                          