ASMB,R,L,C,Q
*     NAME:   VSCBA 
*     SOURCE: 92067-18482 
*     RELPC:  92067-16261 
*     PGMR:   G.L.M.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
* 
      NAM VSCBA,6 92067-16261 REV.1903 790202 
* 
      ENT VSCBA 
* 
      EXT $SHED,ISMVE,$SMLK,.ZPRV 
* 
* 
* 
VSCBA NOP 
      JSB .ZPRV     GO PRIV IF IN SYS LIB 
      DEF LIBX
      DLD VSCBA,I   FETCH RETURN
      STA VSCBA       ADDRESS AND SAVE FOR EXIT 
* 
      LDB B,I       FETCH TEST ADDRESS
* 
      LDA $SMLK     SET OFFSET TO 
      ADA B         ADJUST TEST ADDRESS 
      STA SCBAD        AND SAVE 
* 
      LDA $SHED     FETCH HEAD OF SCB LIST
* 
NEXT  SZA,RSS       CHECK FOR END OF LIST 
      JMP LIBX     END OF LIST-- NO MATCH (RETURNS A=0) 
* 
      STA TEMP0     SAVE LOCATION OF THIS SCB 
* 
      JSB ISMVE 
      DEF V.2 
      DEF TEMP0     READ FROM LOCATION DEFINED BY TEMP0 
      DEF NOP       WITH A ZERO OFFSET
      DEF TEMP1      PUT IT HERE
      DEF .4        MOVE 4 WORDS
V.2   EQU * 
* 
      LDA TEMP4     PRE-FETCH POSSIBLE ID 
      AND B377      ISOLATE SESSION ID
      LDB TEMP0     IS THIS THE 
      CPB SCBAD       REQUESTED SCB ? 
      JMP LIBX        YES-- RETURN A= SESSION IDENTIFIER
* 
      LDA TEMP1     FETCH LINK TO NEXT SCB
      JMP NEXT      GO GET IT 
* 
LIBX  JMP VSCBA,I 
      DEF VSCBA 
* 
TEMP0 NOP 
* 
*  DO NOT CHANGE THE ORDER OF THE FOLLOWING:
TEMP1 NOP 
TEMP2 NOP 
TEMP3 NOP 
TEMP4 NOP 
* 
*  DO NOT CHANGE THE ORDER OF THE ABOVE TEMPS 
* 
B     EQU 1 
NOP   NOP 
SCBAD NOP 
.4    DEC 4 
B377  OCT 377 
* 
      END 
                                                        