ASMB,R,Q,C
*     NAME:   IFBIT 
*     SOURCE: 92070-18274 
*     RELOC:  92070-1X274 
*     PGMR:   HLC 
* 
* 
*  **************************************************************** 
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS      * 
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,       * 
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT * 
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.        * 
*  **************************************************************** 
* 
* 
      NAM IFBIT,7  92070-1X274  REV.1941  790613
      ENT IFBIT 
      EXT EXEC
* 
* 
*     PURPOSE:  TO DETERMINE IF AN LU IS ASSIGNED TO  
*               THE BIT BUCKET. 
* 
*     CALLING SEQUENCE: 
*       I=IFBIT(LU) 
*         I: -1 IF BIT BUCKET 
*             0 IF NOT BIT BUCKET 
* 
*    OR 
* 
*       IF(IFBIT(LU))10,20
*         GOES TO 10 IF BIT BUCKET
*         GOES TO 20 IF NOT BIT BUCKET
* 
A     EQU 0 
B     EQU 1 
* 
* 
IFBIT NOP 
      DLD IFBIT,I 
      LDB B,I 
      STB LU        LU NUMBER 
      STA IFBIT     RETURN ADDRESS
* 
      JSB EXEC      STATUS REQUEST
      DEF *+5 
      DEF D13NA     NO ABORT
      DEF LU
      DEF TYPE
      DEF CODE
      JMP NO        NOT A VALID LU
      LDA CODE
      AND =B77  
      SZA,RSS 
      CCA,RSS       SELECT CODE = 0, RETURN 'TRUE'
NO    CLA 
      JMP IFBIT,I   EXIT
* 
TYPE  NOP 
CODE  NOP 
LU    NOP 
D13NA OCT 100015
* 
      END 
                            