ASMB,Q,C
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
*     SOURCE PART NUMBER :92067-18376 
* 
*     RELOCATABLE PART NUMBER : 92067-16361 
* 
*     PROGRAMER(S)   : J.M.N. 
* 
* 
      NAM ACSDN,7 92067-16361 REV.1940 790111 
      ENT ACSDN 
      EXT EXEC,.ENTR,$LGOF,XLUEX,XFTTY,LUSES,ACOMD
      EXT $CES,$LIBR,$LIBX
* 
* 
LU    NOP 
IERR  NOP 
ACSDN NOP 
      JSB .ENTR 
      DEF LU
* 
*     CLEAR IERR
* 
      CLA 
      STA IERR,I
* 
*          GET SCB ADDRESS
* 
      LDA LU,I
      AND B377
      STA LU1 
* 
*     IF LU IS 0 THEN DISABLE LU 1 AS SESSION ACTRM 
* 
      SZA 
      JMP NRMLU     NORMAL LU 
      JSB $LIBR     MUST GO PRIVILEGED
      NOP 
      XSA $CESA,I   ZAP ENTRY POINT 
      JSB $LIBX 
      DEF ACSDN     THEN RETURN 
* 
NRMLU IOR ISGN
      STA LU2 
      JSB LUSES     GO GET SCB ADDRESS
      DEF *+2 
      DEF LU1 
      SZA,RSS       IF NO SCB THEN RETURN 
      JMP ERR       GO SET ERROR
      STA ISES      SAVE SCB ADDRESS
* 
      LDA $LGOF 
      STA ICLAS     STUFF CLASS # 
      JSB EXEC
      DEF RTRN1 
      DEF D20 
      DEF D0
      DEF IDUM
      DEF D0
      DEF LU,I
      DEF ISES
      DEF ICLAS 
* 
*     PROGRAM SCHEDULE
* 
RTRN1 JSB EXEC
      DEF RTRN2 
      DEF SCNAB 
      DEF NAME
RTRN2 NOP 
      JSB XFTTY     IF NOT INTERACTIVE RETURN 
      DEF *+2 
      DEF LU2 
      SZA,RSS 
      JMP ACSDN,I 
* 
      LDA MESS1     SEND MESSAGE TO GUY YOU ABORTED 
      JSB MESS
      LDA MESS2 
      JSB MESS
      JMP ACSDN,I   RETURN
* 
*     ERROR RETURN
* 
ERR   LDA DM221     SET IERR TO -221
      STA IERR,I
      JMP ACSDN,I 
* 
*     CLASS IO WRITE REQUEST
* 
MESS  NOP 
      STA BUFAD 
      JSB XLUEX 
      DEF RTRN3 
      DEF D18I
      DEF LU2 
BUFAD BSS 1 
      DEF D15 
      DEF IDUM
      DEF IDUM
      DEF ACOMD 
RTRN3 NOP 
      JMP MESS,I
* 
$CESA DEF $CES+1
D20   DEC 20
D15   DEC 15
DM221 DEC -221
B377  OCT 377 
D18I  OCT 100022
D0    DEC 0 
SCNAB OCT 100012
NAME  ASC 3,LGOFF 
ISGN  OCT 100000
MESS1 DEF *+1 
      ASC 15,SYSTEM MANAGER IS ABORTING YOU 
MESS2 DEF *+1 
      ASC 15,------------------------------          *
ICLAS BSS 1 
ISES  BSS 1 
LU1   BSS 1 
LU2   BSS 2 
IDUM  BSS 1 
      END 
                                                                                                                        