ASMB,Q,C
      NAM XMTBU,7 92067-1X564 REV.2026 800430 
* 
* 
*     SOURCE PART NO.: 92067-18564
*     RELOC. PART NO.: 92067-1X564
*         NAME: XMTBU 
*     PART OF $DKULB(92067-12003) 
* 
* 
*     PROGRAMMER: JRS 
* 
******************************************************************* 
*                                                                 * 
*     (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1980. ALL RIGHTS      * 
*  RESERVED. NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,          * 
*  REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT   * 
*  THE PRIOR WRITTEN CONSENT OF THE HEWLETT-PACKARD COMPANY.      * 
*                                                                 * 
******************************************************************* 
* 
* 
* 
*     THIS SUBROUTINE TAKES AN LU IN A RTE-IVB SYSTEM AND BUFFERS 
*  OR UNBUFFERS THE ASSOCIATED EQT. IT WORKS BOTH IN SESSION AND
*  NON-SESSION ENVIROMENTS. 
* 
*    CALL XMTBU(LU,FLAG)
* * 
*         LU:  THE LU WHOSE EQT NEEDS TO BE ADJUSTED
*       FLAG:  ON CALLING:
*                 FLAG = -1 =>  BUFFER THE EQT
*                 FLAG =  0 =>  UNBUFFER THE EQT
*              ON RETURN: 
*                 FLAG = -1 =>  EQT WAS BUFFERED
*                 FLAG =  0 =>  EQT WAS NOT BUFFERED
* 
* 
* 
      EXT .ENTR,LUTRU,$LIBR,$LIBX 
      ENT XMTBU 
LU    NOP 
FLAG  NOP 
XMTBU NOP 
      JSB .ENTR 
      DEF LU
* 
      LDA LU,I      GET THE ALLEGED LU
      STA LU        SAVE IT FOR THE INQUISITION 
      JSB LUTRU     THIS IS THE INQUISITION 
      DEF *+2 
      DEF LU        CONFESS,THE ANSWER IS IN THE A REG
* 
      JSB $LIBR     HIT THE SYSTEM ON THE HEAD
      NOP 
* 
      XLB DRTI      GET THE HEAD OF THE DRT 
      ADA B         ADD IT TO THE REAL LU 
      ADA DM1       SUBTRACT 1 FOR GOOD MEASURE 
      XLA A,I       GET THE DRT ENTRY FOR MY LU 
      AND B77       KEEP ONLY THE EQT PART
      ADA DM1       SUBTRACT 1 TO OFFSET EQT# 
      MPY D15       MULTIPLY EQT BY 15 FOR OFFSET 
      XLB EQTA      GET THE HEAD OF THE EQT LIST
      ADB A         ADD HEAD AND OFFSET INTO EQT
      ADB D3        ADD 3 TO GET TO EQT4
      STB EQT4A     SAVE IT FOR LATER 
      XLB B,I       GET THE EQT4 WORD 
      LDA FLAG,I    GET THE FLAG PARAMETER
      CLE,SZA       IS FLAG SET???
      CCE           YES...SET E REG TO BUFFER EQT 
      RBL,RBL       GET BIT 14 OUT IN THE OPEN
      ERB,RBR       PUT THE NEW B BIT IN BIT 14 
      XSB EQT4A,I   PUT IT BACK IN ITS HOME 
      CLA,SEZ       WAS B BIT SET PREVIOUSLY??
      CCA           YES 
      STA FLAG,I    SEND IT BACK TO THE CALLER
      JSB $LIBX     YOO HOO SYSTEM....WAKE UP 
      DEF *+1 
      DEF *+1 
* 
      JMP XMTBU,I   BLOW THIS TACO STAND! 
* 
A     EQU 0 
B     EQU 1 
DRTI  EQU 1652B     HEAD OF THE DRT TABLE 
EQTA  EQU 1650B     HEAD OF THE EQT TABLE 
EQT4A NOP           EQT4 SAVE ADDRESS 
B77   OCT 77
D15   DEC 15
D3    DEC 3 
DM1   DEC -1
      END 
                              