ASMB,R,L,C    ** LOGLU - RETURNS LU FROM PROGRAM ID SEGMENT 
      HED -LOGLU - FIND LU THAT THIS PROGRAM ORIGINATED FROM. 
*     NAME:   LOGLU 
*     SOURCE: 92067-18297 
*     RELOC:  PART OF 92067-16268 
*     PGMR:   C.M.M.,G.L.M. 
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
      NAM LOGLU,7 92067-1X297 REV.2013 790228 
      ENT LOGLU 
* 
*     ROUTINE TO FIND THE LOGICAL UNIT NUMBER THAT THIS 
*     PROGRAM ORIGINATED FROM.
*          CALLED AS FOLLOWS: 
* 
* LU = LOGLU(SYSLU)           JSB LOGLU 
*                             DEF *+2 
*                             DEF SYSLU 
* 
* 
*    LU = A REG = LU #     OF LU AT WHICH 'RU'  OR  'ON' WAS ENTERED. 
*                          OR IF SCHEDULED BY A FATHER, THE LU AT WHICH 
*                          THE FATHER WAS SCHEDULED.
*               = 1        IF PROGRAM SCHEDULED BY INTERUPT OR TIME LIST
*         B REG = ASCII LU # (SESSION TERMINAL LU)
*         SYSLU = SYSTEM LU OF SESSION TERMINAL IF IN SESSION 
*               = -LU IF NOT IN SESSION 
* 
* 
LOGLU NOP           ENTRY 
      DLD LOGLU,I   GET RETURN ADDRESS & DUMMY ADDRESS
      STB SYSLU     SAVE DUMMY ADDRESS
      STA LOGLU     &RETURN ADDRESS 
      LDA XEQT      GET MY ID ADDRESS 
      ADA D32       ADVANCE TO SESSION WORD 
      XLB A,I        AND FETCH IT 
* 
      SZB           IF NON
      SSB                 SESSION GO DO 
       JMP MTM                          MTM WORK
* 
      CLA,INA       SET SESSION LU=1
      STA LU# 
* 
* 
* 
*     JSB MMAP      GO MAP IN POSSIBLE TABLE PARTITION
* 
NXT   INB           POINT AT LU SWITCH
      XLA B,I       FETCH AN LU SWITCH
      AND B377      ISOLATE SESSION LU-1
      SZA           IF NOT LU 1 DEFINITION
      JMP NXT       GO GET THE NEXT ONE 
* 
*  FOUND SESSION LU 1 
* 
      XLA B,I       FETCH THE SWITCH AGAIN
      ALF,ALF       POSITION SYSTEM LU-1 TO LOW BYTE
      INA           ADJUST FOR INTERNAL FORMAT
      STA SYSLU,I   AND RETURN IT TO CALLER 
CONV  CLB           CLEAR (B) FOR DIVIDE
      DIV D10 
      ALF,ALF 
      ADB A 
      ADB ASC00     B = ASCII LU #
      LDA LU#       A = BINARY LU # 
      JMP LOGLU,I   RETURN
* 
* 
MTM   SZB,RSS       IF SESSION WORD=0 
      CCB           USE 1 
      STB SYSLU,I 
      CMB,INB       SET LU POSITIVE 
      STB LU#       SAVE FOR RETURN 
      LDA B         MOVE LU TO A FOR CONVERSION 
      JMP CONV
* 
* 
D10   DEC 10
D32   DEC 32
B377  OCT 377 
SYSLU NOP 
LU#   NOP 
ASC00 ASC 1,00
XEQT  EQU 1717B 
A     EQU 0 
B     EQU 1 
      END 
                                                                                                  