ASMB,R,L,C
*     NAME:   IDCBS 
*     SOURCE: 92070-18044 
*     RELOC:  92070-16044 
*     PGMR:   G.A.A.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
* 
      NAM IDCBS,7  92070-1X044  REV.1941  790709
* 
      HED IDCBS 
      ENT IDCBS 
      EXT .ENTR,GTOPN 
* 
IDCB  NOP 
IDCBS NOP 
      JSB .ENTR     FETCH PARAM ADDR
      DEF IDCB
      LDB IDCB
      ADB D9        OFFSET TO OPEN FLAG 
      JSB GTOPN     GET CURRENT OPEN FLAG 
      DEF *+1 
      CPA B,I       IS IT THE SAME AS IN DCB? 
      JMP OPEND     YES, ITS OPEN 
      LDA MD11
      JMP EXIT      EXIT ERROR -11
* 
OPEND ADB MD7       BACK UP TO WORD 2 
      LDA B,I 
      CPA D1        FILE TYPE 1?
      CLA           OR 0? 
      SZA,RSS       YES, SET BUFFER SIZE=0
* 
      JMP RTNOK 
* 
      ADB D5        ADVANCE TO WORD 7 
      LDA B,I       GET SIZE WORD 
      ARS,ALR        BUT CLEAR BITS 0 AND 15
RTNOK ADA D16       ADD 16 TO BUFFER SIZE 
EXIT  JMP IDCBS,I   RETURN DCB SIZE IN A
* 
A     EQU 0 
B     EQU 1 
D1    DEC 1 
D5    DEC 5 
D9    DEC 9 
D16   DEC 16
MD11  DEC -11 
MD7   DEC -7
* 
      END 
                    