ASMB,R,L
      HED BUMP ROUTINE
*     NAME:   BUMP
*     SOURCE: 92067-18163 
*     RELOC:  92067-16125 
*     PGMR:   G.A.A.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
* 
      NAM BUMP.,8 92067-16125 REV.1903 741025 
      ENT BUMP. 
      EXT $BATM,.ENTR 
A     EQU 0 
* 
T1    NOP 
T2    NOP 
BUMP. NOP 
      JSB .ENTR     FETCH PARAM ADDRS 
      DEF T1
* 
      LDA T1
      INA 
      STA T3        SAVE ADDR OF SECOND WORD
      DLD $BATM     FETCH BATCH TIME
      CMA,CLE,INA   COMPLEMENT
      CMB,SEZ 
      CLE,INB 
      CLE           SET UP FOR NEXT ADD 
      ADA T2,I      SUBTRACT FROM PREVIOUS TIME 
      ISZ T2         TO GET ELAPSED TIME
      SEZ,CLE 
      INB 
      ADB T2,I
      CMA,CLE,INA   COMPLEMENT
      CMB,SEZ       A DOUBLE INTEGER
      CLE,INB 
      CLE           SET UP FOR NEXT ADD 
      ADA T1,I      SUBTRACT FROM TIME LIMIT
      SEZ            TO GET TIME LIMIT LEFT.
      INB 
      ADB T3,I
      DST T1,I      RETURN NEW LIMIT TO CALLER
      JMP BUMP.,I 
* 
T3    NOP 
* 
      BSS 0         SIZE OF BUMP. 
      END 
                                              