ASMB,R,L,C,Q
*     NAME:   .UACT 
*     SOURCE: 92067-18090 
*     RELPC:  92067-16125 
*     PGMR:   G.L.M.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
* 
      NAM .UACT,7 92067-16125 REV.1903 790129 
* 
* 
* 
      ENT .UACT 
* 
      EXT .CLGN,EXEC
* 
* 
A     EQU 0 
B     EQU 1 
* 
* 
* PURPOSE: GIVEN A LOG-ON STRING, RETURN DIRECTORY ENTRY # FOR
*          THE SPECIFIED USER.
* 
*  CALLING SEQUENCE: (A)=NEGATIVE CHARACTER COUNT 
*                    (B)=WORD ADDRESS OF INPUT STRING 
*                    JSB .UACT
*                    DEF ERROR MESSAGE BUFFER(128)
* 
*            RTN (A)>0= DIRECTORY ENTRY NUMBER
*                (B)=0
*           OR
*                (A)=-1= SESSION NOT INITIALIZED OR NOT INSTALLED 
*                (B) NOT DEFINED
* 
*          ELSE (A)   = - TRANS LOG (BYTES) OF TERMINATING ERROR MSG
*                       (ERROR STRING IN BUFFER ) 
*               (B)  =  ERROR CODE
* 
* 
      SKP 
* 
* 
* 
.UACT NOP 
      JSB .CLGN     SEND REQUEST TO LOGON (A = LENGTH)
DM4   DEC -4        DIRECTORY # FETCH REQUEST 
* 
      LDB .UACT,I   FETCH ERROR BUFFER LOCATION 
      STB BUFA
* 
      SSA           ERROR ? 
      JMP ERR1        YES GET OUT 
* 
      STA CCLAS     SAVE COMMUNICATION CLASS
* 
GETIT LDA DM256     FETCH BUFFER SIZE 
      JSB GETR      GO DO A GET 
       JMP ERR1     ERROR ON GET REQUEST
* 
      LDA CALL      FETCH CALL TYPE ( THAT THE GET FETCHED) 
      CPA D1        MUST BE READ OR WRITE\READ
      RSS 
      JMP GETIT     TRY AGAIN 
* 
      CMB,INB       SET TRANS LOG NEG 
      STB TEMP       AND SAVE AS POSSIBLE ERROR FLAG
      LDA BUFA,I   FETCH POSSIBLE DIRECTORY ENT # 
      LDB IOP2      FETCH LOGON RETURN STATUS 
      STB TEMP3 
      CPB OK?       IF GOOD COMPLETION
EXIT  STA TEMP      SAVE RETURN STATUS
* 
      LDA CCLAS     CLEAR THE 
      XOR SAVC        SAVE CLASS BIT
      STA CCLAS        IN CLASS WORD
AGAIN CLA           AND ISSUE GET (ZERO LENGTH BUFFER)
      JSB GETR      MAKE SURE THE COMMUNICATION CLASS WAS RETURNED
       CLB,RSS      ERROR ON GET SO GET OUT 
      JMP AGAIN 
* 
      LDA TEMP3     FETCH LOGON RETURN STATUS 
      ALF            ISOLATE POSSIBLE ERROR CODE TO  (B MUST=0) 
      ASL 6             LOW 6 BITS OF (B) FOR RETURN TO CALLER
      LDA TEMP      FETCH RETURN STATUS 
      ISZ .UACT     .BUMP RETURN ADDR 
      JMP .UACT,I 
* 
* 
*  INPUT STRING STARTS ON ODD BYTE. 
*  BLANK THE EVEN BYTE OF THAT WORD SO THE PARSE OF THE NAME
*  IS CORRECT.
* 
* 
* 
GETR  NOP 
      STA TEMP2 
      JSB EXEC
      DEF GET1
      DEF DS21
      DEF CCLAS 
      DEF BUFA,I    RESULT BUFFER 
      DEF TEMP2      BUF LEN
      DEF IOP 
      DEF IOP2
      DEF CALL
GET1  EQU * 
      RSS 
      ISZ GETR
      JMP GETR,I
* 
ERR1  CCA 
      JMP EXIT
* 
* 
* 
B40   OCT 40
CALL  NOP 
SAVC  OCT 20000 
D1    DEC 1 
D2    DEC 2 
TEMP  NOP 
TEMP2 NOP 
TEMP3 NOP 
DM256 DEC -256
DS21  OCT 100025
IOP  NOP
IOP2  NOP 
OK?   OCT 110011
CCLAS NOP 
BUFA  NOP 
      END 
                                                                                          