ASMB,R,L,C,Q
*     NAME:   .UNAM 
*     SOURCE: 92067-18092 
*     RELPC:  92067-16125 
*     PGMR:   G.L.M.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
* 
      NAM .UNAM,7 92067-16125 REV.1903 790129 
* 
* 
* 
      ENT .UNAM 
* 
      EXT .CLGN,EXEC
* 
* 
A     EQU 0 
B     EQU 1 
* 
* 
*  PURPOSE: GIVEN A DIRECTORY ENTRY NUMBER, RETURN CORRESPONDING
*           USER.GROUP NAME.
* 
*  CALLING SEQUENCE: (A)=DIRECTORY ENTRY NUMBER 
*                    (B)=RESULT BUFFER ADDRESS (11 WORDS) 
*                    JSB .UNAM
*                    DEF ERROR MESSAGE BUFFER(128)
* 
*            RTN (A) 0= USER.GROUP NAME IS IN THE RESULT BUFFER (B=0) 
*                   -1= SESSION NOT INITIALIZED OR NOT INSTALLED
*                    (B)=0
*            ELSE (A) = - TRANS LOG (BYTES) OF TERMINATING ERROR MSG
*                       (ERROR STRING IN BUFFER 2)
*                 (B) = ERROR CODE
* 
* 
* 
      SKP 
* 
* 
* 
.UNAM NOP 
      STA TEMP      SAVE DIRECTORY ENT #
      STB RBUF      SAVE RESULT BUFFER ADDRESS
      LDA .UNAM,I   FETCH ERROR BUFFER ADDRESS
      STA BUFA
      CLA,INA       SEND ONE WORD 
      LDB DTEMP      TO LOGON (ADDR OF DENT IN (B)) 
      JSB .CLGN 
DM3   DEC -3        RETURN USER.GROUP NAME
* 
      SSA           ERROR ? 
      JMP ERR1        YES GET OUT 
* 
      STA CCLAS     SAVE COMMUNICATION CLASS
GETIT LDA DM256     FETCH BUFFER SIZE 
      JSB GETR      GO DO A GET 
       JMP ERR1     ERROR ON GET REQUEST
* 
      LDA CALL      FETCH CALL TYPE ( THAT THE GET FETCHED) 
      CPA D1        MUST BE READ OR WRITE\READ
      RSS 
      JMP GETIT     TRY AGAIN 
* 
      LDA IOP2      FETCH LOGON RETURN STATUS 
      STA TEMP3     SAVE POSSIBLE ERROR CODE
      CPA OK?       IF COMPLETION STATUS RETURNED 
      JMP MOVE      GO MOVE THE USER.GROUP NAME INTO CALLERS BUFFER 
* 
      CMB,INB,RSS   SET TRANS LOG NEGATIVE  & SKIP
ERR1  CCB           ERROR =-1 
EXIT  STB TEMP      SAVE RETURN STATUS
* 
      LDA CCLAS     CLEAR SAVE CLASS
      XOR SAVC       BIT
      STA CCLAS 
* 
AGAIN CLA           GET ZERO LENGTH BUFFER
      JSB GETR      RELEASE COMMUNICATION CLASS 
       CLB,RSS      ERROR ON GET SO GET OUT 
      JMP AGAIN 
* 
      LDA TEMP3     FETCH POSSIBLE ERROR CODE FROM LOGON
      ALF           POSITION TO (B) (B MUST = 0 FIRST)
      ASL 6 
      LDA TEMP      FETCH RETURN STATUS 
      ISZ .UNAM     .BUMP RETURN ADDR 
      JMP .UNAM,I     AND RETURN
* 
* 
* 
MOVE  LDA BUFA      FETCH FROM ADDRESS
      LDB RBUF      FETCH "T0" ADDRESS
      MVW D11 
      CLB 
      JMP EXIT      RETURN STATUS=0 
* 
* 
GETR  NOP 
      STA TEMP2 
      JSB EXEC
      DEF GET1
      DEF DS21
      DEF CCLAS 
      DEF BUFA,I   RESULT BUFFER
      DEF TEMP2 
      DEF IOP1
      DEF IOP2
      DEF CALL
GET1  EQU * 
      RSS 
      ISZ GETR
      JMP GETR,I
* 
* 
* 
* 
SAVC  OCT 20000 
CALL  NOP 
D1    DEC 1 
D11   DEC 11
TEMP  NOP 
TEMP2 NOP 
TEMP3 NOP 
DTEMP DEF TEMP
OK?   OCT 110011
RBUF  NOP 
BUFA  NOP 
DM256 DEC -256
DS21  OCT 100025
IOP1  NOP 
IOP2  NOP 
CCLAS NOP 
      END 
                