ASMB,R,L,C
      HED MAG. TAPE FUNCTION REQUESTS 
* 
*     NAME:   MAGTP 
*     SOURCE: 92068-18020 
*     RELOC:  PART OF 92067-16268 AND 92067-16035 
*     PGMR:   R.A.G.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1980.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
      NAM MAGTP,7 92068-1X020 REV.2013 750701 
      ENT IEOF,IERR,IEOT,IWRDS,LOCAL,ISOT,RWSTB 
      EXT .ENTR,EXEC
      SKP 
UNIT. NOP           UNIT-REFERENCE NUMBER PARAMETER.
IEOF  NOP           ENTRY POINT.
      JSB .ENTR     "CALL" WITH ONE(1) PARAMETER. 
      DEF UNIT. 
      LDA UNIT.,I   LOAD THE UNIT-REFERENCE NUMBER. 
      LDB DSTCD     LOAD DYNAMIC STATUS CODE
      JSB STAT.     GO GET THE UNIT STATUS. 
      ALF,CLE,ALF   SHIFT THE "EOF" BIT TO 15.
      JMP IEOF,I    RETURN. 
      SPC 2 
.UNIT NOP           UNIT-REFERENCE NUMBER PARAMETER.
IERR  NOP           ENTRY POINT.
      JSB .ENTR     "CALL" WITH ONE(1) PARAMETER. 
      DEF .UNIT 
      LDA .UNIT,I   LOAD THE UNIT-REFERENCE NUMBER. 
      LDB DSTCD     LOAD DYNAMIC STATUS CODE
      JSB STAT.     GO GET THE UNIT STATUS. 
      AND =B000022  SAVE THE ERROR BITS ONLY. 
      CCE,SZA       WERE THERE ANY ERRORS?
      ELA,CLE,RAR   YES, SO MAKE "A" NEGATIVE.
      JMP IERR,I    NO, RETURN. 
      SPC 2 
U.5   NOP           UNIT-REFERENCE NUMBER PARAMETER.
IEOT  NOP           ENTRY POINT.
      JSB .ENTR     "CALL" WITH ONE(1) PARAMETER. 
      DEF U.5 
      LDA U.5,I     LOAD THE UNIT-REFERENCE NUMBER. 
      LDB DSTCD     LOAD DYNAMIC STATUS CODE
      JSB STAT.     GO GET THE UNIT STATUS. 
      ALF,CLE,ALF   SHIFT THE "EOT" BIT TO 15.
      RAL,CLE,RAL   SHIFT THE "EOT" BIT TO 15.
      JMP IEOT,I    RETURN. 
      SPC 2 
UNITI NOP           UNIT-REFERENCE NUMBER PARAMETER.
IWRDS NOP           ENTRY POINT.
      JSB .ENTR     "CALL" WITH ONE(1) PARAMETER. 
      DEF UNITI 
      LDA UNITI,I   LOAD THE UNIT-REFERENCE NUMBER. 
      STA REQST     LOGICAL UNIT
      JSB EXEC      I/O STATUS
      DEF *+5 
      DEF STATC     STATUS REQUEST CODE 
      DEF REQST 
      DEF STAT.     DUMMY 
      DEF STAT.     DUMMY 
A     EQU 00000B    DEFINES THE ADDRESS OF "A". 
      STB A         STORE THE LOG IN "A" FOR RETURN.
      ELA,CLE,ERA   REMOVE THE MODE FLAG. 
      JMP IWRDS,I   RETURN. 
      SPC 2 
UN.RF NOP           UNIT-REFERENCE NUMBER PARAMETER.
LOCAL NOP           ENTRY POINT.
      JSB .ENTR     "CALL" WITH ONE(1) PARAMETER. 
      DEF UN.RF 
      LDA UN.RF,I   LOAD THE UNIT-REFERENCE NUMBER. 
      LDB DSTCD     LOAD DYNAMIC STATUS CODE
      JSB STAT.     GO GET THE UNIT STATUS. 
      RAR,CLE       SHIFT THE "LOCAL" BIT TO 15.
      JMP LOCAL,I   RETURN. 
      SPC 2 
U.0   NOP           UNIT-REFERENCE NUMBER PARAMETER.
ISOT  NOP           ENTRY POINT.
      JSB .ENTR     "CALL" WITH ONE(1) PARAMETER. 
      DEF U.0 
      LDA U.0,I     LOAD THE UNIT-REFERENCE NUMBER. 
      LDB DSTCD     LOAD DYNAMIC STATUS CODE
      JSB STAT.     GO GET THE UNIT STATUS. 
      ALF,ALF       SHIFT THE "SOT" BIT TO 15.
      RAL,CLE       SHIFT THE "SOT" BIT TO 15.
      JMP ISOT,I    RETURN. 
      SPC 2 
U.1   NOP           UNIT-REFERENCE NUMBER PARAMETER.
RWSTB NOP           ENTRY POINT.
      JSB .ENTR     "CALL" WITH ONE(1) PARAMETER. 
      DEF U.1 
      LDA U.1,I     LOAD THE UNIT-REFERENCE NUMBER. 
      LDB RSBCD     LOAD REWIND/STANDBY CODE
      JSB STAT.     GO EXECUTE THE REQUEST. 
      JMP RWSTB,I   RETURN. 
      SPC 2 
STAT. NOP           ENTRY POINT.
      SZA           IS THE UNIT-REFERENCE ZERO(0)?
      SSA           NO - IS IT NEGATIVE ? 
      JMP STAT.,I   YES - RETURN
      AND =B000077  SAVE THE UNIT NUMBER ONLY.
B     EQU 00001B    DEFINES THE ADDRESS OF "B". 
      IOR B         INCLUDE THE OPERATION CODE. 
      STA REQST     SETUP THE REQUEST CODE. 
      JSB EXEC
      DEF *+3 
      DEF RCODE 
      DEF REQST 
      JMP STAT.,I   RETURN. 
      SPC 3 
*         BEGIN "LOCAL STORAGE".
      SPC 1 
STATC DEC 13
RCODE DEC 3 
DSTCD OCT 000600
RSBCD OCT 000500
REQST OCT 0         REQUEST CODE
      SPC 1 
*         END OF "LOCAL STORAGE". 
      SPC 1 
      END 
* 
* 
                                                              