ASMB
      NAM FMERR,7 92069-16061 REV.1912 790209 
* 
* 
**************************************************************
* (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS    *
* RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED, RE- *
* PRODUCED, OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITH-  *
* OUT THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.  *
**************************************************************
* 
* 
*     SOURCE:    92069-18118
*     RELOC:     92069-16060
* 
* 
************************************************************* 
* 
* 
* 
*     ENTRY POINTS AND EXTERNS
* 
      ENT FMERR 
* 
* 
      EXT ERIO,.ENTR,CITA 
* 
      SUP PRESS LISTING 
* 
*     CALLING SEQUENCE: 
* 
*          CALL FMERR(FMP ERROR #,LOGICAL UNIT #) 
* 
*              WHERE:  ERROR # IS NEG # RETURNED BY FMP 
*                      LOG UNIT # IS THE DEVICE THE ERROR MESSAGE 
*                        IS TO BE PRINTED ON
* 
* 
* 
* 
* 
ERNUM NOP 
LU    NOP 
FMERR NOP 
      JSB .ENTR 
      DEF ERNUM 
* 
      LDA ERNUM,I   GET ERROR NUMBER
      STA LCNTR     SAVE ERROR NUMBER FOR COUNTER 
      LDB FMESA     GET ADDRESS OF FMP ERRORS 
PRMS1 LDA 1,I     GET LENGTH OF MESSAGE 
      INB          MOVE PNTR TO MESSAGE 
      ISZ LCNTR   INDEX ERROR CNTR, IS IT = 0?
      RSS          NO, MOVE PNTR TO NEXT MESSG
      JMP PRMS2     YES - GO PRINT MESSAGE
      SLA         IF CHAR COUNT ODD,
      INA          MAKE EVEN
      ARS           CONVERT TO WORDS
      ADB 0          MOVE PNTR TO NEXT MESSG
* 
* 
* 
      LDA FMEND            IS THIS THIS THE LAST MESSAGE? 
      CMA,INA 
      ADA 1 
      SSA 
      JMP PRMS1        NO, GO GET NEXT MESSAGE
* 
PRMS3 JSB CITA       CONVERT ERROR CODE 
      DEF *+3 
      DEF ERNUM,I 
      DEF FMNO
* 
      LDB FMEND 
      LDA 1,I 
      INB 
* 
PRMS2 SZA,RSS 
      JMP PRMS3 
* 
      STB BUF       SET UP MESSAGE ADDRESS
      CMA,INA 
      STA IL        SET UP MESSAGE LENGTH 
* 
      LDA LU,I
      IOR B200
      STA LIST
      JSB ERIO      PRINT 
      DEF *+5 
      DEF .2          THE ERROR 
      DEF LIST
      DEF BUF,I         MESSAGE 
      DEF IL
* 
      JMP FMERR,I 
* 
* 
.2    DEC 2 
B200  OCT 200 
LIST  NOP 
LCNTR NOP           MESSAGE COUNTER 
BUF   NOP           ADDRESS OF MESSAGE
IL    NOP           LENGTH OF MESSAGE 
*********************** 
*                     * 
* ERROR MESSAGE TABLE * 
*                     * 
*********************** 
* 
FMESA DEF *+1 
      DEC 10
      ASC 5, DISC DOWN
      DEC 15
      ASC 8, DUPLICATE NAME 
      DEC 0 
      DEC 39
      ASC 20, MORE THAN 32, 767 RECORDS IN TYPE 2 FILE
      DEC 38
      ASC 19, READ OR WRITE TO A RECORD NOT WRITTEN 
      DEC 15
      ASC 8, FILE NOT FOUND 
      DEC 52
      ASC 26, INVALID SECURITY CODE OR ILLEGAL WRITE ON LU 2 OR 3 
      DEC 50
      ASC 25, FILE CURRENTLY OPEN OR EXCLUSIVE OR LOCK REJECTED 
      DEC 0 
      DEC 0 
      DEC 13
      ASC 7, DCB NOT OPEN 
      DEC 26
      ASC 13, SOF OR EOF READ OR SENSED 
      DEC 17
      ASC 9, CARTRIDGE LOCKED 
      DEC 15
      ASC 8, DIRECTORY FULL 
      DEC 13
      ASC 7, ILLEGAL NAME 
      DEC 25
      ASC 13, ILLEGAL TYPE OR SIZE = 0
      DEC 32
      ASC 16, ILLEGAL READ OR WRITE ON TYPE 0 
      DEC 11
      ASC 6, ILLEGAL LU 
      DEC 30
      ASC 15, ILLEGAL ACCESS TO SYSTEM DISC 
      DEC 18
      ASC 9, ILLEGAL ACCESS TO LU 
      DEC 23
      ASC 12, ILLEGAL DESTINATION LU
      DEC 0 
      DEC 0 
      DEC 0 
      DEC 0 
      DEC 0 
      DEC 0 
      DEC 0 
      DEC 0 
      DEC 30
      ASC 15, VALUE TOO LARGE FOR PARAMETER 
      DEC 0 
      DEC 25
      ASC 13, DISC CARTRIDGE NOT FOUND
      DEC 34
      ASC 17, NOT ENOUGH ROOM ON DISC CARTRIDGE 
      DEC 0 
      DEC 0 
      DEC 0 
      DEC 0 
      DEC 0 
      DEC 26
      ASC 13, CONFLICT IN SST DEFINITION
      DEC 20
      ASC 10, LU NOT FOUND IN SST 
      DEC 0 
      DEC 0 
      DEC 0 
      DEC 0 
      DEC 0 
      DEC 25
      ASC 13, GREATER THAN 255 EXTENTS
FMLST DEC 18
      ASC 6, ERROR NO.
FMNO  ASC 3,XXXXXX
* 
FMEND DEF FMLST 
* 
      END 
                                                      