ASMB,R,Q,C
      HED MESSS 
*     NAME:   MESSS 
*     SOURCE: 92067-18472 
*     RELPC:  92067-16456 
*     PGMR:   G.A.A.,C.M.M. 
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1978.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
      NAM MESSS,7 92067-16456 REV.1913 780724 
      ENT MESSS 
      EXT $LIBR,$LIBX,$MESS,.ENTP,$WORK,$PVCN,$$OP
      SPC 2 
      SPC 2 
BUFFR NOP 
LNGTH NOP 
P1    NOP 
MESSS NOP 
      JSB $LIBR      GO PRIVILEGED. 
CNTR  NOP 
      JSB .ENTP      GET PARAMETERS.
      DEF BUFFR 
      LDA MESSS 
      LDB HERE
      SZB 
      JMP EXIT2 
THERE STA RTN 
      STA HERE
      LDA DEFEF 
      STA MESSS 
      CLA 
      STA $PVCN 
      LDA BUFFR 
      LDB LNGTH,I 
      JSB $MESS     PASS MESSAGE TO SYSTEM. 
      ISZ $PVCN 
      SZA,RSS 
      JMP CHECK     IF NO RETURNED MESSAGE, THEN CHECK
      XLB A,I        FOR SPECIAL PATCHING OF 'RU' OR  'ON'
      STB LNGTH     OTHERWIZE PROCESS MESSAGE.
      BRS 
      STB CNTR
LOOP  INA 
      XLB A,I 
      STB BUFFR,I 
      ISZ BUFFR 
      ISZ CNTR
      JMP LOOP
* 
      LDA LNGTH 
EXIT  CLB 
      STB HERE
      STB P1
EXIT1 JSB $LIBX 
DEF   DEF RTN 
RTN   NOP 
HERE  NOP 
DEFEF DEF DEF 
      SPC 2 26
CHECK LDB $WORK     GET PROGRAM'S ID SEGMENT ADDRESS. 
      INB 
      LDA BUFFR,I   TEST FOR ON,RUN 
      CPA .ON       COMMANDS
      JMP DP1        TEST 1ST PRAM
      CPA .RU 
      JMP DP1 
      JMP DP2 
      SPC 2 
DP1   XLA B,I        LU# IF GIVEN 
      SZA,RSS         IN FIRST
      LDA P1,I         PARAMETER. 
      XSA B,I 
* 
DP2   XLA $$OP,I      GET THE OP CODE THE SYS PARSED
      CPA .ON         ON ?
      JMP DP3 
      CPA .RU         RU ?
      JMP DP3 
      JMP EXIT2 
* 
DP3   LDB XEQT      GET MY ID ADDRESS 
      JSB SES#3     NOW GET THE SESSION WORD
      XLA B,I 
      STA HERE      & SAVE IT 
* 
      LDB $WORK     GET THE SON'S ID ADDRESS
      JSB SES#3     AND GET IT'S SESSION WORD ADDRESS 
      LDA HERE      GET THE FATHERS WORD
      XSA B,I       AND PROPIGATE TO THE SON. 
* 
* 
EXIT2 CLA           ZERO OUT 'A' REG FOR RETURN 
      JMP EXIT
      SPC 2 
* 
SES#3 NOP 
      ADB D14       INDEX TO TYPE WORD
      XLA B,I        GET THE TYPE 
      AND D7        KEEP ONLY TYPE
      CPA D1        IS IT MEM RES ? 
      ADB DM4 
      ADB D18        B = SESSION WORD # 3 ADDRESS 
      JMP SES#3,I   RETURN
* 
* 
.ON   ASC 1,ON
.RU   ASC 1,RU
D1    DEC 1 
D5    DEC 5 
D7    DEC 7 
D14   DEC 14
D18   DEC 18
D29   DEC 29
DM4   DEC -4
A     EQU 0 
B     EQU 1 
XEQT  EQU 1717B 
* 
      END 
                                                                                            