ASMB,R,L,C
*     NAME:   TEST
*     SOURCE: 92070-18117 
*     RELOC:  92070-16117 
*     PGMR:   D.J.W.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1976.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
* 
      NAM TEST,7  92070-1X117  REV.1941  790904 
* 
* 
*  THE TEST SUBROUTINE IS USED TO CHECK OUT AND PROCESS THE OPTION
*  PARAMETERS.  THE SUBROUTINE SETS A FEW FLAGS FOR LATER USE IN
*  LOADING THE PROGRAM.  AS THE FLAGS COME IN THEY ARE SET,  THE
*  FLAGS ARE NOT CHECKED AND USED UNTIL ALL INFORMATION HAS BEEN
*  READ FROM THE RUN STRING OR COMMAND FILE AND THE LOAD IS TO
*  COMMENCE.
* 
*        FLAG       VALUE         MEANING 
*        ------     ------        ------- 
* 
*        CPL.L        0           BASE PAGE LINKING 
*                     1           CURRENT PAGE LINKING
*        COMTP       -1           NO COMMON, OR LOCAL COMMON
*                     2           SYSTEM COMMON 
*        PL.ST        0           NO LISTING
*                     1           LIST NAME AND BOUNDS
*                     2           LIST ENTRIES ALSO 
*        DBFLG        0           NO DBUGR
*                     1           DBUGR APPENDED
* 
* 
* 
*  CALLING SEQUENCE:  B-REG = MENUMONIC OPTION PARAMETER
*                     JSB TEST
* 
*  ON RETURN:         P+1:  ERROR RETURN, A-REG = FMP ERROR 
*                     P+2:  NO ERROR
* 
      ENT TEST
      EXT COMTP,CPL.L,DBFLG,PL.ST,PROGT,STBND 
* 
A     EQU 0 
B     EQU 1 
* 
BLANK ASC 1,
P2    DEC 2 
* 
TEST  NOP 
      SZB           IF NOTHING ENTERED
      CPB BLANK     (I.E.  OPTION EQUALS ASCII BLANK) 
      JMP TESE      THEN SIMPLY RETURN
      STB OPP 
      LDA LDOPC     GET START OF OPCODE TABLE 
      STA XTEMP     AND SAVE FOR SEARCH 
      LDA LDJMP     GET JUMP ADDRESS TABLE
      STA YTEMP     AND SAVE FOR JUMP TO APPROPRIATE PROCESSOR
      CLA           CLEAR A FOR FLAG VALUE
LOOPR CPB XTEMP,I   IS THIS THE CODE
      JMP YTEMP,I   YES, SO JUMP TO THE APPROPRIATE PROCESSOR 
      ISZ XTEMP     NO, SO BUMP THE 
      ISZ YTEMP     TWO POINTERS AND
      JMP LOOPR     TRY AGAIN.
* 
LDOPC DEF *+1       ADDRESS OF START OF TABLE 
      ASC  8,BGRTBPCPSCNLLEDB 
OPP   NOP 
LDJMP DEF *+1,I     HEAD OF JUMP TABLE
      DEF BG        BACKGROUND PROGRAM
      DEF RT        REALTIME PROGRAM
      DEF BP        BASE PAGE LINKING 
      DEF CP        CURRENT PAGE LINKING
      DEF SC        SYSTEM COMMON 
      DEF NL        NO LIST 
      DEF LE        LIST BOUNDS AND ENTRIES 
      DEF DB        APPEND THE DBUG ROUTINE 
      DEF OPERR     INPUT ERROR PROCESSING
RT    INA 
BG    STA PROGT 
      JSB STBND 
      JMP TESE
CP    INA           CURRENT PAGE LINKING
BP    STA CPL.L     BASE PAGE LINKING 
      JMP TESE
SC    LDA P2        SYSTEM COMMON SPECIFIED 
      STA COMTP     SAVE COMMON TYPE
      JMP TESE
LE    LDA PL.ST     LIST ENTRIES
      IOR P2
      STA PL.ST 
      JMP TESE
NL    STA PL.ST 
      JMP TESE
DB    INA 
      STA DBFLG 
TESE  ISZ TEST
* 
OPERR JMP TEST,I
* 
* 
XTEMP NOP 
YTEMP NOP 
      END 
                                                                                                                                          