ASMB,R,L,C
*     NAME:   POST
*     SOURCE: 92070-18050 
*     RELOC:  92070-16050 
*     PGMR:   G.A.A.
*     MOD:    G.L.M 
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
* 
      NAM POST,7  92070-1X050  REV.1941  790709 
* 
      HED POST - CLEAR THE DCB BUFFER 
      ENT POST
      EXT .ENTR,R/W$,GTOPN
* 
* 
*     THE POST ROUTINE CLEARS THE DCB BUFFER BY POSTING ANY 
*     DATA THAT NEEDS TO BE WRITTEN ON THE DISC.  IT WILL IN
*     ALL CASES CLEAR THE INCORE FLAG SO THE NEXT FILE
*     ACCESS WILL FORCE A DISC READ.
* 
*     POST IS TO BE USE WITH THE RN LOCK FEATURE AS 
*     FOLLOWS:
* 
*     POST
*     LOCK
* 
*     DO YOUR THING 
* 
*     POST
*     UNLOCK
* 
*     CALLING SEQUENCE: 
* 
*     CALL POST(DCB,ER) 
* 
*     WHERE:
* 
*     DCB IS THE DCB ARRAY
*     ER  IS THE OPTIONAL RETURN ERROR CODE 
* 
* 
POST  NOP 
      CLA           PRE-SET 
      STA ER           CALL 
      LDA POST            PARMS 
      STA DOST      MOVE PARM ADDRESS 
      JMP DOST+1    TO DUMMY ENTRY POINT
* 
DCB   NOP 
ER    NOP 
DOST  NOP           ENTRY POINT 
      JSB .ENTR     GET THE PRAM ADDRESSES
      DEF DCB 
      JSB GTOPN     GET CURRENT OPEN FLAG 
      DEF *+1 
      LDB DCB       GET DCB ADDRESS AND POINT 
      ADB D9          TO IT'S OPEN FLAG 
      CPA B,I       IS IT THE SAME AS CURRENT?
      JMP OK        YES, IT'S OPEN! 
* 
      LDA N11       NO   RETURN ERROR 
EREX  STA ER,I      SET THE ERROR CODE
      CLB           SET ER ADDRESS
      STB ER        FOR NEXT TIME 
      JMP DOST,I    EXIT
* 
OK    LDB DCB       GET THE DCB ADDRESS 
      CLE           SET E FOR WRITE 
      JSB R/W$      GO POST THE BUFFER
      JMP EREX      DISC ERROR GO EXIT
* 
      CLA           ALL IS GOOD SET OK ERROR CODE 
      JMP EREX      AND GO EXIT 
* 
D9    DEC 9 
N11   DEC -11 
A     EQU 0 
B     EQU 1 
      END 
          