ASMB,R,Q,C
*     NAME:   SEGLD 
*     SOURCE: 92070-18217 
*     RELOC:  92070-1X217 
*     PGMR:   HLC 
* 
* 
*  **************************************************************** 
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS      * 
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,       * 
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT * 
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.        * 
*  **************************************************************** 
* 
* 
      NAM SEGLD,7  92070-1X217  REV.1941  790607
      ENT SEGLD,SEGRT 
* 
      EXT .ENTR,EXEC
* 
* 
A     EQU 0 
B     EQU 1 
* 
* 
SEGLD NOP           TRUE ENTRY POINT
      LDA DZERO 
      STA P1
      STA P2
      STA P3
      STA P4
      STA P5
      LDA SEGLD 
      STA SEG.. 
      JMP SEG..+1 
* 
* 
D8NA  OCT 100010
DZERO DEF ZERO
ZERO  DEC 0 
* 
NAME  NOP 
IERR  NOP 
P1    NOP 
P2    NOP 
P3    NOP 
P4    NOP 
P5    NOP 
SEG.. NOP           PSEUDO ENTRY POINT
      JSB .ENTR 
      DEF NAME
      JSB EXEC      EXEC SEGMENT LOAD CALL
      DEF RTN 
      DEF D8NA      NO ABORT
      DEF NAME,I
      DEF P1,I
      DEF P2,I
      DEF P3,I
      DEF P4,I
      DEF P5,I
RTN   LDA =D-6      FAKE A 'FILE NOT FOUND' ERROR 
EXIT  STA IERR,I
      JMP SEG..,I 
* 
* 
* 
* 
SEGRT NOP           RETURN FROM SEGMENT 
      CLA 
      JMP EXIT
* 
      END 
                                                                  