ASMB,R,L,C
      HED FMGR1 
*     NAME:   FMGR1 
*     SOURCE: 92070-18003 
*     RELOC:  92070-16003 
*     PGMR:   G.A.A.       MOD. M.L.K.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
      NAM FMGR1,5  92070-1X003  REV.1941  790712
      EXT PARS.,.PARS,REA.C 
      EXT NO.RD,.ENTR,PAR.R,SEG.R,TR..,.IDAD
      EXT INT.,ECHF.,MSS.,IFBRK 
      SUP 
FMGR1 STA .IDAD 
      LDA PARSE    SET THE PARSE ROUTINE ADDRESS
      STA PARS.    IN THE MAINS ADDRESS WORD
      JMP PAR.R    RETURN TO THE MAIN 
      SPC 2 
PAR   NOP          READ AND PARSE ENTRY POINT 
      JSB .ENTR 
      DEF PAR      FETCH RETURN ADDRESS 
      JSB IFBRK     CHECK FOR BREAK PENDING 
      DEF *+1 
      SZA,RSS       IF NO BREAK 
      JMP PAR1      SKIP MESSAGE
* 
      JSB MSS.      ELSE SEND THE BREAK MESSAGE 
      DEF *+2          AND TRANSFER TO LOG DEVICE 
      DEF ZERO
* 
PAR1  LDA NO.RD    IF NO READ FLAG SET
      SZA           THEN
      JMP PAR2     BY PASS THE READ CALL
* 
      JSB REA.C    CALL TO READ A COMMAND 
      DEF *+1 
      CCA           SET THE ECHO NOT DONE FLAG
      STA ECHF. 
      JSB .PARS     PARSE THE COMMAND 
      DEF *+1 
      JMP PAR,I     AND RETURN
* 
PAR2  CLB          CLEAR THE NO READ CALL FLAG
      STB NO.RD 
      STB ECHF.     DON'T ECHO INTERNAL CALLS 
      SSA,RSS 
      JMP TRLD
* 
      CLB,INB       SET TO INTERACTIVE INPUT
      LDA INT.      SAVE THE TTY FLAG 
      STB INT.      SET IT FOR NOW
      STA TMPM
PARS  JSB .PARS    PARS THE COMMAND 
      DEF *+1 
      LDA TMPM      RESTORE THE TTY FLAG
      STA INT.
      JMP PAR,I    RETURN TO THE MAIN TO CALL THE SEGMENT 
* 
TRLD  LDA TR
      JMP SEG.R 
* 
      DEC -2
TMPM  NOP 
TR    DEF * 
      DEF TR..      TR+1
ZERO  NOP           TR+4
PARSE DEF PAR       TR+5
A     EQU 0 
B     EQU 1 
      ORG * 
      END FMGR1 
                            