ASMB,R,L,C
      HED (FMP) CLD.R: CALL DIRECTORY MANAGER (D.RTR) 
*     NAME:   CLD.R 
*     SOURCE: 92071-18055 
*     RELOC:  92071-16055 
*     PGMR:   M.L.K.
*     MOD:    E.D.B.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1980.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
      NAM CLD.R,7 92071-1X055 REV.2041 800627 
* 
      ENT CLD.R 
      ENT .P1, .P2, .P3, .P4, .P5, .P6, .P7, .P8, .P9 
      ENT .P6A, .P6B, .P6C
      ENT .R1, .R2, .R3, .R4, .R5 
* 
      EXT GTOPN 
      EXT EXEC, RMPAR 
      SUP 
      SKP 
* 
*     DESCRIPTION 
* 
*     CLD.R PROVIDES A CENTRAL CALLING POINT
*     FOR D.RTR (THE DISC DIRECTORY MANAGER)
* 
*     GLOBAL PARAMETERS:
*     .P1-.P9       INPUT PARAMETERS TO D.RTR 
*     .R1-.R5       OUTPUT PARAMETERS FROM D.RTR
*     .S1-.S6       OUTPUT STRING PARAMETERS FROM D.RTR 
      SKP 
* 
*     ENTRY 
* 
CLD.R NOP 
      JSB GTOPN     GET CURRENT OPEN FLAG 
      DEF *+1 
      STA .P0       STORE IN ID PARAMETER 
* 
      JSB EXEC      SCHEDULE D.RTR
      DEF *+10       QUEUED WITH WAIT 
      DEF NAB23       AND NO ABORT BIT SET
      DEF NAME
      DEF .P1       SEND INPUT PARAMETERS VIA THIS
      DEF .P2 
      DEF .P3 
      DEF .P4 
      DEF .P5 
      DEF .P0       SEND AUXILLARY INPUT PARAMETERS AS STRING 
      DEF .12       LENGTH OF AUXILLARY INPUT PARAMETER BUFFER
      JMP WHY?      EXEC FAILED! WHY? 
* 
      JSB RMPAR     GET RETURN PARAMETERS 
      DEF *+2        VIA RMPAR
      DEF .R1         INTO RETURN PARAMETER BUFFER
* 
      LDA .R1       GET ERROR RETURN CODE 
      CPA B100K     IF D.RTR ABORTED, 
      RSS            THEN INDICATE ERROR
      JMP CLD.R,I   SUCCESS RETURN
* 
WHY?  LDA N102      WHY DID EXEC ABORT? 
      STA .R1 
      JMP CLD.R,I   JUST RETURN FOR NOW 
      SKP 
* 
*     STORAGE AREA
* 
NAME  ASC 3,D.RTR   D.RTR'S NAME IN ASCII 
NAB23 OCT 100027    DECIMAL 23 WITH ABORT BIT SET (BIT 15)
* 
.12   DEC 12        FOR INPUT PARAM LENGTH
* 
N102  DEC -102      FOR ERROR 
* 
B100K OCT 100000    ABORT RETURN CODE 
* 
*     EXTERNAL PARAMETER STORAGE AREA 
* 
.P0   NOP 
.P1   NOP 
.P2   NOP 
.P3   NOP 
.P4   NOP 
.P5   NOP 
.P6   NOP 
      NOP 
      NOP 
.P7   NOP 
.P8   NOP 
.P9   NOP 
* 
.P6A  EQU .P6 
.P6B  EQU .P6+1 
.P6C  EQU .P6+2 
* 
.R1   NOP 
.R2   NOP 
.R3   NOP 
.R4   NOP 
.R5   NOP 
* 
A     EQU 0 
B     EQU 1 
* 
END   EQU * 
* 
      END 
                  