ASMB,R,L,C
      HED RWND$ 
*     NAME:   RWND$ 
*     SOURCE: 92067-18144 
*     RELOC:  92067-16125 
*     PGMR:   G.A.A.,N.J.S. 
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
      NAM RWND$,7 92067-16125 REV.1903 780801 
      ENT RWND$ 
      EXT EXEC,RMPAR
      ENT RFLG$ 
* 
*     RWND$         IS A MODULE OF THE REAL TIME FILE 
*                   MANAGEMENT PACKAGE.  IT IS INVOKED
*                   TO SET OR RESET WORDS 11 THROUGH 16 
*                   OF THE DCB.  THE RECORD COUNT IS RESET IF EXTENT 0. 
* 
*     CALLING SEQUENCE: 
* 
*     LDA EXTENT#   SET A TO DESIRED EXTENT 
*     LDB DCB       SET B TO DCB ADDRESS
*     JSB RWND$     CALL
*     JMP ERR       ERROR EXIT (A=CODE) 
*     ---           NORMAL RETURN 
* 
      SPC 3 
TMP   NOP 
TMP2  NOP 
RWND$ NOP           ENTRY POINT 
      STB DCB       SAVE THE DCB
      INB           ADDRESS 
      STB TRACK     FOR THE D.RTR CALL
      ADB .2        SAVE THE
      STB TMP       TRACK ADDRESS 
      STA TMP2      AND THE EXTENT
      ADB .12       INDEX TO THE EXTENT#
      CPA B,I       IF SAME - CONTINUE
      JMP SETUP     WITH SETUP
      LDA RFLG$     GET READ WRITE FLAG 
      LDB .6        GET READ EXTENT OPEN REQUEST CODE 
      SZA,RSS       IF WRITE
      ADB .2        ADD TWO TO GET WRITE EXTENT OPEN REQUEST
      STB SET       SET IT FOR CALL TO D.RTR
      JSB EXEC      ELSE
      DEF *+8       CALL
      DEF .23       D.RTR 
      DEF D.RTR     TO
      DEF XEQT      OPEN
      DEF SET       THE 
DCB   NOP           EXTENT. 
TRACK NOP 
      DEF TMP2
      SPC 1 
      JSB RMPAR     CALL RMPAR TO GET 
      DEF *+2        RETURN PARAMETERS
      DEF ERTN        TO LOCAL AREA 
      LDB AERTN 
      LDA B,I       ANY ERRORS? 
      SSA           FROM D.RTR? 
      JMP RWND$,I   YES; RETURN 
      SPC 1 
      ADB .3        NO; STEP TO TRACK 
      LDA B,I       GET TRACK 
      STA TMP,I     SET IN DCB
      INB           STEP TO SECTOR
      LDA B,I       GET AND 
      AND B377      MASK
      LDB TMP       GET DCB ADDRESS 
      INB           SET 
      STA B,I       SECTOR IN DCB 
SETUP LDB TMP       CLEAR THE WRITE FLAGS 
      ADB .4         AND THEN SET THE 
      LDA B,I         DCB FROM THE TRACK
      AND MASK         AND SECTOR WORDS.
      STA B,I 
      ADB .3
      LDA TMP,I     SET 
      JSB SET       TRACK 
      ISZ TMP       AND 
      LDA TMP,I     SECTOR
      JSB SET       WORDS.
      LDA B         SET THE 
      ADA .4        BUFFER
      JSB SET       ADDRESS.
      LDA TMP2      GET EXTENT# 
      ADB .2        SKIP
      JSB SET       SET THE EXTENT #
      ISZ RWND$     STEP
      JMP RWND$,I   AND RETURN
      SPC 3 
SET   NOP 
      STA B,I       SET THE WORD IN THE DCB 
      INB           STEP DCB ADDRESS
      JMP SET,I     RETURN
      SPC 3 
ERTN  NOP 
      NOP           LOCAL STORAGE 
      NOP            RETURN PARAMETERS
      NOP             FROM D.RTR
      NOP 
AERTN DEF ERTN
.2    OCT 2 
.3    OCT 3 
.4    OCT 4 
.6    DEC 6 
.12   DEC 12
.23   DEC 23
B377  OCT 377 
MASK  OCT 177770
RFLG$ NOP           GLOBAL READ WRITE FLAG
D.RTR ASC 3,D.RTR 
XEQT  EQU 1717B 
A     EQU 0 
B     EQU 1 
      SPC 1 
END   EQU * 
      SPC 1 
      END 
                                                                                                                                        