ASMB,Q,C
      NAM IFDVR,7 92067-1X542 REV.2040 800717 
* 
* 
*     SOURCE PART NO.: 92067-18542
*     RELOC. PART NO.: 92067-1X542
*         NAME: IFDVR 
*               PART OF $DSCLB(92067-12002) 
* 
* 
*     PROGRAMMER: JRS 
* 
******************************************************************* 
*                                                                 * 
*     (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1980. ALL RIGHTS      * 
*  RESERVED. NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,          * 
*  REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT   * 
*  THE PRIOR WRITTEN CONSENT OF THE HEWLETT-PACKARD COMPANY.      * 
*                                                                 * 
******************************************************************* 
* 
* 
* 
*     THIS SUBROUTINE TAKES AN LU IN A RTE-IVB SYSTEM AND 
*  DECIDES IF IT IS A DVA32 OR DVR32 LU, BY KNOWING THAT ONLY 
*  DVA32 PROCESSES ITS OWN TIME OUTS. THE FIRST TIME IFDVR IS 
*  ENTERED, IT MAKES AN EXEC 1 (GET TRACK MAP) REQUEST TO 
*  INSURE THE DRIVER HAS BEEN ENTERED. THIS GIVES THE DRIVER
*  A CHANCE TO SET THE TIME OUT PROCESSING BIT. THIS ROUTINE
*  ALSO WORKS IN NON SESSION ENVIROMENTS. 
* 
*    CALL IFDVR(LU) 
* * 
*         LU:  THE LU WHOSE EQT NEEDS TO BE EXAMINED
* 
* 
      EXT .ENTR,EXEC
      ENT IFDVR 
LU    NOP 
IFDVR NOP 
      JSB .ENTR 
      DEF LU
* 
      LDA LU,I      COMPARE LU TO FLAG TO  FIND OUT IF WE...
      CPA FLAG      HAVE WE BEEN HERE BEFORE
      JMP GETEQ     YES...FLAG IS CLEAR...NO NEED TO ENTER DRIVER 
* 
      STA FLAG      SAVE IT FOR FUTURE REFERENCE
      ADA B2200        ....ADD 2200B
      STA DLU 
      JSB EXEC      NO...MAKE SURE DRIVER HAS BEEN ENTERED ONCE 
      DEF GETEQ 
      DEF D1        EXEC 1- GET TRACK MAP 
      DEF DLU       LU AND CONWD OF 0(CLEAR)
      DEF LBUF      TRACK MAP BUFFER
      DEF B5        1 SUBCHANNELS WORTH 
      DEF NOP1
      DEF NOP2
* 
GETEQ LDA LU,I      GET THE ALLEGED LU
      LDB DRTI      GET THE HEAD OF THE DRT 
      ADA B         ADD IT TO THE REAL LU 
      ADA DM1       SUBTRACT 1 FOR GOOD MEASURE 
      LDA A,I       GET THE DRT ENTRY FOR MY LU 
      AND B77       KEEP ONLY THE EQT PART
      ADA DM1       SUBTRACT 1 TO OFFSET EQT# 
      MPY D15       MULTIPLY EQT BY 15 FOR OFFSET 
      LDB EQTA      GET THE HEAD OF THE EQT LIST
      ADB A         ADD HEAD AND OFFSET INTO EQT
      ADB D3        ADD 3 TO GET TO EQT4
      LDB B,I       GET THE EQT4 WORD 
      RBL,RBL       GET BIT 12... 
      RBL,ELB                 ...OUT IN THE OPEN
      CLA,SEZ       WAS B BIT SET PREVIOUSLY??
      CCA           YES 
* 
      JMP IFDVR,I   BLOW THIS TACO STAND! 
* 
A     EQU 0 
B     EQU 1 
DRTI  EQU 1652B     HEAD OF THE DRT TABLE 
EQTA  EQU 1650B     HEAD OF THE EQT TABLE 
B2200 OCT 2200
B5    OCT 5 
B77   OCT 77
D15   DEC 15
D1    DEC 1 
D3    DEC 3 
DLU   NOP 
DM1   DEC -1
FLAG  DEC -1
NOP1  NOP 
NOP2  NOP 
LBUF  BSS 5 
      END 
            