ASMB,R
*     NAME:   RSTOR 
*     SOURCE: 92067-18336 
*     RELOC:  92067-16336 
*     PGMR:   S.P.K.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1976.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
      NAM RSTOR,3,99 92067-16336 REV.1903 790620
* MAG TAPE TO DISC DATA TRANSFER
      EXT MTD,BUFER,RMPAR,EXEC,ITASK
RSTOR JSB RMPAR     GET PARAMETERS PASSED BY USER 
      DEF *+2 
      DEF IP
      CLA,INA 
      STA ITASK     TASK=1 FOR RESTORE
      JSB BUFER     GET FWA OF AVMEM IN PARTITION & # WORDS IN AVMEM
      DEF FWA       ADDRESS OF FWA IN AVMEM 
      DEF PLEN
      DEF BFLEN     # OF WORDS IN AVMEM 
      LDA FWA 
      INA 
      STA ITR       SET UP VARIABLES USED BY MTD ROUTINE
      INA 
      STA JB        BUFFER TO WRITE ON DISC 
      ADA D98 
      STA ILUTR     LU-#TRCKS TABLE AT KB(101)
      LDA FWA       BUFFER FOR HEADER REC IS PLACED IN LAST 140 WORDS 
      ADA BFLEN     OF PARTITION
      ADA N140      FWA+BFLEN-140 
      STA IHDR
      ADA D37       IHDR(38)
      STA IDTP1     IDTYP1
      INA 
      STA ITPSV     IHDR(39)-TYPE OF SAVE 
      INA 
      STA LU2       IHDR(40)-LU2 INVOLVED IN SAVE?
      ADA D2        IHDR(42)-REC SIZE OF SAVED DATA 
      STA RSIZE 
      ADA D33 
      STA ILUTB     IHDR(75)-COPY OF LU-#TRCKS TABLE
      JSB MTD       GO TO MAIN RESTORE ROUTINE
      DEF *+15
      DEF FWA,I     KB
      DEF PLEN      LENGTH OF PARTITION 
      DEF BFLEN     # WORDS IN AVMEM
      DEF JB,I      JB
      DEF ITR,I     ITR 
      DEF FWA,I     ITB30 
      DEF ILUTR,I   ILUTR 
      DEF IHDR,I    IHDR
      DEF IDTP1,I   IDTYP1
      DEF ITPSV,I   ITPSV 
      DEF LU2,I     LU2 
      DEF RSIZE,I   RECORD SIZE-IREC
      DEF ILUTB,I   ILUTB 
      DEF IP        PARAMETER LIST
      JSB EXEC      END RSTOR 
      DEF *+2 
      DEF D6
* 
FWA   BSS 1 
PLEN  BSS 1 
BFLEN BSS 1 
JB    BSS 1 
ITR   BSS 1 
ILUTR BSS 1 
IHDR  BSS 1 
IDTP1 BSS 1 
ITPSV BSS 1 
LU2   BSS 1 
RSIZE BSS 1 
ILUTB BSS 1 
IP    BSS 5 
D2    DEC 2 
D6    DEC 6 
D33   DEC 33
D37   DEC 37
D98   DEC 98
N140  DEC -140
      END RSTOR 
                                                                                