ASMB,R,L,C
*     NAME:   PGS.
*     SOURCE: 92067-18183 
*     RELOC:  92067-16125 
*     PGMR:   B.L.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
      NAM PGS.,7 92067-16125 REV.1903 781002
      ENT PGS.
      EXT .ENTR     PARAMETER ADDRESS FETCH ROUTINE 
      EXT READF     FMP FILE READ ROUTINE 
* 
*  ROUTINE TO DETERMINE WHETHER A SESSION MONITOR DISC
*  ID REPRESENTS A PRIVATE, GROUP OR SYSTEM DISC
*  NOTE:  ASSUMES CALLER HAS OPENED AND WILL CLOSE ACCOUNT
*         FILE WITH SPECIFIED DCB 
* 
*  CALLING SEQUENCE:  JSB PGS.
*                     DEF *+4 
*                     DEF IDCB      ACCOUNT FILE DCB
*                     DEF ID        SESSION MONITOR DISC ID 
*                     DEF PGS       ON RETURN, = 1 IF PRIVATE ID
*                                              = 2 IF GROUP ID
*                                              = 3 IF SYSTEM ID 
*                                              = 0 OTHERWISE
* 
* METHOD:  IF ID IS 0, RETURN PGS=0.  IF ID IS 4095, RETURN PGS=3.
*          OTHERWISE, EXAMINE THE SESSION ACCOUNT FILE HEADER 
*          RECORD, WORDS 23 AND 24.  IF ID IS GREATER THAN OR EQUAL 
*          TO THE LOWEST PRIVATE ID USED (WORD 23), RETURN PGS=1. 
*          IF ID IS LESS THAN OR EQUAL TO THE HIGHEST GROUP ID
*          USED (WORD 24), RETURN PGS=2.  OTHERWISE RETURN PGS=0. 
* 
IDCB  NOP           ACCOUNT FILE DCB
ID    NOP           SESSION DISC ID 
PGS   NOP           RETURN WORD 
PGS.  NOP           ENTRY 
      JSB .ENTR     GET PARAMETER ADDRESSES 
      DEF IDCB
      LDA ID,I      GET SESSION DISC ID 
      SZA,RSS       IF ZERO, RETURN PGS=0 
      JMP DONE      ZERO, SO RETURN 
      CPA SYSID     SYSTEM ID?
      JMP SYS       YES 
      JSB READF     READ THE ACCOUNT FILE HEADER
      DEF *+7 
      DEF IDCB,I    DCB 
      DEF IERR      ERROR RETURN
      DEF IBUF      RETURN BUFFER 
      DEF .24       NBR. OF WORDS TO READ 
      DEF IDMY
      DEF .1        RECORD #1 
      LDA IERR      GET ERROR WORD
      SSA           ERROR?
      JMP ZERO      YES, RETURN PGS=0 
      LDA IBUF+22   GET LOWEST PRIVATE ID USED
      CMA,INA       CHECK IF GREATER THAN 
      ADA ID,I      ID PARAMETER
      SSA,RSS 
      JMP PRIV      NO, SO ID IS PRIVATE ID 
      LDA IBUF+23   GET HIGHEST GROUP ID USED 
      CMA           CHECK IF LESS THAN
      ADA ID,I      ID PARAMETER
      SSA 
      JMP GROUP     NO, SO ID IS GROUP ID 
ZERO  CLA,RSS       RETURN PGS=0
PRIV  CLA,INA       RETURN PGS=1
      RSS 
GROUP LDA .2        RETURN PGS=2
      RSS 
SYS   LDA .3        RETURN PGS=3
DONE  STA PGS,I     SAVE IN RETURN PARAMETER
      JMP PGS.,I    RETURN
.1    DEC 1 
.2    DEC 2 
.3    DEC 3 
.24   DEC 24
SYSID OCT 7777
IBUF  BSS 24
IDMY  BSS 1 
IERR  BSS 1 
      END 
                                                                                                                        