ASMB,L,C
      HED RMCLN SUBROUTINE FOR RECOV
      NAM RMCLN,7 92069-1X167 REV.2040 800730 
* 
* 
******************************************************************* 
* (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979. ALL RIGHTS RESERVED.
* NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED, REPRODUCED, OR
* TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT THE PRIOR WRITTEN
* CONSENT OF HEWLETT-PACKARD COMPANY. 
******************************************************************* 
* 
* 
*     SOURCE:    92069-18167
*     RELOC:     92069-1X167
* 
*     PRGMR:     CEJ
* 
* 
******************************************************************* 
* 
* 
* 
*  DS/1000 AND RDBA STANDARD EQUATES FOR REQUEST BUFFER.
* 
#STR  EQU 1         STREAM WORD 
#SEQ  EQU 2         SEQUENCE NUMBER 
#SRC  EQU 3         SOURCE NODE NUMBER
#DST  EQU 4         DESTINATION NODE NUMBER 
* 
RBIDX EQU 5         RDBA INDEX
RBMOD DEC 5         RDBA MODE 
* 
#EC2  EQU 6         ERROR CODE WORD 2 ON REPLY
* 
*** 
* 
A     EQU 0 
B     EQU 1 
* 
      ENT RMCLN 
      EXT #NODE,.ENTR,.MVW,D65MS
* 
PNAME NOP 
PNODE NOP 
ERROR NOP 
* 
RMCLN NOP 
      JSB .ENTR 
       DEF PNAME
* 
      LDA D10       SET UP REQUEST BUFFER:
      STA RQBUF+#STR  STREAM = 10 
      LDA #NODE 
      STA RQBUF+#DST   DESTINATION NODE = LOCAL NODE
* 
      CCA 
      STA RQBUF+RBIDX  RDBA INDEX = -1
      LDB RQBUF 
      ADB RBMOD       MODE AND INFO WORDS = THE NAME
      LDA PNAME         OF THE MASTER PROGRAM TO
      JSB .MVW          CLEAN-UP AFTER AND ITS NODE 
       DEF D3           NUMBER
       DEC 0
      LDA PNODE,I 
      STA B,I 
* 
      JSB D65MS     ASK D65MS TO ROUTE THE REQUEST
       DEF *+9        TO RDBAM FOR US.
       DEF CONWD
       DEF RQBUF,I
       DEF D9 
       DEF D0       THERE IS NO DATA WITH EITHER
       DEF D0         THE REQUEST OR REPLY. 
       DEF D0 
       DEF D7 
       DEF D0 
* 
      CCA,RSS       ERROR RETURN
      LDA RQBUF+#EC2  NORMAL RETURN 
      STA ERROR,I 
      JMP RMCLN,I 
* 
D0    DEC 0 
D3    DEC 3 
D7    DEC 7 
D9    DEC 9 
D10   DEC 10
* 
CONWD OCT 100000
* 
RQBUF DEF *+1 
      BSS 31
      END 
                                                                                      