ASMB,R,Q,C
*     NAME:   .CBT  
*     SOURCE: 92070-18167 
*     RELOC:  92070-1X167 
*     PGMR:   HLC 
* 
* 
*  **************************************************************** 
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS      * 
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,       * 
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT * 
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.        * 
*  **************************************************************** 
* 
* 
      NAM .CBT,6  92070-1X167  REV.1941  790926 
      ENT .CBT
      EXT .ZPRV 
* 
A     EQU 0 
B     EQU 1 
* 
* 
.CBT  NOP           COMPARE BYTES 
      JSB .ZPRV     SHARABLE ROUTINE
      DEF EXIT
      STA .A.       SAVE A REGISTER 
      ERA,ALS 
      SOC 
      INA 
      STA .EO.      SAVE E AND O
* 
      LDA .CBT,I    ADDRESS OF COUNT
      ISZ .CBT
      LDA A,I       WORD COUNT
      SZA,RSS 
      JMP CBTEX     ZERO, EXIT
      ADA B 
      STA .B.       FINAL B REGISTER VALUE
* 
* 
* 
CBTLP LDA .A. 
      CLE,ERA 
      LDA A,I       WORD CONTAINING BYTE 1
      SEZ,RSS 
      ALF,ALF 
      AND =B377 
      STA CHAR      BYTE 1, RIGHT JUSTIFIED 
* 
      CLE,ERB 
      LDA B,I       WORD CONTAINING BYTE 2
      SEZ,RSS 
      ALF,ALF 
      AND =B377     BYTE 2, RIGHT JUSTIFIED 
      ELB 
      CPA CHAR
      INB,RSS       BUMP POINTER 2
      JMP LT.GT     DOES NOT COMPARE
      ISZ .A.       BUMP POINTER 1
      CPB .B.       CHECK FOR DONE
      JMP CBTEX 
      JMP CBTLP     NEXT
* 
* 
LT.GT ISZ .CBT      SKIP OVER ZERO WORD 
      ISZ .CBT      SKIP OVER NORMAL RETURN 
      CMA,INA 
      ADA CHAR      SUBTRACT 2 FROM 1 
      SSA,RSS 
      ISZ .CBT      1 LARGER THAN 2 
      LDB .B. 
* 
CBTEX LDA .EO.
      CLO           RESET OVERFLOW
      SLA,ELA 
      STO 
      LDA .A. 
EXIT  JMP .CBT,I
      DEF .CBT
* 
* 
CHAR  NOP 
.A.   NOP 
.B.   NOP 
.EO.  NOP 
      END 
            