ASMB,Q,C
*     NAME:   EQTRQ 
*     SOURCE: 92070-18257 
*     RELOC:  92070-1X257 
*     PGMR:   HLC 
* 
* 
*  **************************************************************** 
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS      * 
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,       * 
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT * 
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.        * 
*  **************************************************************** 
* 
* 
      NAM EQTRQ,7  92070-1X257  REV.1941  790613
      ENT EQTRQ 
      EXT $ID#,$LIBR,$SUSP,$RQRT
      EXT $STAT,$ERAB 
* 
A     EQU 0 
B     EQU 1 
* 
* 
*     PURPOSE: TO LOCK ALL THE LU'S ON A GIVEN INTERFACE
*              TO THE CALLING PROGRAM.  USED FOR DIAGNOSTICS
*              OR OTHER PROGRAMS THAT MODIFY THE STATE OF 
*              A MULTI-DEVICE CONTROLLER SUCH THAT IT SHOULD
*              NOT BE USED BY OTHER PROGRAMS. 
* 
*     DUMMY ROUTINE FOR SYSTEMS THAT DO NOT SUPPORT TRUE
*     INTERFACE LOCKING CAPABILITY. 
* 
EQTRQ NOP 
      CLA,INA 
      CPA $ID#      THE CALLER SHOULD BE THE ONLY PROGRAM 
      JMP OK
* 
*     TOO MANY ID SEGMENTS, COULD BE TROUBLE! 
* 
      JSB $LIBR     TURN OFF MEMORY PROTECT 
      NOP 
      CCA 
      ADA EQTRQ 
      STA $SUSP,I   ADDRESS OF CALL 
* 
      DLD EQTRQ,I 
      INA 
      STA $RQRT     SAVE POINT OF RETURN FOR 'NO ABORT' 
* 
      LDB B,I       GET THE OPTION
      LDA $STAT,I 
      AND =B137777  CLEAR THE 'NO ABORT' BIT
      RBL 
      SSB 
      IOR =B40000   SET THE 'NO ABORT' BIT
      STA $STAT,I 
* 
      LDA =AEQ
      LDB =D2 
      JMP $ERAB     ABORT CALLER
* 
* 
* 
OK    DLD EQTRQ,I 
      LDB B,I       GET THE OPTION
      RBL 
      SSB 
      INA           BUMP TO GOOD RETURN 
      STA EQTRQ 
* 
      CLA 
      CLB 
      JMP EQTRQ,I 
* 
      END 
                                                                                      