ASMB,R,L,C
      HED (FMGR) SY.EX: SYSTEM COMMAND AND EXIT ACTION ROUTINES 
*     NAME:   SY.EX 
*     SOURCE: 92071-18034 
*     RELOC:  92071-16034 
*     PGMR:   M.L.K.
*     MOD:    E.D.B.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1980.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
      NAM SY.EX,7 92071-1X034 REV.2041 800715 
* 
      ENT SY.., COMM, EX..
* 
      EXT C.BUF, CAM.I, CAM.O, ECH, O.BUF 
      EXT MVW 
      EXT CLOSE 
      EXT .ENTR, MESSS, EXEC
      SUP 
      SKP 
* 
*     DESCRIPTION 
* 
*     SY.. PASSES A COMMAND TO RTE-L TO BE EXECUTED 
* 
*     COMM IGNORES A COMMENT LINE 
* 
*     EX.. EXITS FMGR 
* 
      SKP 
* 
*     SYSTEM COMMAND ACTION ROUTINE 
* 
SY..  NOP 
      JSB .ENTR     GET RETURN ADDRESS
      DEF SY..
* 
      LDA ECH       FETCH COMMAND LENGTH (IN WORDS) 
      ALS            CONVERT TO BYTES 
      STA SYN         AND SAVE IT FOR MESSS 
* 
      JSB MVW       MOVE COMMAND BUFFER 
      DEF *+4        INTO TEMPORARY BUFFER
      DEF C.BUF 
      DEF O.BUF 
      DEF ECH 
* 
      JSB MESSS     PASS COMMAND TO SYSTEM
      DEF *+3 
      DEF O.BUF     BUFFER ADDRESS
      DEF SYN       BYTE COUNT
* 
      CMA,INA,SZA,RSS IF NO RESPONSE
      JMP SY..,I    THEN WE ARE ALL DONE
* 
*     PRINT RESPONSE
* 
      ARS           CONVERT RESPONSE LENGTH TO WORDS
      STA SYN        AND SAVE FOR EXEC
* 
      JSB EXEC     PRINT THE RESPONSE ON LOG
      DEF *+5 
      DEF .2
      DEF CAM.O 
      DEF O.BUF 
      DEF SYN 
* 
      JMP SY..,I    RETURN
      SKP 
* 
*     COMMENT ACTION ROUTINE
* 
COMM  NOP 
      JSB .ENTR     GET RETURN ADDRESS
      DEF COMM
* 
      CLA           NO ERROR INTENDED 
      JMP COMM,I    RETURN
      SKP 
* 
*     EXIT ACTION ROUTINE 
* 
EX..  NOP 
      JSB .ENTR     GET RETURN ADDRESS
      DEF EX..
* 
      JSB CLOSE     CLOSE INPUT FILE/DEVICE 
      DEF *+2 
      DEF CAM.I 
* 
      JSB EXEC      TERMINATE 
      DEF *+2 
      DEF .6
      SKP 
* 
*     STORAGE AREA
* 
.2    DEC 2 
.6    DEC 6 
* 
SYN   NOP           MESSAGE LENGTH
* 
A     EQU 0 
B     EQU 1 
* 
END   EQU * 
* 
      END 
                            