ASMB,R,L,C,Q
*     NAME:   .OWNR 
*     SOURCE: 92067-18324 
*     RELPC:  92067-16268 
*     PGMR:   G.L.M 
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1978.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
* 
      NAM .OWNR,7 92067-1X324 REV.2013 780919 
* 
* 
* 
      ENT .OWNR 
* 
      EXT ISMVE,$SMID,$SMII,.ZPRV 
* 
* 
      SUP 
      SKP 
* 
* 
*  CALLING SEQUENCE: JSB .OWNR
* 
*          RETURN    (A)=OWNER FLAG FOR THIS SESSION
* 
* 
* 
.OWNR NOP 
      JSB .ZPRV 
      DEF LIBX
      LDB XEQT      FETCH ID
      ADB D32         ADDR OF SESSION WORD
      XLB B,I            THEN CONTENTS OF SAME
      SSB,RSS       IF NOT
      SZB,RSS         SESSION 
      JMP NSES          RETURN, ID=0
* 
      STB TMP0      SAVE SESSION WORD 
* 
* 
*  CHECK TO SEE IF THIS IS THE SYSTEM MANAGER CALLING.
* 
*  IF IT IS, RETURN AN ID OF ZERO TO INDICATE THAT THE PROGRAM
*  BELONGS TO THE SYSTEM, NOT THE SESSION.
* 
* 
      JSB ISMVE 
      DEF ISM1
      DEF TMP0      READ FROM LOCATION DEFINED BY TMP0
      DEF $SMID     WITH AN OFFSET BACK TO PRIVATE DISC ID
      DEF TMP1      PLACE THE RESULT HERE 
      DEF D1        MOVE ONE WORD 
ISM1  EQU * 
* 
      LDA TMP1      FETCH PRIVATE ID
      CPA B7777     IF SYSTEM MANAGER 
      JMP NSES         RETURN ID=0 SO LGOFF WON'T PURGE THE ID. 
* 
* 
* 
*  NOT SYSTEM MANAGER SO GET SESSION ID FOR THIS SESSION
* 
* 
      JSB ISMVE 
      DEF ISM2
      DEF TMP0      SESSION WORD
      DEF $SMII     SESSION ID OFFSET 
      DEF TMP0      PLACE RESULT HERE 
      DEF D1
ISM2  EQU * 
* 
      LDA TMP0      FETCH THE ID
      AND B377      ISOLATE IT
      RSS           GET OUT 
* 
* 
NSES  CLA           ID=0
LIBX  JMP .OWNR,I 
      DEF .OWNR 
* 
* 
* 
TMP0  NOP 
TMP1  NOP 
XEQT  EQU 1717B 
D1    DEC 1 
D32   DEC 32
B7777 OCT 7777
B377  OCT 377 
B     EQU 1 
      END 
                                                          