ASMB,R,Q,C
*     NAME:   XQTIM 
*     SOURCE: 92070-18271 
*     RELOC:  92070-16271 
*     PGMR:   HLC 
* 
* 
*  **************************************************************** 
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS      * 
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,       * 
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT * 
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.        * 
*  **************************************************************** 
* 
* 
      NAM XQTIM,7  92070-1X271  REV.1941  790709
      ENT XQTIM 
      EXT EXEC,.ENTR,OPEN,IDRPL,CLOSE 
* 
A     EQU 0 
B     EQU 1 
* 
* 
XQTIM NOP 
      LDA DZERO 
      STA NAME      SET UP DEFAULT PARAMETERS 
      STA SEC 
      STA CR
      STA RES 
      STA MULT
      STA TMARY 
      LDA XQTIM     SAVE RETURN ADDRESS 
      STA XQT..       IN DUMMY ENTRY POINT
      JMP XQT..+1 
* 
* 
* 
DCB   NOP 
ERR   NOP 
NAME  NOP 
SEC   NOP 
CR    NOP 
RES   NOP 
MULT  NOP 
TMARY NOP 
* 
XQT.. NOP 
      JSB .ENTR     PASS PARAMETER ADDRESSES
      DEF DCB 
      LDA TMARY 
      INA 
      STA MIN 
      INA 
      STA SECS
      INA 
      STA MSECS 
* 
TRY   JSB EXEC      TRY TO SCHEDULE THE PROGRAM 
      DEF RTN1
      DEF TMSCH     CODE 12, NO ABORT 
      DEF NAME,I    PROGRAM NAME
      DEF RES,I 
      DEF MULT,I
      DEF TMARY,I 
MIN   NOP 
SECS  NOP 
MSECS NOP 
RTN1  JMP FAIL      SCHEDULE REQUEST FAILED 
* 
      CLA 
EROUT STA ERR,I     SAVE FMP ERROR CODE 
      JMP XQT..,I 
* 
* 
* 
* 
FAIL  LDA B         CHECK FOR 'SC05' ERROR
      CPA =A05
      RSS 
      JMP EROUT     STRANGE SYSTEM ERROR MESSAGE
* 
      JSB OPEN      OPEN THE TYPE 6 FILE
      DEF RTN2
      DEF DCB,I 
      DEF ERR,I     ERROR CODE
      DEF NAME,I    FILE NAME 
      DEF D1        NON-EXCLUSIVE OPEN
      DEF SEC,I 
      DEF CR,I
RTN2  SSA 
      JMP EROUT     OPEN FAILED 
* 
      JSB IDRPL     'RP' THE PROGRAM
      DEF RTN3
      DEF DCB,I 
      DEF ERR,I     ERROR CODE
      DEF NAME,I    PROGRAM NAME
DZERO DEF ZERO      TEMPORARY 
RTN3  JSB CLOSE     CLOSE THE FILE
      DEF *+2 
      DEF DCB,I 
      SSA 
      JMP EROUT     CLOSE ERROR 
* 
      LDA ERR,I     CHECK FOR IDRPL ERROR 
      SSA 
      JMP EROUT 
      JMP TRY       SUCCESSFUL 'RP', TRY AGAIN
* 
* 
* 
* 
D1    DEC 1 
TMSCH OCT 100014    CODE 12, NO ABORT 
ZERO  DEC 0,0,0,0 
      END 
                                