ASMB,R,L,C    ** SEGLD ** 
      HED SEGLD - ROUTINE TO LOAD A SEGMENT 
*     NAME:   SEGLD 
*     SOURCE: 92067-18257 
*     RELOC:  PART OF 92067-16035 
*     PGMR:   S.K.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
*  SEGLD CALLS EXEC TO LOAD SEGMENT.  IF SEGMENT NOT FOUND, SEGLD 
*  SCHEDULES T5IDM PROGRAM TO BUILD THE ID SEGMENT FOR THE SEGMENT
*  AND THEN CALLS EXEC TO LOAD SEGMENT. 
* 
*  CALLING SEQUENCE:
*      CALL SEGLD(ISGNM,IERR,IP1,IP2,IP3,IP4,IP5) 
*   WHERE:  ISGNM = NAME OF SEGMENT 
*           IERR  = ERROR RETURNED BY SEGLD 
*           IP1 - IP5 =  OPTIONAL PARAMETERS TO BE PASSED 
*                             TO THE SEGMENT
* 
*  RETURN:
*           IERR  = 5 IF SEGMENT NOT FOUND
*                 = 0 IF SEGMENT LOADED 
* 
* 
      NAM SEGLD,7 92067-16035 REV.1913 790202 
      ENT SEGLD 
* 
      EXT .ENTP,EXEC,.DFER,$OPSY
* 
SGNAM NOP 
IERR  NOP 
PARM1 NOP 
PARM2 NOP 
PARM3 NOP 
PARM4 NOP 
PARM5 NOP 
* 
SEGLD NOP 
      JMP CLRPM     POINT THE 5 OPTIONAL
.ZERO DEF ZERO        PARAMETERS TO ZERO
GTPRM JSB .ENTP     GET THE PARAMETERS PASSED 
      DEF SGNAM 
* 
TRY   JSB EXEC      LOAD SEGMENT
      DEF *+8 
      DEF .S8       =100010B -- NO ABORT BIT SET
      DEF SGNAM,I   NAME OF SEGMENT 
      DEF PARM1,I   FIVE
      DEF PARM2,I 
      DEF PARM3,I      OPTIONAL 
      DEF PARM4,I 
      DEF PARM5,I          PARAMETERS 
      NOP 
* 
*  SCHEDULE T5IDM TO SET UP ID SEGMENT FOR SEGMENT
* 
      JSB .DFER     GET SEGMENT NAME
      DEF SGNM1 
      DEF SGNAM,I 
      JSB EXEC
      DEF *+7 
      DEF .S23      =100027B  SCHEDULE WITH NO ABORT
      DEF T5IDM 
      DEF SGNM1     SEGMENT 
      DEF SGNM2          NAME 
      DEF SGNM3 
      DEF .1        ONE SEGMENT TO LOAD 
      JMP SC05      T5IDM PROGRAM NOT FOUND 
* 
      LDA $OPSY     HOW TO GET THE RETURN PARAMETER 
      ERA,SLA       TEST THE DMS BIT
      JMP DMS       IF DMS INSTALLED JMP
* 
      LDA B,I       ELSE JUST LOAD THE DATA 
      JMP TS        GO TEST THE RESULT
* 
DMS  XLA B,I        DMS  DO THE DM CROSS LOAD 
TS    SZA,RSS       IF ZER THEN THE SEGMENT WAS SET UP
      JMP TRY       GO TRY AGAIN
* 
SC05  LDA .5        SEND ERROR 5 TO INDICATE SCO5 
      STA IERR,I
      JMP SEGLD,I   RETURN
* 
* 
ZERO  DEC 0 
.S23  OCT 100027
.1    DEC 1 
.5    DEC 5 
SGNM1 NOP 
SGNM2 NOP 
SGNM3 NOP 
T5IDM ASC 3,T5IDM 
* 
.S8   OCT 100010
* 
* 
CLRPM LDA .ZERO 
      STA PARM1 
      STA PARM2 
      STA PARM3 
      STA PARM4 
      STA PARM5 
      JMP GTPRM     DONE
* 
* 
* 
A     EQU 0 
B     EQU 1 
      END 
                                                